VBA的异常处理(On Error Goto 错误标签....)

　　在 Word 、 Excel 乃至其他支持 VBA 的 Office 组件中，在代码中处理错误的方式通常都是使用“ On Error Goto 错误标签”语句，然后在代码的后面添加错误标签及其中包含的错误处理代码。下面总结了创建错误处理程序的步骤：

　　（ 1 ）在过程中可能导致错误的代码行的前面添加错误处理语句 On Error Goto ErrHandler ，其中的“ ErrHandler ”为自定义的错误标签名称。

　　（ 2 ）在有可能导致错误的代码行后面添加取消错误处理的语句 On Error Goto 0 ，这样当遇到错误时，就不会跳转到指定的错误标签处，而是直接显示错误提示窗口，其中包括【调试】、【结束】等按钮。

　　（ 3 ）在宏的末尾（正常程序的末尾）添加代码行 Exit Sub ，这样可以避免程序未发生错误时执行错误处理程序。

　　（ 4 ）在代码行 Exit Sub 的下一行添加一个错误标签，该标签由名称和冒号组成，例如“ MyErr: ”。

　　（ 5 ）在错误标签的下一行编写错误处理代码。如果要返回导致错误的代码行后面的代码行，可以使用 Resume Next 语句。

　　注意：可以在过程的末尾添加多个错误处理程序，但必须确保每个错误处理程序都以Resume Next 或 Exit Sub 语句结束，这样可以避免从当前错误程序之后继续执行其后的错误处理程序。

　　举一个简单的例子可能会更直观地反映出上面所说的内容。在下面的代码中，当检测到工作簿中没有指定的工作表时，将出现错误，并执行错误代码，显示一个包含错误号与错误描述的对话框。

Sub 检测工作表是否存在 ()

    Dim wksname As String, msg As String

    On Error GoTo MyErr

    wksName = Worksheets("sx").Name

    MyErr:

    msg = " 错误 " & Err.Number & " ： " & Err.Description

    MsgBox msg

End Sub

 　　注意：无论在导致问题的代码行前面使用 On Error Resume Next 语句还是“ On Error Goto 标签”语句，要想让程序重新获取其他错误信息，则都必须在导致问题的代码行后面使用 On Error Goto 0 语句恢复正常的错误捕获状态。否则当前的错误处理程序将对后面的所有错误都起作用。例如，下面的代码由于没有使用 On Error Goto 0 语句，因此，在后面遇到错误时（两次 x/y ），都会转到标签 MyErr 处执行错误处理程序。

Sub ErrTest()

    Dim x As Integer, y As Integer, z As Single

    x = 1

    y = 0

    On Error GoTo MyErr

    MsgBox x / y

    MsgBox x / y

    MsgBox " 继续执行错误代码行的下一行代码 "

    Exit Sub

MyErr:

    MsgBox " 第 1 次：除数不能为 0"

    Resume Next   

End Sub

 

　　而下面的代码由于及时使用了 On Error Goto 0 语句，因此，在第 2 次错误发生时（即第 2 个 x/y ），系统将显示内置错误消息，而不是运行 MyErr 标签处的代码。

Sub ErrTest1()

    Dim x As Integer, y As Integer, z As Single

    x = 1

    y = 0

    On Error GoTo MyErr

    MsgBox x / y

    On Error GoTo 0

    MsgBox x / y

    MsgBox " 继续执行错误代码行的下一行代码 "

    Exit Sub

MyErr:

    MsgBox " 第 1 次：除数不能为 0"

    Resume Next

End Sub

 

　　下面的代码虽然未使用 On Error Goto 0 语句，但是在第 2 个错误发生前，添加了第2 个错误标签，因此，两个错误处理程序分别处理各自的错误。

Sub ErrTest2()

    Dim x As Integer, y As Integer, z As Single

    x = 1

    y = 0

    On Error GoTo MyErr1

    MsgBox x / y

    On Error GoTo MyErr2

    MsgBox x / y

    MsgBox " 继续执行错误代码行的下一行代码 "

    Exit Sub

MyErr1:

    MsgBox " 第 1 次：除数不能为 0"

    Resume Next

MyErr2:

    MsgBox " 第 2 次：除数不能为 0"

    Resume Next

End Sub

　　以上 3 段代码在执行完错误处理程序后，都会返回发生错误的代码之后继续执行。对于本例来说，在执行完错误处理程序后，都会继续执行“ MsgBox " 继续执行错误代码行的下一行代码 " ”代码行。

　　虽然我们不希望在程序运行时出现错误，但是有些时候我们可以利用错误来提高代码的效率。例如，当用户由于某些原因将工作簿中的某个工作表删除，如果 VBA 程序中包括操作该工作表的代码，那么当用户运行该程序时，将导致错误发生。此时，可以利用错误来检测要操作的工作表是否存在于工作簿中。代码如下：

Sub 检测工作表是否存在()

    Dim WksName As String

    On Error Resume Next

    WksName = Worksheets("sx").Name

    If Err.Number <> 0 Then

        MsgBox prompt:=" 此工作簿中未找到工作表 sx", Title:=" 错误 "

    End If

    On Error GoTo 0

End Sub

 

　　注意：当使用 On Error Resume Next 语句后，应该及时在可能导致错误的代码行之后使用 On Error Goto 0 语句恢复错误的捕获，即恢复到错误检查的正常状态，以便可以获悉其他任何可能发生的错误。另外，如果使用 On Error Resume Next 语句忽略了无法忽略的错误，将会立刻结束当前运行的过程。而更糟糕的是，如果宏 1 调用宏 2 ，但宏 2 发生了无法忽略的错误，那么将立刻结束宏 2 的运行，而继续执行宏 1 中的下一行代码，这种情况可能会使整个代码包含了不可预知的错误，因此务必要小心。

Resume 语句

　　在错误处理程序结束后，恢复原有的运行。

语句	描述
Resume	如果错误和错误处理程序出现在同一个过程中，则从产生错误的语句恢复运行。如果错误出现在被调用的过程中，则从最近一次调用包含错误处理程序的过程的语句处恢复运行
Resume Next	如果错误和错误处理程序出现在同一个程序中，则从紧随产生错误的语句的下个语句恢复运行。如果错误发生在被调用的过程中，则对最后一次调用包含错误处理程序的过程的语句（或 On Error Resume Next 语句），从紧随该语句之后的语句处恢复运行。
Resume line	在必要的 line 参数指定的 line 处恢复运行。line 参数是行标签或行号，必须和错误处理程序在同一个过程中。

 

On Error 语句
　　启动一个错误处理程序并指定该子程序在一个过程中的位置；也可用来禁止一个错误处理程序。

语句	描述
On Error GoTo line	启动错误处理程序，且该例程从必要的 line 参数中指定的line 开始。line 参数可以是任何行标签或行号。如果发生一个运行时错误，则控件会跳到 line，激活错误处理程序。指定的 line 必须在一个过程中，这个过程与 On Error 语句相同； 否则会发生编译时间错误。
On Error Resume Next	说明当一个运行时错误发生时，控件转到紧接着发生错误的语句之后的语句，并在此继续运行。访问对象时要使用这种形式而不使用 On Error GoTo。
On Error GoTo 0	禁止当前过程中任何已启动的错误处理程序。

 

 

　　错误处理程序依靠 Err 对象的 Number 属性中的值来确定错误发生的原因。在其它任何错误发生之前，或在调用一个可能会导致错误发生的过程之前，错误处理程序应该先测试或存储 Err 对象中相关的属性值。Err 对象中的属性值只反映最近发生的错误。Err.Description 中包含有与 Err.Number 相关联的错误信息。

　　On Error GoTo 0 停止在当前过程中处理错误。即使过程中包含编号为 0 的行，它也不把行 0 指定为处理错误的代码的起点。如果没有 On Error GoTo 0 语句，在退出过程时，错误处理程序会自动关闭。

 

摘：https://blog.csdn.net/daihongliu/article/details/78285088