如何在 SQL Server 2005 实例之间传输登录和密码

如何在 SQL Server 2005 实例之间传输登录和密码

CREATE LOGIN (Transact-SQL)

如何在 SQL Server 2005 实例之间传输登录和密码
--http://support.microsoft.com/kb/918992
--本文介绍如何在不同服务器上的 Microsoft SQL Server 2005 实例之间传输登录和密码。

--有关如何在其他版本的 SQL Server 实例之间传输登录和密码的更多信息，请单击下面的文章编号，以查看 Microsoft 知识库中相应的文章：
--246133 如何在 SQL Server 实例之间传输登录和密码
--回到顶端 | 提供反馈
--更多信息
--在本文中，服务器 A 和服务器 B 是不同的服务器。另外，服务器 A 和服务器 B 都在运行 SQL Server 2005。

--在将一个数据库从服务器 A 上的 SQL Server 实例移动到服务器 B 上的 SQL Server 实例之后，用户可能无法登录到移至服务器 B 上的数据库。而且，用户可能会收到以下消息：
--用户“MyUser”登录失败。(Microsoft SQL Server，错误:18456)
--出现此问题的原因是，您未将登录和密码从服务器 A 上的 SQL Server 实例传输到服务器 B 上的 SQL Server 实例。

--若要将登录和密码从服务器 A 上的 SQL Server 实例传输到服务器 B 上的 SQL Server 实例，请执行以下步骤：

--1. 在服务器 A 上，启动 SQL Server Management Studio，然后连接到要从中移动数据库的 SQL Server 实例。
--2. 打开新的查询编辑器窗口，然后运行以下脚本。
USE master
GO
IF OBJECT_ID ( 'sp_hexadecimal') IS NOT NULL
    DROP PROCEDURE sp_hexadecimal
GO
CREATE PROCEDURE sp_hexadecimal
    @binvalue VARBINARY (256 ) ,
    @hexvalue VARCHAR (514 ) OUTPUT
AS
    DECLARE @charvalue VARCHAR ( 514)
    DECLARE @i INT
    DECLARE @length INT
    DECLARE @hexstring CHAR ( 16)
    SELECT  @charvalue = '0x'
    SELECT  @i = 1
    SELECT  @length = DATALENGTH( @binvalue )
    SELECT  @hexstring = '0123456789ABCDEF'
    WHILE ( @i <= @length )
        BEGIN
            DECLARE @tempint INT
            DECLARE @firstint INT
            DECLARE @secondint INT
            SELECT   @tempint = CONVERT (INT , SUBSTRING ( @binvalue, @i, 1 ))
            SELECT   @firstint = FLOOR (@tempint / 16 )
            SELECT   @secondint = @tempint - ( @firstint * 16 )
            SELECT   @charvalue = @charvalue + SUBSTRING( @hexstring ,
                                                        @firstint + 1 , 1)
                    + SUBSTRING ( @hexstring, @secondint + 1, 1 )
            SELECT   @i = @i + 1
        END

    SELECT  @hexvalue = @charvalue
GO
 
IF OBJECT_ID ( 'sp_help_revlogin') IS NOT NULL
    DROP PROCEDURE sp_help_revlogin
GO
CREATE PROCEDURE sp_help_revlogin
    @login_name SYSNAME = NULL
AS
    DECLARE @name SYSNAME
    DECLARE @type VARCHAR ( 1)
    DECLARE @hasaccess INT
    DECLARE @denylogin INT
    DECLARE @is_disabled INT
    DECLARE @PWD_varbinary VARBINARY ( 256)
    DECLARE @PWD_string VARCHAR ( 514)
    DECLARE @SID_varbinary VARBINARY ( 85)
    DECLARE @SID_string VARCHAR ( 514)
    DECLARE @tmpstr VARCHAR ( 1024)
    DECLARE @is_policy_checked VARCHAR ( 3)
    DECLARE @is_expiration_checked VARCHAR ( 3)

    DECLARE @defaultdb SYSNAME
 
    IF ( @login_name IS NULL )
        DECLARE login_curs CURSOR
        FOR
            SELECT   p . sid ,
                    p .name ,
                    p .type ,
                    p .is_disabled ,
                    p .default_database_name ,
                    l .hasaccess ,
                    l .denylogin
            FROM     sys . server_principals p
                    LEFT JOIN sys. syslogins l ON ( l. name = p. name )
            WHERE    p . type IN ( 'S', 'G', 'U' )
                    AND p . name <> 'sa'
    ELSE
        DECLARE login_curs CURSOR
        FOR
            SELECT   p . sid ,
                    p .name ,
                    p .type ,
                    p .is_disabled ,
                    p .default_database_name ,
                    l .hasaccess ,
                    l .denylogin
            FROM     sys . server_principals p
                    LEFT JOIN sys. syslogins l ON ( l. name = p. name )
            WHERE    p . type IN ( 'S', 'G', 'U' )
                    AND p . name = @login_name
    OPEN login_curs

    FETCH NEXT FROM login_curs INTO @SID_varbinary , @name , @type , @is_disabled ,
        @defaultdb , @hasaccess , @denylogin
    IF ( @@fetch_status = - 1 )
        BEGIN
            PRINT 'No login(s) found.'
            CLOSE login_curs
            DEALLOCATE login_curs
            RETURN - 1
        END
    SET @tmpstr = '/* sp_help_revlogin script '
    PRINT @tmpstr
    SET @tmpstr = '** Generated ' + CONVERT (VARCHAR , GETDATE ()) + ' on '
        + @@SERVERNAME + ' */'
    PRINT @tmpstr
    PRINT ''
    WHILE ( @@fetch_status <> - 1 )
        BEGIN
            IF ( @@fetch_status <> -2 )
                BEGIN
                    PRINT ''
                    SET @tmpstr = '-- Login: ' + @name
                    PRINT @tmpstr
                    IF ( @type IN ( 'G' , 'U' ) )
                        BEGIN -- NT authenticated account/group

                            SET @tmpstr = 'CREATE LOGIN ' + QUOTENAME (@name )
                                + ' FROM WINDOWS WITH DEFAULT_DATABASE = ['
                                + @defaultdb + ']'
                        END
                    ELSE
                        BEGIN -- SQL Server authentication
        -- obtain password and sid
                            SET @PWD_varbinary = CAST (LOGINPROPERTY ( @name,
                                                              'PasswordHash' ) AS VARBINARY ( 256))
                            EXEC sp_hexadecimal @PWD_varbinary,
                                @PWD_string OUT
                            EXEC sp_hexadecimal @SID_varbinary,
                                @SID_string OUT
 
        -- obtain password policy state
                            SELECT   @is_policy_checked = CASE is_policy_checked
                                                           WHEN 1 THEN 'ON'
                                                           WHEN 0 THEN 'OFF'
                                                           ELSE NULL
                                                         END
                            FROM     sys . sql_logins
                            WHERE    name = @name
                            SELECT   @is_expiration_checked = CASE is_expiration_checked
                                                              WHEN 1 THEN 'ON'
                                                              WHEN 0
                                                              THEN 'OFF'
                                                              ELSE NULL
                                                             END
                            FROM     sys . sql_logins
                            WHERE    name = @name
 
                            SET @tmpstr = 'CREATE LOGIN ' + QUOTENAME (@name )
                                + ' WITH PASSWORD = ' + @PWD_string
                                + ' HASHED, SID = ' + @SID_string
                                + ', DEFAULT_DATABASE = [' + @defaultdb + ']'

                            IF ( @is_policy_checked IS NOT NULL )
                                BEGIN
                                    SET @tmpstr = @tmpstr
                                        + ', CHECK_POLICY = '
                                        + @is_policy_checked
                                END
                            IF ( @is_expiration_checked IS NOT NULL )
                                BEGIN
                                    SET @tmpstr = @tmpstr
                                        + ', CHECK_EXPIRATION = '
                                        + @is_expiration_checked
                                END
                        END
                    IF ( @denylogin = 1 )
                        BEGIN -- login is denied access
                            SET @tmpstr = @tmpstr + '; DENY CONNECT SQL TO '
                                + QUOTENAME ( @name)
                        END
                    ELSE
                        IF ( @hasaccess = 0 )
                            BEGIN -- login exists but does not have access
                                SET @tmpstr = @tmpstr
                                    + '; REVOKE CONNECT SQL TO '
                                    + QUOTENAME ( @name)
                            END
                    IF ( @is_disabled = 1 )
                        BEGIN -- login is disabled
                            SET @tmpstr = @tmpstr + '; ALTER LOGIN '
                                + QUOTENAME ( @name) + ' DISABLE'
                        END
                    PRINT @tmpstr
                END

            FETCH NEXT FROM login_curs INTO @SID_varbinary, @name, @type ,
                @is_disabled , @defaultdb , @hasaccess , @denylogin
        END
    CLOSE login_curs
    DEALLOCATE login_curs
    RETURN 0
GO

--注意：此脚本会在“master”数据库中创建两个存储过程。两个存储过程分别命名为“sp_hexadecimal”存储过程和“sp_help_revlogin”存储过程。
--3. 运行下面的语句。
--EXEC sp_help_revlogin
--由“sp_help_revlogin”存储过程生成的输出脚本是登录脚本。此登录脚本创建具有原始安全标识符 (SID) 和原始密码的登录。
--4. 在服务器 B 上，启动 SQL Server Management Studio，然后连接到您将数据库移动到的 SQL Server 实例。

--重要信息：在执行步骤 5 之前，请检查“备注”一节中的信息。
--5. 打开新的查询编辑器窗口，然后运行步骤 3 中生成的输出脚本。

--备注
--在对服务器 B 的实例上运行输出脚本之前，请检查以下信息：

--* 仔细检查输出脚本。如果服务器 A 和服务器 B 处在不同的域中，则必须修改输出脚本。然后，必须在 CREATE LOGIN 语句中使用新的域名来替换原始域名。新的域中授予访问权限的集成登录不会具有与原始域中的登录相同的 SID。因此，用户会从这些登录中孤立出来。 有关如何解决这些孤立用户的更多信息，请单击下面的文章编号，以查看 Microsoft 知识库中相应的文章：
--240872 如何解决在运行 SQL Server 的服务器之间移动数据库时的权限问题
--如果服务器 A 和服务器 B 处于同一域中，则使用相同的 SID。因此，用户不可能是孤立的。
--* 在输出脚本中，通过使用加密密码来创建登录。这是因为 CREATE LOGIN 语句中使用了 HASHED 参数。此参数指定在 PASSWORD 参数后输入的密码已经过哈希处理。
--* 默认情况下，只有“sysadmin”固定服务器角色的成员可以从“sys.server_principals”视图运行 SELECT 语句。除非“sysadmin”固定服务器角色的成员授予用户必需的权限，否则用户无法创建或运行输出脚本。
--* 本文中的步骤不会为特定登录传输默认数据库信息。这是因为默认数据库不可能总是存在于服务器 B 上。若要定义某个登录的默认数据库，请使用 ALTER LOGIN 语句，并传入登录名和默认数据库作为参数。
--* 服务器 A 的排序顺序可能不区分大小写，而服务器 B 的排序顺序可能区分大小写。在此情况下，当您将登录和密码传输到服务器 B 上的实例之后，必须以大写字母的形式来键入密码中的所有字母。

--或者，服务器 A 的排序顺序可能区分大小写，而服务器 B 的排序顺序可能不区分大小写。在此情况下，您将无法使用传输到服务器 B 上的实例的登录和密码进行登录，除非满足下面的条件之一：

--* 原始密码不包含字母。
--* 原始密码中的所有字母都是大写字母。
--服务器 A 和服务器 B 的排序顺序可能都区分大小写，或者可能都不区分大小写。在这些情况下，用户不会遇到问题。
--* 已经位于服务器 B 上的实例中的登录可能具有与输出脚本中的某个名称相同的名称。在此情况下，当对服务器 B 上的实例运行输出脚本时，会接收到下面的错误消息：
--消息 15025，级别 16，状态 1，行 1
--服务器主体 'MyLogin' 已存在。
--类似地，已经位于服务器 B 上的实例中的登录可能具有与输出脚本中的某个 SID 相同的 SID。在此情况下，当对服务器 B 上的实例运行输出脚本时，会接收到下面的错误消息：
--消息 15433，级别 16，状态 1，行 1
--所提供的参数 sid 正在使用。
--因此，必须执行以下操作：

--1. 仔细检查输出脚本。
--2. 检查服务器 B 上的实例中的“sys.server_principals”视图的内容。
--3. 相应地解决这些错误消息。

--* 在 SQL Server 2005 中，登录的 SID 用作实现数据库级别访问的基础。一个登录可能在服务器的两个不同数据库中具有两个不同的 SID。在此情况下，该登录只可以访问具有与“sys.server_principals”视图中的 SID 匹配的 SID 的数据库。在从两个不同的服务器合并这两个数据库时，可能会出现此问题。若要解决此问题，可使用 DROP USERT 语句，从具有不匹配的 SID 的数据库中手动删除相应的登录。然后，通过使用 CREATE USER 语句再次添加该登录。

--回到顶端 | 提供反馈
--参考
--有关如何解决孤立用户问题的更多信息，请访问以下 Microsoft Developer Network (MSDN) 网站：
--http://msdn2.microsoft.com/zh-cn/library/ms175475.aspx
--有关 CREATE LOGIN 语句的更多信息，请访问下面的 MSDN 网站：
--http://msdn2.microsoft.com/zh-cn/library/ms189751.aspx
--有关 ALTER LOGIN 语句的更多信息，请访问下面的 MSDN 网站：
--http://msdn2.microsoft.com/zh-cn/library/ms189828.aspx
--回到顶端 | 提供反馈
  

 --3. 运行下面的语句。
EXEC sp_help_revlogin
--由“sp_help_revlogin”存储过程生成的输出脚本是登录脚本。此登录脚本创建具有原始安全标识符 (SID) 和原始密码的登录。

/* sp_help_revlogin script 
** Generated 12 20 2013  8:19PM on JOE\SQL2012 */
 
 
-- Login: ##MS_PolicyTsqlExecutionLogin##
CREATE LOGIN [##MS_PolicyTsqlExecutionLogin##] WITH PASSWORD = 0x0200AE58A58B8176D7B99F6E153821591CA0C961A49034946C6F8FC4C588363AE1CF00CCEC2FCC4BCEB86CE8EC6EB0B46ADE593A716607B6D2F22A660CDC7DA9EBD51E6E01FC HASHED,  SID = 0xFB5428192C68DE479445435923D3CE58, DEFAULT_DATABASE = [master], CHECK_POLICY = ON, CHECK_EXPIRATION = OFF; ALTER LOGIN [##MS_PolicyTsqlExecutionLogin##] DISABLE
 
-- Login: JOE\Administrator
CREATE LOGIN [JOE\Administrator] FROM WINDOWS WITH DEFAULT_DATABASE = [master]
 
-- Login: NT SERVICE\SQLWriter
CREATE LOGIN [NT SERVICE\SQLWriter] FROM WINDOWS WITH DEFAULT_DATABASE = [master]
 
-- Login: NT SERVICE\Winmgmt
CREATE LOGIN [NT SERVICE\Winmgmt] FROM WINDOWS WITH DEFAULT_DATABASE = [master]
 
-- Login: NT Service\MSSQL$SQL2012
CREATE LOGIN [NT Service\MSSQL$SQL2012] FROM WINDOWS WITH DEFAULT_DATABASE = [master]
 
-- Login: NT AUTHORITY\SYSTEM
CREATE LOGIN [NT AUTHORITY\SYSTEM] FROM WINDOWS WITH DEFAULT_DATABASE = [master]
 
-- Login: NT SERVICE\SQLAgent$SQL2012
CREATE LOGIN [NT SERVICE\SQLAgent$SQL2012] FROM WINDOWS WITH DEFAULT_DATABASE = [master]
 
-- Login: NT SERVICE\ReportServer$SQL2012
CREATE LOGIN [NT SERVICE\ReportServer$SQL2012] FROM WINDOWS WITH DEFAULT_DATABASE = [master]
 
-- Login: ##MS_PolicyEventProcessingLogin##
CREATE LOGIN [##MS_PolicyEventProcessingLogin##] WITH PASSWORD = 0x02003733615D2133A632CF43E59C182337C512C7813C0E382E4FF79D81136335306B0F7774C4CB93561716F4E7D3C30E3AFF7CF4F4B007B2807AFAD36F5A4AA7CFDD2B274A99 HASHED,  SID = 0xA2892B9877725C40BAE347190FC4396B, DEFAULT_DATABASE = [master], CHECK_POLICY = ON, CHECK_EXPIRATION = OFF; ALTER LOGIN [##MS_PolicyEventProcessingLogin##] DISABLE
 
-- Login: hengshan
CREATE LOGIN [hengshan] WITH PASSWORD = 0x02007A0556532EDD794355D532FA0A7D36516AE57FB4544209D2BE2B1EA43788811A7BE31A3D1A7A2C611EC213F98A738023DED8624B2BAA9B9EECF0935849989895F107643F HASHED,  SID = 0xA69177FD8FEFCF45AE23A9146C05A925, DEFAULT_DATABASE = [master], CHECK_POLICY = ON, CHECK_EXPIRATION = OFF