bat批处理中截取字符串
举例：输入hello world和-2，输出ld
这个简单。代码如下
@ echo off&Setlocal enabledelayedexpansion
:标签1
set 文本=hello world
set 开头=-2
set 结尾=
set /p 文本=请输入文本，留空使用默认值hello world
set /p 开头=请输入取值开头位数，正数为从前往后数，负数为从后往前数。留空使用默认值-2
set /p 结尾=请输入取值结尾位数，正数为从取值开头往后数，负数为从文本结尾往前数。留空则从文本结尾结束。
if not "%结尾%"="" set 结尾=,%结尾%
set 文本=!文本:~%开头%%结尾%!
echo 处理结果：%文本%
goto 标签1
转载请注明出处
1.变量的范围
数字计算[±21 4748 3647 整数]，文本[8191个字节](set /p a=<文件 和 ^换行符 可突破该限制，暂不解释)
2.变量的命名
不允许使用纯数字
不建议使用单字母变量
命名不区分大小写
可以使用中文作为变量名
3.变量扩展-文本(以下示例均以变量%a%示范，实际变量名可以为任何值)
文本替换
%a:文本1=文本2% 文本1替换为文本2（文本2可留空，如%a:文本1=%）
文本替换支持通配符*?等
%a:*文本1=文本2% 开头到文本1第一次出现的地方替换为文本2（文本2可留空）
文本截取部分
%a:~10% 第10个字之后的内容
%a:~-10% 倒数第10个字之后的内容
%a:~,5% 开头5个字
%a:~,-5% 开头 - 倒数第5个字
%a:~10,5% 第10个字之后的5个字
%a:~10,-5% 第10个字 - 倒数第5个字
%a:~-10,5% 倒数第10个字之后的5个字
%a:~-10,-5% 倒数第10个字 - 倒数第5个字
注：文本扩展在for命令中可能不可用
示范：set a=%a:~-10,-5%
3.变量扩展-路径(以下示例均以变量%a示范)
(此时右边%可以省略， %~a 和 %~a% 是一样的)
%a 路径 "Temp\tmp 12345.txt"
%~a 删除引号 Temp\tmp 12345.txt
%~fa 完整路径 D:\AppData\Local\Temp\tmp 12345.txt
%~da 分区 D:
%~pa 路径 \AppData\Local\Temp\
%~na 文件名 tmp 12345
%~xa 扩展名 .txt
%~sa 短文件名 D:\AppData\Local\Temp\TM3A8C~1.TXT
%~aa 文件属性 --a--------
%~ta 修改日期 2016/06/02 16:26
%~za 文件大小(字节) 18
%~$b:a 在 目录b 搜索 文件a 找到的第一个文件。
如果变量b不存在，或者没有找到文件a，返回空字符串。
需事先给变量b赋值，多个路径可用分号分隔。命令示例
set b=C:\WINDOWS\system32;C:\WINDOWS;C:\WINDOWS\System32\Wbem
可以组合使用来得到多重结果
%~dpa 分区和路径 D:\AppData\Local\Temp\
%~nxa 完整文件名 tmp 12345.txt
%~dp$b:a 在 目录b 搜索 文件a 输出 文件a 的 分区和路径
%~ftzaa 类似dir命令的输出(完整路径 日期 大小 属性)
--a-------- 2016/06/02 16:26 18 D:\AppData\Local\Temp\tmp 12345.txt
不组合拆分开也行，比如这样%~fa %~ta %~za %~aa
注意：路径扩展仅适用于%0 %1 …%9和for中的单字母变量%%i，若要支持其他变量，考虑使用call
示范
@ echo off & set a=百度贴吧。百度公司。中国公司
echo %%0 %0
echo 文本
echo %%a%% %a%
echo %%a:。=-%% %a:。=-%
echo %%a:百度=%% %a:百度=%
echo %%a:*公司=123%% %a:*公司=123%
echo %%a:~5%% %a:~5%
echo %%a:~-5%% %a:~-5%
echo %%a:~,3%% %a:~,3%
echo %%a:~,-3%% %a:~,-3%
echo %%a:~5,3%% %a:~5,3%
echo %%a:~5,-3%% %a:~5,-3%
echo %%a:~-5,3%% %a:~-5,3%
echo %%a:~-5,-3%% %a:~-5,-3%
pause & echo 产生一个临时文件>"tmp 12345.txt"
rem 使用上方办法即可创建带空格的文件
Call :sub "tmp 12345.txt"
rem 以上一条命令表示跳转到sub标签并将变量%1设置为"tmp 12345.txt"
pause & Del "tmp 12345.txt" & goto tu
:sub
echo 路径
echo %%1 %1
echo %%~1 %~1
echo %%~f1 %~f1
echo %%~d1 %~d1
echo %%~p1 %~p1
echo %%~n1 %~n1
echo %%~x1 %~x1
echo %%~s1 %~s1
echo %%~a1 %~a1
echo %%~t1 %~t1
echo %%~z1 %~z1
echo %%~dp1 %~dp1
echo %%~nx1 %~nx1
echo %%~ftza1 %~ftza1
echo. & Goto :eof
:tu
echo 特殊变量
echo 当前目录%%CD%% %CD%
echo 当前日期%%DATE%% %DATE%
echo 当前时间%%TIME%% %TIME%
echo 范围在0-32767的伪随机数%%RANDOM%% %RANDOM%
echo 错误返回码%%ERRORLEVEL%% %ERRORLEVEL%
echo cmd的版本号%%CMDEXTVERSION%% %CMDEXTVERSION%
echo 显示当前打开cmd所用的命令%%CMDCMDLINE%% %CMDCMDLINE%
echo 当前最高NUMA节点号%%HIGHESTNUMANODENUMBER%% %HIGHESTNUMANODENUMBER%
pause
截取字符串可以说是字符串处理功能中最常用的一个子功能了，能够实现截取字符串中的特定位置的一个或多个字符。
set ifo=abcdefghijklmnopqrstuvwxyz0123456789
echo 原字符串（第二行为各字符的序号）：
echo %ifo%
echo 123456789012345678901234567890123456
echo 截取前5个字符：
echo %ifo:~0,5%
echo 截取最后5个字符：
echo %ifo:~-5%
echo 截取第一个到倒数第6个字符：
echo %ifo:~0,-5%
echo 从第4个字符开始，截取5个字符：
echo %ifo:~3,5%
echo 从倒数第14个字符开始，截取5个字符：
echo %ifo:~-14,5%
pause
出处：https://www.zhihu.com/question/356855628/answer/1000353295
=======================================================================================
FOR命令中有一些变量,他们的用法许多新手朋友还不太了解,今天给大家讲解他们的用法!
先把FOR的变量全部列出来:
~I - 删除任何引号(")，扩展 %I
%~fI - 将 %I 扩展到一个完全合格的路径名
%~dI - 仅将 %I 扩展到一个驱动器号
%~pI - 仅将 %I 扩展到一个路径
%~nI - 仅将 %I 扩展到一个文件名
%~xI - 仅将 %I 扩展到一个文件扩展名
%~sI - 扩展的路径只含有短名
%~aI - 将 %I 扩展到文件的文件属性
%~tI - 将 %I 扩展到文件的日期/时间
%~zI - 将 %I 扩展到文件的大小
%~$PATH:I - 查找列在路径环境变量的目录，并将 %I 扩展
到找到的第一个完全合格的名称。如果环境变量名
未被定义，或者没有找到文件，此组合键会扩展到
空字符串
我们可以看到每行都有一个大写字母"I",这个I其实就是我们在FOR带入的变量,我们FOR语句代入的变量名是什么,这里就写什么.
比如:FOR /F %%z IN ('set') DO @echo %%z
这里我们代入的变量名是z那么我们就要把那个I改成z,例如%~fI改为%~fz
至于前面的%~p这样的内容就是语法了!
好开始讲解:
~I - 删除任何引号(")，扩展 %I
这个变量的作用就如他的说明,删除引号!
我们来看这个例子:
首先我们在桌面建立一个名字为temp.txt文本文件,在里面输入这些内容
"1111
2222"
"3333"
44"44
然后在建立个BAT文件代码如下:
FOR /F "delims=" %%i IN (temp.txt) DO @echo %%~i
pause
执行后,我们看CMD的回显如下:
1111
2222"
3333
44"44
和之前temp.txt中的内容对比一下,我们会发现第一行和第三行的引号都消失了,这就是删除引号~i的作用了!
删除引号规则如下(BAT兄补充!)
1、若字符串首尾同时存在引号，则删除首尾的引号；
2、若字符串尾不存在引号，则删除字符串首的引号；
3、如果字符串中间存在引号，或者只在尾部存在引号，则不删除。
%~fI - 将 %I 扩展到一个完全合格的路径名
看例子:
把代码保存放在随便哪个地方,我这里就放桌面吧.
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~fi
pause
执行后显示内容如下
C:\Documents and Settings\Administrator\桌面\test.bat
C:\Documents and Settings\Administrator\桌面\test.vbs
当我把代码中的 %%~fi直接改成%%i
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%i
pause
执行后就会显示这些内容
test.bat
test.vbs
通过对比,我们很容易就看出没有路径了,这就是"将 %I 扩展到一个完全合格的路径名"的作用
也就是如果%i变量的内容是一个文件名的话,他就会把这个文件所在的绝对路径打印出来,而不只单
单打印一个文件名,自己动手动实验下就知道了!
%~dI - 仅将 %I 扩展到一个驱动器号
看例子:
代码如下,我还是放到桌面执行!
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~di
pause
执行后我CMD里显示如下
C:
C:
我桌面就两个文件test.bat,test.vbs,%%~di作用是,如果变量%%i的内容是一个文件或者目录名,他就会把他这文件
或者目录所在的盘符号打印出来!
%~pI - 仅将 %I 扩展到一个路径
这个用法和上面一样,他只打印路径不打印文件名字
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~pi
pause
我就不打结果了,大家自己复制代码看结果吧,下面几个都是这么个用法,代码给出来,大家自己看结果吧!
%~nI - 仅将 %I 扩展到一个文件名
只打印文件名字
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~ni
pause
%~xI - 仅将 %I 扩展到一个文件扩展名
只打印文件的扩展名
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~xi
pause
%~sI - 扩展的路径只含有短名
打印绝对短文件名
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~si
pause
%~aI - 将 %I 扩展到文件的文件属性
打印文件的属性
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~ai
pause
%~tI - 将 %I 扩展到文件的日期/时间
打印文件建立的日期
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~ti
pause
%~zI - 将 %I 扩展到文件的大小
打印文件的大小
FOR /F "delims==" %%i IN ('dir /b') DO @echo %%~zi
pause
%~$PATH:I - 查找列在路径环境变量的目录，并将 %I 扩展
到找到的第一个完全合格的名称。如果环境变量名
未被定义，或者没有找到文件，此组合键会扩展到
空字符串
这是最后一个,和上面那些都不一样,我单独说说!
我们先在桌面建立一个temp.txt文件,里面写上这些内容
c:\windows
c:\windows\system32
c:\windows\teett
然后在把这些代码保存为批处理,放在桌面.
FOR /F "delims==" %%i IN (temp.txt) DO @echo %%~$PATH:i
pause
执行后CMD显示如下内容
c:\WINDOWS
c:\WINDOWS\system32
ECHO 处于打开状态。
为什么会这样呢,还有一行c:\windows\teett呢?
我们直接在CMD里输入echo %path% 会显示C:\WINDOWS\system32;C:\WINDOWS;C:\WINDOWS\System32\Wbem
%%~$PATH:i也就是在文本里寻找匹配这个PATH变量值的内容,如果里面的内容和PATH变量相同,就打印出来
如果不相同,就显示一个空行!
只能适用于PATH变量,其他变量不行,如果要比较很多值,可尝试把值赋予给PATH变量,我没测试!
好了,FOR的的变量就介绍到这了!
下面为大家分享下实例：
bat 批处理 字符串 替换函数 和 字符串截取函数
1、字符串替换 好了，符号说到这，现在说%PATH:str1=str2% 上面语法的意思就是：将字符串变量%PATH%中的str1 替换为str2
@echo off
@color 02
set ALL=demo123
echo %ALL%
set VAT=%ALL:1=aaa%
echo %VAT%
---结果是demoaaa23
pause
2、字符串截取 ********************************************** 截取功能统一语法格式为：%a:~[m[,n]]% **********************************************
从第m为截取n长度的字符串,m 为偏移量（缺省为0），n 为截取长度（缺省为全部）,n可以是负数
%a:~0,n% 相当于函数 left(a,n) 取左边 n 位 %a:~-m% 相当于函数 right （a,m） 取右边 m 位 %a:~m,n% 相当于函数 mid(a,m+1,n) 从 m+1 位开始取 n 位 %a:~m,-n% 相当于函数 mid(a,m+1,len(a)-m-n),从 m+1 位开始，至倒数 n+1 位 %a:~m % 相当于函数 mid(a,m+1,len(a)-m) 或者 right(a,len(a)-m)，从m+1 位开始取右边全部。
%a:~[m[,n]]%
%123:~0，1%
结果1
bat截取字符串
@echo off
set str=123456789
echo 第一个字符为：%str:~0,1%
echo 头两个字符为：%str:~0,2%
echo 头5个字符为：%str:~0,5%
echo 去掉最后一个字符后的字符串为：%str:~0,-1%
echo 去掉最后3个字符后的字符串为：%str:~0,-3%
echo 第4个字符为：%str:~3,1%
echo 第4个及其之后的3个字符为：%str:~3,4%
echo 最后一个字符为：%str:~-1%
echo 最后一个字符为：%str:~-1,1%
echo 最后两个字符为：%str:~-1,2%
echo 倒数第4个字符为：%str:~-4,1%
echo 倒数第4个及其之后的字符为：%str:~-4%
echo 倒数第4个及其之后的1个字符为：%str:~-4,2%
echo 倒数第4个及其之后的2个字符为：%str:~-4,3%
pause
为了说明这个问题,我在这里把批处理取字符,做下进一步的解释,希望对新手有所启发
如下:
echo %var:~n,k%
我们在这里对每个参数做个说明:"%var",即我们要从中要截取字符的字符串." ~ "取字
符标志符(我是这么理解的),"n" 我们将其理解为指针,"k"我们将其理解为偏移地址.(注
:指针和偏移地址都是从零开始数的)
我们还是用namejm版主的例子做下说明:
@echo off
set str=123456789
rem 定义一个str字符串为123456789
echo 第一个字符为：%str:~0,1%
rem 指针为0,偏移地址为1,即从第0位开始,取1位
echo 头两个字符为：%str:~0,2%
rem 指针为0,偏移地址为2,即从第0位开始,取2位
echo 头5个字符为：%str:~0,5%
rem 指针为0,偏移地址为5,即从第0位开始,取5位
echo 去掉最后一个字符后的字符串为：%str:~0,-1%
rem 当"k"为负值时,我们可以这样理解:从指针开始处开始取其后面所有字符,然后减去
后面"abs(k)位"..所以这个句字我们可以做如下解释:从第0位开始取其全部字符
为:123456789然后从后面减去abs(k)位,所以最后结果为:12345678
echo 去掉最后3个字符后的字符串为：%str:~0,-3%
rem 该句解释同上↑
echo 最后一个字符为：%str:~-1%
rem 参数"n,"和"k"都可以为缺省,缺省"n,"时可以理解为:从abs(k)位开始取其全部
echo 倒数第4个及其之后的字符为：%str:~-4%
rem 解释同上↑
echo 最后一个字符为：%str:~-1,1%
rem n为负值时,表示从后面开始截取字符,取k位(此时n应从1开始数)
echo 最后一个字符为：%str:~-1,2%
rem 解释同上↑
echo 倒数第4个字符为：%str:~-4,1%
rem 解释同上↑
echo 倒数第4个及其之后的1个字符为：%str:~-4,2%
rem 解释同上↑
echo 倒数第4个及其之后的2个字符为：%str:~-4,3%
rem 解释同上↑
pause
出处：https://www.jb51.net/article/50354.htm
=======================================================================================
个人使用
在补充一个我自己使用，在for循环中截取路径中最后一个字符，判断是否是反斜线，如果是则截取反斜线前的所有字符
@echo off
setlocal enabledelayedexpansion
set varTarget=E:\_Del\2\,E:\_Del\3 E:\_Del\4 E:\_Del\5\
set distPath=
rem Format data:loop to remove \
for %%a in (%varTarget%) do (
set destTmp=%%~a
if "!destTmp!" neq "" (if "!destTmp:~-1!" equ "\" (set destTmp=!destTmp:~,-1!))
if defined distPath set distPath=!distPath!,
set distPath=!distPath!"!destTmp!"
)
其中varTarget使用了逗号、空格作为分隔符，有反斜线结尾，及无反斜线结尾作为测试
如果，您希望更容易地发现我的新博客，不妨点击一下绿色通道的【关注我】。(●'◡'●)
因为，我的写作热情也离不开您的肯定与支持，感谢您的阅读，我是【Jack_孟】！
本文来自博客园，作者：jack_Meng，转载请注明原文链接：https://www.cnblogs.com/mq0036/p/16101639.html
【免责声明】本文来自源于网络，如涉及版权或侵权问题，请及时联系我们，我们将第一时间删除或更改！
posted on 2022-04-05 10:38 jack_Meng 阅读(4893) 评论(0) 编辑 收藏 举报
