windows下bat批处理实现守护进程(有日志)

开发部的一个核心程序总是会自己宕机，然后需要手工去起，而这个服务的安全级别又很高，只有我可以操作，搞得我晚上老没法睡，昨晚实在受不了了，想起以前在hp-ux下写的shell守护进程，这回搞个windows下的bat版守护程序吧，当时晚上思路已经很迟钝了，就叫了个兄弟让他写了，上去后运行效果不错，至少昨晚我安心睡了7小时。

早上来把程序改完善一些，增加了记录等功能。

实现：

检查是否有notepad，要用的话就算成自己的进程名，如果进程宕了就过会自动重启（会在当前目录下生成一个start.bat）

@echo off

set _task=notepad.exe
set _svr=c:/windows/notepad.exe
set _des=start.bat

:checkstart
for /f "tokens=5" %%n in ('qprocess.exe ^| find "%_task%" ') do (
if %%n==%_task% (goto checkag) else goto startsvr
)

:startsvr
echo %time%
echo ********程序开始启动********
echo 程序重新启动于 %time% ,请检查系统日志 >> restart_service.txt
echo start %_svr% > %_des%
echo exit >> %_des%
start %_des%
set/p=.<nul
for /L %%i in (1 1 10) do set /p a=.<nul&ping.exe /n 2 127.0.0.1>nul
echo .
echo Wscript.Sleep WScript.Arguments(0) >%tmp%/delay.vbs
cscript //b //nologo %tmp%/delay.vbs 10000
del %_des% /Q
echo ********程序启动完成********
goto checkstart


:checkag
echo %time% 程序运行正常,10秒后继续检查..
echo Wscript.Sleep WScript.Arguments(0) >%tmp%/delay.vbs
cscript //b //nologo %tmp%/delay.vbs 10000
goto checkstart

 

 

出处：https://blog.csdn.net/jiangxinyu/article/details/5217342

========================================================================

 

这个脚本提供两种方式守护，一种是通过进程名，但对于进程名都是java.exe的java程序不适用，另一种是通过netstat查找应用程序所监听的端口是否正在被监听。这两种方式可以在脚本中通过两个冒号注释来选择切换。下面是设置成通过端口来守护的，当端口没被监听则打开一个zip文件，所以运行后会发现没过5秒会重复打开这个zip文件，除非这个zip文件打开后会自动监听8080端口，那当然是不可能的！脚本涉及的命令就不解释了搜一下就知道了。

@echo off

::检测时间间隔，单位：秒
set _interval=5

::需要守护的进程名称
set _processName=WinRAR

::需要守护的进程启动命令
set _processCmd=C:\ideavim-0.32.zip

::需要守护的进程预估启动完毕所需时间，单位：秒
set _processTimeout=10

::需要守护的进程所监听的端口
set _port=8080

::进程用户名，一般是Administrator
set _username=Administrator 

:LOOP
set /a isAlive=false

::通过进程名称检测
::tasklist /FI "username eq %_username%" | find /C "%_processName%" > temp.txt
::set /p num= < temp.txt
::del /F temp.txt

::通过进程的端口是否正在被监听检测
netstat -an | find /C "0.0.0.0:%_port%" > temp.txt
set /p num= < temp.txt
del /F temp.txt

if "%num%" == "0" (
start %_processCmd% | echo 启动 %_processName% 于 %time%
choice /D y /t %_processTimeout% > nul
)

if "%num%" NEQ "0" echo 已启动

::ping -n %_interval% 127.1>nul
choice /D y /t %_interval% >nul

goto LOOP

该脚本运行后会出现一个dos窗口，若觉得碍眼可以用记事本将下面保存为扩展名为.vbs的文件。其中guard.bat是上面批处理保存的文件名。两个文件放在同一目录下双击vbs文件后，守护进程就在后台运行了，单这样得通过资源管理器结束cmd进程才能停止守护进程。

set ws=WScript.CreateObject("WScript.Shell")
ws.Run "guard.bat",0

 

 

出处：https://blog.csdn.net/qin9r3y/article/details/22805095

==================================================================

根据上面的内容自己修改一个放到项目上使用：

1）可以根据参数，执行指定的程序

2）可以保存详细的执行日志

 

版本一：

@echo off
title processWatch
cls
set d=%date:~0,10%
set d=%d: =0%
echo %d%
set logFile=.\processWatch_%d:-=%.txt
echo 现在时间：%date%%time% 
echo ********程序开始启动******** >> %logFile%

set runAppPath=%1
set runAppPath="C:\Users\Administrator\Desktop\新建文件夹\Cares.AutoUpdate.exe"
set runAppFolder=''
if '%runAppPath%'=='' (goto end)

set _processName=''
set _processNameExt=''
::检测时间间隔，单位：秒
set _interval=10

for %%a in (%runAppPath%) do (
set _processName=%%~na
set _processNameExt=%%~nxa
set runAppFolder=%%~dpa
)
goto checkstart

rem 以下是测试代码
echo %_processName%
echo %_processNameExt%
echo %runAppFolder%
echo %runAppPath%
echo ====================================================
goto end


:checkstart
set d=%date:~0,10%
set d=%d: =0%
set logFile=.\processWatch_%d:-=%.txt
for /f "tokens=1" %%n in ('tasklist.exe ^| find /I "%_processNameExt%" ') do ( 
if '%%n'=='%_processNameExt%' (echo 检查进程【%_processNameExt%】正在运行 >> %logFile% && goto checkend) )
echo 检查进程【%_processNameExt%】未在运行 >> %logFile%

:startApp
echo, && echo ********开始启动程序********
echo ********开始启动程序******** >> %logFile%
echo [%date:~0,10%%time:~0,8%] 未检测到【%_processNameExt%】的进程，将重新启动程序 >> %logFile%
echo [%date:~0,10%%time:~0,8%] 重新启动程序：%runAppPath%
echo [%date:~0,10%%time:~0,8%] 重新启动程序：%runAppPath% >> %logFile%
echo 开始执行 start "" %runAppPath% >> %logFile%
pushd %runAppFolder%
start "" %runAppPath%
popd
echo ********启动程序完成******** && echo,
echo ********启动程序完成******** >> %logFile%
echo, >> %logFile%


:checkend
echo [%date:~0,10%%time:~0,8%] 程序【%_processNameExt%】运行正常,%_interval%秒后继续检查......
choice /t %_interval% /d y /n >nul
goto checkstart

:end
echo end.

 

后续将继续优化