【BZOJ1812】riv（多叉树转二叉树，树形DP）

题意：给定一棵树，每个点有权值，每条边有边权（单向边）。你可以选取K个黑点，使得从每个点移动到距离他最近的黑点的花费（距离*点权）的总和最小。

n<=100 k<=50 w[i],a[i]<=10000

思路：见IOI2005龙凡解题报告

为什么要多叉转二叉？因为假设点U被选，这个被选点只会对U自己的儿子有影响，对U的兄弟并没有影响

dp[i,j,k]表示以i为根的子树，建j个节点，离i最近的被选点是k时的最小总和

\[ dp[i,j,k]=min\begin{cases} dp[l[i],t,k]+dp[r[i],j-t,k]+(dis[i]-dis[k])*a[i]\\dp[l[i],t,i]+dp[r[i],j-t-1,k] \end{cases} \]

var dp:array[1..200,0..60,1..200]of longint;
    head,vet,next,len,l,r,tree,a,dis:array[1..1000]of longint;
    n,m,i,x,y,tot:longint;

procedure add(a,b,c:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 len[tot]:=c;
 head[a]:=tot;
end;

procedure dfs(u:longint);
var e,v:longint;
begin
 e:=head[u];
 while e<>0 do
 begin
  v:=vet[e];
  dis[v]:=dis[u]+len[e];
  dfs(v);
  e:=next[e];
 end;
end;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

function ask(u,i,k:longint):longint;
var ans,j:longint;
begin
 if dp[u,i,k]<maxlongint div 3 then exit(dp[u,i,k]);
 dp[u,i,k]:=maxlongint div 3;
 for j:=0 to i do
 begin
  ans:=0;
  if l[u]>0 then ans:=ans+ask(l[u],j,k);
  if r[u]>0 then ans:=ans+ask(r[u],i-j,k);
  dp[u,i,k]:=min(dp[u,i,k],ans+(dis[u]-dis[k])*a[u]);
  if i-j-1>=0 then
  begin
   ans:=0;
   if l[u]>0 then ans:=ans+ask(l[u],j,u);
   if r[u]>0 then ans:=ans+ask(r[u],i-j-1,k);
   dp[u,i,k]:=min(dp[u,i,k],ans);
  end;
 end;
 //writeln(u-1,' ',i,' ',k-1);
 exit(dp[u,i,k]);
end;

begin
 assign(input,'bzoj1812.in'); reset(input);
 assign(output,'bzoj1812.out'); rewrite(output);
 readln(n,m);
 inc(n);
 for i:=2 to n do
 begin
  read(a[i],x,y);
  inc(x);
  if tree[x]=0 then begin l[x]:=i; tree[x]:=i; end
   else begin r[tree[x]]:=i; tree[x]:=i; end;
  add(x,i,y);
 end;
 dfs(1);
 fillchar(dp,sizeof(dp),$7f);
 writeln(ask(1,m,1));
 close(input);
 close(output);
end.