[BZOJ2453]维护队列|分块

Description

你小时候玩过弹珠吗？

小朋友A有一些弹珠，A喜欢把它们排成队列，从左到右编号为1到N。为了整个队列鲜艳美观，小朋友想知道某一段连续弹珠中，不同颜色的弹珠有多少。当然，A有时候会依据个人喜好，替换队列中某个弹珠的颜色。但是A还没有学过编程，且觉得头脑风暴太浪费脑力了，所以向你来寻求帮助。

 

　　思路很简单，在[l,r]中出现过的颜色数量

　　我们设b[i]为第i位的数其之前出现的时候的下标

　　只要统计在[l,r]间，b[i]<l的数量即可

　　

　　只要在每次修改的时候维护好b，再每次排序，询问的时候二分查找即可。

　　如何维护b呢？

　　对于每一个修改，它最多影响两个数的b，一个是它自身，一个是它后面遇到的第一个与它相等的数

　　我们只要重新对两个块排序

　　但是处理处b，刚开始我想要在每个块中再维护一个以颜色为第一关键字，下标为第二关键字的序列

　　对于每个块二分找到修改的点前一次出现的位置 但是感觉十分麻烦

　　看了下数据，修改的次数不会超过1000，n<=10000，每次重新算一遍b数组也是可以的

　　但是第一次提交TLE了，发现习惯性的fillchar实际上时间并不那么快

　　统计b的last数组实际上O（n）赋值比fillchar要快得多（因为last的范围的[0..10^6]啊/w\）

program bzoj2453;
const maxn=10010;maxm=1000010;
var n,m,i,block,x,y,q:longint;
    ch:char;
    pos,a,b,pre:array[-1..maxn]of longint;
    last:array[-1..maxm]of longint;

function min(a,b:longint):longint;
begin
    if a<b then exit(a) else exit(b);
end;

procedure qsort(L,R:longint);
var i,j,mid:longint;
begin
    i:=L;j:=R;mid:=pre[random(R-L+1)+L];
    repeat
        while (i<R)and(pre[i]<mid) do inc(i);
        while (L<j)and(pre[j]>mid) do dec(j);
        if i<=j then
        begin
            pre[0]:=pre[i];pre[i]:=pre[j];pre[j]:=pre[0];
            inc(i);dec(j);
        end;
    until i>j;
    if i<R then qsort(i,R);
    if L<j then qsort(L,j);
end;

procedure new(x:longint);
var l,r,i:longint;
begin
    l:=(x-1)*block+1;r:=min(x*block,n);
    for i:=l to r do pre[i]:=b[i];
    qsort(l,r);
end;

procedure change(x,y:longint);
var i:longint;
begin
    for i:=1 to n do last[a[i]]:=0;
    a[x]:=y;
    for i:=1 to n do
    begin
        if last[a[i]]<>b[i] then
                begin

                b[i]:=last[a[i]];
                        new(pos[i]);
                end;
        b[i]:=last[a[i]];
        last[a[i]]:=i;
    end;
end;

function find(x,y:longint):longint;
var L,R,mid:longint;
begin
    find:=(x-1)*block;
    L:=find+1;R:=min(x*block,n);
    while L<=R do
    begin
        mid:=(L+R) >> 1;
         if pre[mid]<=y then
        begin
            find:=mid;L:=mid+1;
        end else R:=mid-1;
    end;
    dec(find,(x-1)*block);
end;

procedure build;
var i:longint;
begin
    for i:=1 to n do last[a[i]]:=0;
    for i:=1 to n do
    begin
        b[i]:=last[a[i]];
        last[a[i]]:=i;
    end;
    for i:=1 to m do new(i);
end;

function query(x,y:longint):longint;
var i,tot:longint;
begin
    tot:=0;
    if pos[x]=pos[y] then
    begin
        for i:=x to y do if b[i]<=x-1 then inc(tot);
    end else
    begin
        for i:=x to pos[x]*block do if b[i]<=x-1 then inc(tot);
        for i:=(pos[y]-1)*block+1 to y do if b[i]<=x-1 then inc(tot);
        for i:=pos[x]+1 to pos[y]-1 do inc(tot,find(i,x-1));
    end;
    exit(tot);
end;

begin
    readln(n,q);
    block:=trunc(sqrt(n));
    for i:=1 to n do
    begin
        read(a[i]);
        pos[i]:=(i-1) div block+1;
    end;
        readln;
    if n mod block=0 then m:=n div block else m:=n div block+1;
    build;
    for i:=1 to q do
    begin
        read(ch);
        if ch='Q' then
        begin
            readln(x,y);
            writeln(query(x,y));
        end else
        begin
            readln(x,y);
            change(x,y);
        end;
    end;
end.