AS3给图片加水印文字

 

<需要flash player 10+支持>

通过FileReference获取选中的图片，调用它的load方法，将图片存入到内存中。使用Loader(flash.display.Loader)类的loadBytes方法，加载图片。

 

在点击“加水印”的按钮时，建立两个BitmapData，然后里面分别存放图片和需要添加的文字，之后将两个BitmapData转换为Bitmap添加至舞台，再转成一张新的Bitmap。

 

保存图片功能则较为简单了，直接使用FileReference的save方法

 

实现的并不完善，缺少例如：选择字体大小、颜色、间距等功能，未提供平铺或是移动文字位置的功能…

 

 

示例代码如下<仅供参考>：

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml"
                layout="absolute"
                minWidth="400" minHeight="600"
                creationComplete="inited()"
                backgroundColor="#ffffff">

    <mx:Style source="theme/vistaremix/vistaremix.css" />

    <mx:Script>
        <![CDATA[
            import mx.controls.Alert;
            import mx.core.UIComponent;
            import mx.events.PropertyChangeEvent;
            import mx.graphics.codec.PNGEncoder;

            private var file:FileReference;
            private var loader:Loader;

            private function inited():void
            {
                loader = new Loader();
                loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loaderDataCompleteHandler);
                loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, loaderProgressHandler);

                var ui:UIComponent = new UIComponent;

                addChild(ui);

                ui.addChild(loader);

                loader.visible = false;
            }

            private function selectPictureHandler():void
            {
                file = new FileReference();
                file.addEventListener(Event.SELECT, fileSelectHandler);
                file.browse(getFileFilterArr());
            }

            private function getFileFilterArr():Array
            {
                return [new FileFilter("Images(*.jpg;*.jpeg;*.png;*.gif)", "*.jpg;*.jpeg;*.png;*.gif")];
            }

            private function fileSelectHandler(evt:Event):void
            {
                file.removeEventListener(Event.SELECT, fileSelectHandler);
                file.addEventListener(Event.COMPLETE, fileLoadCompleteHandler);
                file.load();

                filePathTxt.text = file.name;
            }

            private function fileLoadCompleteHandler(evt:Event):void
            {
                file.removeEventListener(Event.COMPLETE, fileLoadCompleteHandler);
                loader.loadBytes(file.data);
            }

            private function madePictureHandler():void
            {
                if (loader.content == null)
                {
                    Alert.show("请先选择要处理的图片","提示");

                    return;
                }

                var ui:UIComponent = new UIComponent();

                var txt:TextField=new TextField();
                var imgBitmapData:BitmapData = (loader.content as Bitmap).bitmapData.clone();

                var format:TextFormat = new TextFormat();
                format.size = 22;
                format.bold = true;
                format.color=0xcc9900;
                format.align = TextFormatAlign.CENTER;
                txt.defaultTextFormat = format;
                txt.htmlText = contentTxt.text || "形象装";
                txt.width = 170;
                txt.height = 50;

//                txt.filters = [getTextGlowFilter()];

                var tempBitMapData:BitmapData = new BitmapData(txt.width, txt.height, true, 0x00000000);
                tempBitMapData.draw(txt);

                var txtShap:Shape = new Shape();
                txtShap.graphics.beginBitmapFill(tempBitMapData);
                txtShap.graphics.drawRect(0,0, tempBitMapData.width, tempBitMapData.height);
                txtShap.graphics.endFill();
                txtShap.x=(imgBitmapData.width-tempBitMapData.width) / 2;
                txtShap.y=(imgBitmapData.height-tempBitMapData.height) / 2;
//                txtShap.alpha = .7;

//                txtShap.rotation = 45 + 270;

                ui.addChild(new Bitmap(imgBitmapData));
                ui.addChild(txtShap);

                var newBitmapData:BitmapData = new BitmapData(imgBitmapData.width, imgBitmapData.height, true, 0x00000000);
                newBitmapData.draw(ui);

                var newBitmap:Bitmap = new Bitmap();
                newBitmap.bitmapData = newBitmapData;

                previewImg.source = newBitmap;
            }

            private function getTextGlowFilter(col:uint=0x000000,blur:Number=2):GlowFilter
            {
                var color:uint             = col
                var alpha:Number        = 1;
                var blurX:Number        = blur
                var blurY:Number        = blur
                var strength:Number     = 255;
                var quality:Number      = 1
                return new GlowFilter(color,alpha,blurX,blurY,strength,quality);
            }

            private function savePictureHandler():void
            {
                if (loader.content == null || previewImg.source == null)
                {
                    Alert.show("请先选择要处理的图片","提示");

                    return;
                }

                var pngenc:PNGEncoder = new PNGEncoder();

                var bitmapData:BitmapData = (previewImg.source as Bitmap).bitmapData.clone();

                var imgByteArray:ByteArray = pngenc.encode(bitmapData);

                var _file:FileReference = new FileReference();
                _file.addEventListener(Event.COMPLETE, downloadCompleteHandler);
                _file.save(imgByteArray, "_" + filePathTxt.text);
            }

            private function downloadCompleteHandler(evt:Event):void
            {
                Alert.show("图片已保存成功","提示");
            }

            private function loaderDataCompleteHandler(evt:Event):void
            {
                var bitmapData:BitmapData = new BitmapData(loader.width, loader.height, true, 0x00FFFFFF);

                bitmapData.draw(loader.content);

                var bitmap:Bitmap = new Bitmap();
                bitmap.bitmapData = bitmapData;

                previewImg.source = bitmap;
            }

            private function loaderProgressHandler(evt:ProgressEvent):void
            {
                var percent:Number = evt.bytesLoaded / evt.bytesTotal;

                percent *= 100;

                var msg:String = "正在加载：" + percent + "%";

                trace(msg);
            }

        ]]>
    </mx:Script>


    <mx:VBox width="100%" height="100%" paddingLeft="20" verticalGap="5">

        <mx:HBox width="100%" paddingTop="20" horizontalGap="5">

            <mx:TextInput id="filePathTxt" width="300" editable="false" />

            <mx:Button label="选择图片" id="selectBtn" click="selectPictureHandler()" />

        </mx:HBox>

        <mx:HBox width="100%" horizontalGap="5" verticalAlign="top">

            <mx:TextArea id="contentTxt" width="300" />

            <mx:Button label="加水印" id="madeBtn" click="madePictureHandler()" />

            <mx:Button label="保存图片" id="saveBtn" click="savePictureHandler()" />

        </mx:HBox>

        <mx:Canvas width="350" height="500" id="imgContainer" left="20" top="60"
                   borderColor="#3399cc" borderThickness="1" borderStyle="solid" >

            <mx:Image id="previewImg" horizontalAlign="0" verticalCenter="0" />

        </mx:Canvas>

    </mx:VBox>

</mx:Application>