[POJ2954&POJ1265]皮克定理的应用两例

皮克定理：

　　在一个多边形中。用I表示多边形内部的点数，E来表示多边形边上的点数，S表示多边形的面积。

　　满足：S：=I+E/2-1;

解决这一类题可能运用到的：

　　求E，一条边（x1,y1,x2,y2）上的点数（包括两个顶点）=gcd(abs(x1-x2),abs(y1-y2))+1;

　　求S：刚开始做POJ2954的时候莫名其妙一直WA，用了海伦公式求面积，后来又改用割补法，还是WA。发现面积还是用叉积算的好。

在八十中走廊里看过的书都忘光了啊...这么典型的叉积运用都会选择小学方法...不过至今没弄明白为什么海伦公式和割补法的误差那么大...

---

POJ2954 

program poj2954;
var x1,y1,x2,y2,x3,y3,e:longint;
      s:extended;

function gcd(x,y:longint):longint;
begin
    if y=0 then exit(x) else
    exit(gcd(y,x mod y));
end;

function calc_area(x1,y1,x2,y2,x3,y3:longint):extended;
begin
    exit(abs((x2-x1)*(y3-y1)-(x3-x1)*(y2-y1))/2);
end;

function solve(x1,y1,x2,y2:longint):longint;
begin
    exit(gcd(abs(x1-x2),abs(y1-y2))+1);
end;

begin
    //assign(input,'poj2954.in');reset(input);
    //assign(output,'a.out');rewrite(output);
    while not eof do 
    begin
        readln(x1,y1,x2,y2,x3,y3);
        if (x1=0)and(y1=0)and(x2=0)and(y2=0)and(x3=0)and(y3=0) then halt;
        s:=calc_area(x1,y1,x2,y2,x3,y3);                
        e:=solve(x1,y1,x2,y2)+solve(x1,y1,x3,y3)+solve(x2,y2,x3,y3)-3;
        writeln(trunc(s-e/2+1));
    end;
end.

 

---

 

POJ1265

program poj1265;
const maxn=110;
type point=record x,y:longint;end;
var t,test,n,e,i,tx,ty:longint;
      s:extended;
      a:array[-1..maxn]of point;

function gcd(x,y:longint):longint;
begin
    if y=0 then exit(x) else
    exit(gcd(y,x mod y));
end;

function cross(p0,p1,p2:point):double;
begin
    exit((p1.x-p0.x)*(p2.y-p0.y)-(p2.x-p0.x)*(p1.y-p0.y));
end;

begin
    //assign(input,'poj1265.in');reset(input);
    readln(test);
    for t:=1 to test do 
    begin
        readln(n);
        a[0].x:=0;a[0].y:=0;
        for i:=1 to n do 
        begin
            readln(tx,ty);
            a[i].x:=a[i-1].x+tx;
            a[i].y:=a[i-1].y+ty;
        end;
        e:=0;
        for i:=0 to n-1 do inc(e,gcd(abs(a[i].x-a[i+1].x),abs(a[i].y-a[i+1].y)));
        s:=0;
        for i:=2 to n do s:=s+cross(a[0],a[i-1],a[i])/2;
        s:=abs(s);
        writeln('Scenario #',t,':');
        writeln(trunc(s+1-e/2),' ',e,' ',s:0:1);
        writeln;
    end;
end.