[BZOJ1031][JSOI2007]字符加密Cipher 解题报告

Description

　　喜欢钻研问题的JS 同学，最近又迷上了对加密方法的思考。一天，他突然想出了一种他认为是终极的加密办法：把需要加密的信息排成一圈，显然，它们有很多种不同的读法。例如下图，可以读作：

 

　　JSOI07 SOI07J OI07JS I07JSO 07JSOI 7JSOI0 把它们按照字符串的大小排序： 07JSOI 7JSOI0 I07JSO JSOI07 OI07JS SOI07J 读出最后一列字符：I0O7SJ，就是加密后的字符串（其实这个加密手段实在很容易破解，鉴于这是突然想出来的，那就^^）。但是，如果想加密的字符串实在太长，你能写一个程序完成这个任务吗？

　　这道题好像也做了挺久...一个半小时吧

　　首先题目很亲切 总感觉去年暑假在镇中有过类似的题 但是那道题好像有神奇的O（n）做法

　　其实问题可以转化为将字符串及其循环以后的n-1个串从小到大排序，然后输出字符串首位的前一位字符

　　我们要解决字符串及其循环以后一共n个串的排序

　　我用后缀数组解决

　　我们可以直接用后缀数组处理出1 << (trunc(ln(n)/ln(2)))长度的排序

　　将后缀处理成子串的方法就在原串后面再接一次

　　然后再类似于倍增一点点将剩下的长度加入

　　实现方法类似于后缀数组 几个细节改动一下

　　但是由于要用到中间的数据，所以sa和rank数组要在每一次之后保留不能重复利用

　　还是一道非常不错的题呢^

　　

program bzoj1031;
const maxn=200010;
var i,x,n:longint;
    ss:ansistring;
    a,s,tmp,rk,sa2:array[-1..maxn]of longint;
    rank,sa:array[-1..20,-1..maxn]of longint;

function max(a,b:longint):longint;
begin
        if a>b then exit(a) else exit(b);
end;

procedure Suffix_Array;
var i,j,k,p,v0,v00,v01,v1,size:longint;
begin
        size:=256;
    for i:=0 to n-1 do rank[0,i]:=a[i];
    for i:=0 to size-1 do s[i]:=0;
    for i:=0 to n-1 do inc(s[rank[0,i]]);
    for i:=1 to size-1 do inc(s[i],s[i-1]);
    for i:=n-1 downto 0 do
    begin
             dec(s[rank[0,i]]);
             sa[0,s[rank[0,i]]]:=i;
    end;
    j:=1;k:=1;
        size:=n;
        while j<=n >> 1 do
    begin
        p:=0;
        for i:=n-j to n-1 do
        begin
            tmp[p]:=i;
            inc(p);
        end;
        for i:=0 to n-1 do if sa[k-1,i]-j>=0 then
        begin
            tmp[p]:=sa[k-1,i]-j;
            inc(p);
        end;
        for i:=0 to size-1 do s[i]:=0;
        for i:=0 to n-1 do inc(s[rank[k-1,i]]);
        for i:=1 to size-1 do inc(s[i],s[i-1]);
        for i:=n-1 downto 0 do
        begin
            dec(s[rank[k-1,tmp[i]]]);
            sa[k,s[rank[k-1,tmp[i]]]]:=tmp[i];
        end;
        p:=0;rank[k,sa[k,0]]:=0;
        for i:=1 to n-1 do
        begin
            v0:=sa[k,i-1];v1:=sa[k,i];
            if v0+j<n then v00:=rank[k-1,v0+j] else v00:=-1;
            if v1+j<n then v01:=rank[k-1,v1+j] else v01:=-1;
            if (rank[k-1,v0]=rank[k-1,v1])and(v00=v01) then rank[k,sa[k,i]]:=p else
            begin
                inc(p);
                rank[k,sa[k,i]]:=p;

            end;
        end;
        j:=j << 1;inc(k);
        end;
end;

procedure solve;
var i,j,k,p,x,rec,v0,v1,v00,v01,size:longint;
begin
    x:=trunc(ln(n >> 1)/ln(2));
        size:=max(256,n);
    for i:=0 to n-1 do rk[i]:=rank[x,i];
    for i:=0 to size-1 do s[i]:=0;
    for i:=0 to n-1 do inc(s[rk[i]]);
    for i:=1 to size-1 do inc(s[i],s[i-1]);
    for i:=n-1 downto 0 do
    begin
        dec(s[rk[i]]);
        sa2[s[rk[i]]]:=i;
    end;
    rec:=n >> 1-1 << x;
    while rec<>0 do
    begin
        x:=trunc(ln(rec)/ln(2));
        p:=0;
        for i:=n-1 << x to n-1 do
        begin
            tmp[p]:=i;
            inc(p);
        end;
        for i:=0 to n-1 do if sa[x,i]-1 << x>=0 then
        begin
            tmp[p]:=sa[x,i]-1 << x;
            inc(p);
        end;
        for i:=0 to size-1 do s[i]:=0;
        for i:=0 to n-1 do inc(s[rk[i]]);
        for i:=1 to size-1 do inc(s[i],s[i-1]);
        for i:=0 to n-1 do
        begin
            dec(s[rk[tmp[i]]]);
            sa2[s[rk[tmp[i]]]]:=tmp[i];
        end;
        p:=0;tmp[sa2[0]]:=0;
        for i:=1 to n-1 do
        begin
            v0:=sa2[i-1];v1:=sa2[i];
            if v0+1 << x<n then v00:=rank[x,v0+1 << x] else v00:=-1;
            if v1+1 << x<n then v01:=rank[x,v1+1 << x] else v01:=-1;
            if (rk[v0]=rk[v1])and(v00=v01) then tmp[sa2[i]]:=p else
            begin
                inc(p);
                tmp[sa2[i]]:=p;
            end;
        end;
        for i:=0 to n-1 do rk[i]:=tmp[i];
        dec(rec,1 << x);
    end;
end;

begin
    readln(ss);n:=length(ss);
    for i:=0 to n-1 do a[i]:=ord(ss[i+1]);
        for i:=n to 2*n-1 do a[i]:=a[i-n];
        n:=n*2;
    Suffix_Array;
        solve;
    for i:=0 to n-1 do if sa2[i]<(n >> 1) then
    begin
        x:=sa2[i]-1;
        if x=-1 then x:=n >> 1-1;              
            write(ss[x+1]);
    end;
end.