【BZOJ2002】弹飞绵羊（LCT）

题意：给定一棵树，要求维护以下操作：

1.删除连接(x,y)的边

2.将(x,y)之间连边

3.询问某点子树大小

对于100%的数据n<=200000,m<=100000

思路：第一道有加边删边的LCT

讲一下自己对LCT各个操作的理解

Access：最基本的操作，将一个点到LCT的根的点全部修改为重（实）边

可以理解为“全选操作”，配合Splay操作可以取出某段区间的信息

Splay：将X旋转到它所在链的顶部，这样就相当于将这条链中的信息集中到了X这个点上

LCT的splay要用栈pushdown维护的原因是普通splay中splay操作前这些信息已经在Findkth的时候下传

而LCT没有，需要手动下传

Findroot：找到LCT的根，先Access+splay，因为LCT是按照深度维护的，所以一直往左走，找到深度最小的就是根

Makeroot：将X设置为LCT的根，Access+splay，因为上下翻转了所以要打翻转标记

Link：链接两个不在同一条链上的点，Makeroot(x),fa[x]=y

split：取出(x,y)这段区间的信息，Makeroot(x),Access(y),splay(y)，信息在y点上

此题输出左儿子的子树大小即可

var t:array[0..500000,0..1]of longint;
    next,fa,rev,size,q:array[0..500000]of longint;
    n,m,i,x,y,tmp,top:longint;

function isroot(x:longint):boolean;
begin
 if (t[fa[x],0]<>x)and(t[fa[x],1]<>x) then exit(true);
 exit(false);
end;

procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;

procedure pushup(x:longint);
var l,r:longint;
begin
 l:=t[x,0]; r:=t[x,1];
 size[x]:=size[l]+size[r]+1;
end;

procedure pushdown(x:longint);
var l,r:longint;
begin
 l:=t[x,0]; r:=t[x,1];
 if rev[x]>0 then
 begin
  rev[x]:=rev[x] xor 1; rev[l]:=rev[l] xor 1; rev[r]:=rev[r] xor 1;
  swap(t[x,0],t[x,1]);
 end;
end;

procedure rotate(x:longint);
var y,z,l,r:longint;
begin
 y:=fa[x]; z:=fa[y];
 if t[y,0]=x then l:=0
  else l:=1;
 r:=l xor 1;
 while not isroot(y) do
 begin
  if t[z,0]=y then t[z,0]:=x
   else t[z,1]:=x;
 end;
 fa[x]:=z; fa[y]:=x; fa[t[x,r]]:=y;
 t[y,l]:=t[x,r]; t[x,r]:=y;
 pushup(y);
 pushup(x);
end;

procedure splay(x:longint);
var y,z,k:longint;
begin
 inc(top); q[top]:=x;
 k:=x;
 while not isroot(k) do
 begin
  inc(top); q[top]:=fa[k];
  k:=fa[k];
 end;
 while top>0 do
 begin
  pushdown(q[top]);
  dec(top);
 end;

 while not isroot(x) do
 begin
  y:=fa[x]; z:=fa[y];
  if not isroot(y) then
  begin
   if (t[y,0]=x)xor(t[z,0]=y) then rotate(x)
    else rotate(y);
  end;
  rotate(x);
 end;
end;

procedure access(x:longint);
var last:longint;
begin
 last:=0;
 while x>0 do
 begin
  splay(x); t[x,1]:=last; //pushup(x);
  last:=x; x:=fa[x];
 end;
end;

procedure makeroot(x:longint);
begin
 access(x); splay(x); rev[x]:=rev[x] xor 1;
end;

procedure link(x,y:longint);
begin
 makeroot(x); fa[x]:=y;
end;

procedure split(x,y:longint);
begin
 makeroot(x); access(y); splay(y);
end;

procedure cut(x,y:longint);
begin
 makeroot(x); access(y); splay(y); t[y,0]:=0; fa[x]:=0;
end;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

begin
 assign(input,'bzoj2002.in'); reset(input);
 assign(output,'bzoj2002.out'); rewrite(output);
 readln(n);
 for i:=1 to n do
 begin
  read(x);
  fa[i]:=x+i; size[i]:=1;
  if fa[i]>n then fa[i]:=n+1;
  next[i]:=fa[i];
 end;
 size[n+1]:=1;
 readln(m);
 for i:=1 to m do
 begin
  read(x);
  case x of
   1:
   begin
    read(y); inc(y);
    split(n+1,y);
    writeln(size[t[y,0]]);
   end;
   2:
   begin
    read(x,y);
    inc(x); tmp:=min(x+y,n+1);
    cut(x,next[x]); link(x,tmp); next[x]:=tmp;
   end;
  end;
 end;
 close(input);
 close(output);
end.