位置无关码
ARM下的位置无关和相关码
为什么需要位置无关码?
见 :
U-BOOT详解(什么是《编译地址》？什么是《运行地址》？) http://bbs.21ic.com/forum.php?mod=viewthread&tid=857037&typeid=114
ARM位置无关代码设计规范 http://wenku.baidu.com/view/5ef25b890b4c2e3f562763a8.html
位置无关可执行文件PIE包括位置无关代码PIC和位置无关数据PID两部分。
通常情况下，将bootloader程序下载到ROM的0x0地址进行启动（比如固化到NorFlash中）。然而在很多的设计中，比如将bootloader固化在NAND中，在系统复位后S3C2440A中NAND控制器自动读取NAND中存储的前4K的代码到s3c2440a中称之为
steppingstone的RAM中，steppingstone中的代码用进行一些非核心的硬件初始化，再将NAND中剩下的bootloader代码拷贝到RAM中运行。一般境况下两者的地址并不相同，程序在SDRAM中的地址重定位过程必须由程序员来完成。这样就有了位置无关代码的概念，指代码不在连接时制定的运行地址空间，也可以执行，它一段加载到任意地址空间都能执行的特殊代码。这样在steppingstone设计的代码要用位置无关设计。
位置无关代码可以用于以下场合：
1. 程序在运行期间动态加载到内存；
2. 程序在不同场合与不同程序组合后加载到内存（共享的动态链接库）； 3. 在运行期间不同地址相互之间的映射（如bootloader）
怎么实现位置无关码?
{
1. 位置无关的函数跳转
2. 位置无关的常量访问
}
位置无关代码，即该段代码无论放在内存的哪个地址，都能正确运行。究其原因，是因为代码里没有使用绝对地址，都是相对地址。
而位置相关码，即它的地址与代码处于的位置相关，是绝对地址，如：mov PC ，#0xff；ldr pc，=0xffff等。
如果你的这段代码需要实现位置无关，那么你就不能使用绝对寻址指令，否则的话就是位置有关了。
一、位置无关的写法:
(1) B指令
B指令接受一个相对地址，因此在汇编里用B跳转到一个标号时，实际编译的结果是一个相对跳转。相对地址有个范围限制，即目标不能太远，一般目标放在同一个文件里是肯定可以的。 Offset must IN 32Mbit
_start:
b _reset
_reset:
...
(2) BL
BL用于调用函数，也是一个相对跳转,same as B instrction
(3) ADR
获取标号的地址，在编译时会使用PC+偏移的方式得到该位置的地址。例如，当TEXT_BASE是0时
SMRDATA可能被放在0x100的位置，当TEXT_BASE为0x30000000时放在0x30000100的位置。使用ADR
总能获取正确的位置，与程序的加载地址无关。
ADR R0, SMRDATA
SMRDATA:
.word 0x22111120
.word 0x00002F50
.word 0x00000700
(相应的, LDR Rn, =LABEL是位置相关的)
(4) LDR
当加标号时，LDR可以用于伪指令，也可以真指令。
真指令: (标号前不加=号，表示取标号处的值)
LDR R0, SDRDATA
实际被编译为LDR R0, [PC, #NN]，其中NN是目标的相对距离
伪指令: (标号前加=号，取标号的地址)
LDR R0, = SDRDATA
实际编译的时候的时候，会在某位置存处SDRDATA的值，然后用一个LDR取出来。
显然，用LDR时，加不加=号有很大区别。
无=号：取该标号处的值，位置无关
有=号：取该标号的地址，位置相关
(5) bl/b调用的c语言函数里面也不要使用全局变量, 因为c里面的全局变量的地址是根据链接地址生成的.
见例7.
==================================================================================================================
举例分析
例1：中断向量跳转
_start:
b reset
ldr pc, _undefined_instruction
ldr pc, _software_interrupt
ldr pc, _prefetch_abort
ldr pc, _data_abort
ldr pc, _not_used
ldr pc, _irq
ldr pc, _fiq
_undefined_instruction: .word undefined_instruction
_software_interrupt: .word software_interrupt
_prefetch_abort: .word prefetch_abort
_data_abort: .word data_abort
_not_used: .word not_used
_irq: .word irq
_fiq: .word fiq
其中，
ldr pc, _irq，由于没加=号，表示取值_irq处的值放在pc里 (位置无关)
_irq: .word irq ，表示_irq存放的值是irq的绝对地址(位置有关)
例2:
bl main ; 位置无关
ldr pc, =main; 把main的地址放在pc，位置相关
例3: 静态变量
_MAGIC_NUM:
.word 0x12345678
取值
LDR R0, _MAGIC_NUM ; 位置无关
例4: 存放标号绝对地址(绝对地址是编译的时候已经固定)
_OS_Running_p:
.word OS_Runing
则_OS_Running_p存放的是标号OS_Running的绝对地址
例5: 显式LDR和隐式LDR
以给某C中的变量的g_num赋值为例
(1) 使用伪指令LDR，即为隐式
LDR R0, =g_num @取g_num的地址到R0
MOV R1, #10
STR R1, R0
(2) 显式赋值
先定义一个变量p_g_num，用于保存g_num的地址
p_g_num:
.word g_num @ g_num的绝对地址
然后赋值
LDR R0, p_g_num
MOV R1, #10
STR R1, R0
显然，两者其实一样，伪指令被展开后其实就是(2)的样子。
不同点在于：在多次引用的时候，如果使用伪指令，则会有多个临时定义。所以，
在多次引用的时候应该使用显式定义。
例6: 使用LinkScript中的变量
这种情形和例5相同
1) LinkScript中定义了两个位置
{
__bss_start = .;
.bss : { *(.bss) }
_end = .;
}
2) 定义两个变量，用于存处这两个位置
.globl _bss_start
_bss_start:
.word __bss_start
.globl _bss_end
_bss_end:
.word _end
3) 使用这两个位置
ldr r0, _bss_start /* find start of bss segment */
ldr r1, _bss_end /* stop here */
例7. bl/b调用的c语言函数里面也不要使用全局变量
in head.s and *.c :
Reset: ldr sp, =4096 @ 设置栈指针，以下都是C函数，调用前需要设好栈 bl disable_watch_dog @ 关闭WATCHDOG，否则CPU会不断重启 bl clock_init @ 设置MPLL，改变FCLK、HCLK、PCLK bl memsetup @ 设置存储控制器以使用SDRAM bl nand_init @ 初始化NAND Flash
#define WTCON (*(volatile unsigned long *)0x53000000) void disable_watch_dog(void) { WTCON = 0; // 关闭WATCHDOG很简单，往这个寄存器写0即可 } #define CLKDIVN (*(volatile unsigned long *)0x4c000014) void clock_init(void) { CLKDIVN = 0x03; // FCLK:HCLK:PCLK=1:2:4, HDIVN=1,PDIVN=1 .. .. } void nand_init(void) { S3C2410_NAND * s3c2410nand = (S3C2410_NAND *)0x4e000000; /* 设置时序 */ s3c2440nand->NFCONF = (TACLS<<12)|(TWRPH0<<8)|(TWRPH1<<4); .... } 以上函数都没有使用到全局变量, 一旦使用了全局变量,就不能作为位置无关码的一部分了. 比如bootloader启动的第一阶段, copy2ram的前面部分.必须是位置无关码
