【BZOJ1040】骑士（基环树，树形DP）

题意：有一张N点N边的图，点有点权。相连的两个点不能同时取，问使点权和最大怎么取。

思路：如果是N点N-1边就是一棵树，即”没有上司的舞会“

        现在多了一条边，就是环套树的森林。我们枚举删哪条边，删后就是一棵树，做树形DP取最大值即可。删掉的边所连接的两个点中有一个点要强制不取。

var f:array[1..1100000,0..1]of int64;
    head,vet,next,flag,a:array[1..2100000]of longint;
    n,i,tot,st,ed,ban,x:longint;
    tmp,ans:int64;

procedure add(a,b:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 head[a]:=tot;
end;

function max(x,y:int64):int64;
begin
 if x>y then exit(x);
 exit(y);
end;

procedure dfs(u,pre:longint);
var e,v:longint;
begin
 flag[u]:=1;
 e:=head[u];
 while e<>0 do
 begin
  v:=vet[e];
  if v<>pre then
  begin
   if flag[v]=1 then
   begin
    st:=u; ed:=v; ban:=e;
   end
    else dfs(v,u);
  end;
  e:=next[e];
 end;
end;

function fan(x:longint):longint;
begin
 if x mod 2=0 then exit(x-1)
  else exit(x+1);
end;

procedure dp(u,pre:longint);
var e,v:longint;
begin
 f[u,0]:=0; f[u,1]:=a[u];
 e:=head[u];
 while e<>0 do
 begin
  v:=vet[e];
  if (e<>ban)and(v<>pre)and(e<>fan(ban)) then
  begin
   dp(v,u);
   f[u,0]:=f[u,0]+max(f[v,0],f[v,1]);
   f[u,1]:=f[u,1]+f[v,0];
  end;
  e:=next[e];
 end;
end;

begin

 read(n);
 for i:=1 to n do
 begin
  read(a[i],x);
  add(i,x);
  add(x,i);
 end;
 for i:=1 to n do
  if flag[i]=0 then
  begin
   st:=0; ed:=0; ban:=0;
   dfs(i,-1);
   dp(st,-1);
   tmp:=f[st,0];
   dp(ed,-1);
   tmp:=max(tmp,f[ed,0]);
   ans:=ans+tmp;
  end;
 writeln(ans);

end.