实验4 8086标志寄存器及中断

1. 实验任务1

验证性实验：有些汇编指令会影响到标志寄存器中的一个或多个状态标志位。

在debug环境中，分别实践、观察：

① add指令对标志寄存器中的零标志位ZF(Zero Flag)、进位标志位CF(Carry Flag)是否有影响？

　　add指令会影响ZF,CF标志寄存器的值。

② inc指令对标志寄存器中的零标志位ZF(Zero Flag)、进位标志位CF(Carry Flag)是否有影响？

　　inc指令会影响ZF的值，但不会影响CF的值。

assume cs:code, ds:data

data segment
   x dw 1020h, 2240h, 9522h, 5060h, 3359h, 6652h, 2530h, 7031h
   y dw 3210h, 5510h, 6066h, 5121h, 8801h, 6210h, 7119h, 3912h
data ends
code segment 
start:
    mov ax, data
    mov ds, ax
    mov si, offset x
    mov di, offset y
    call add128

    mov ah, 4ch
    int 21h

add128:
    push ax
    push cx
    push si
    push di

    sub ax, ax

    mov cx, 8
s:  mov ax, [si]
    adc ax, [di]
    mov [si], ax

    inc si
    inc si
    inc di
    inc di
    loop s

    pop di
    pop si
    pop cx
    pop ax
    ret
code ends
end start

对程序进行汇编、链接，得到可执行程序task1.exe。在debug中调试程序，并回答问题。

① line31~line34的4条inc指令，能否替换成如下代码？你的结论的依据/理由是什么？

　　add si, 2

　　add di, 2

 

 本程序中可以替换，debug环境下可以看出，两种代码最终运算结果一致。

因为adc指令做加法时会带上CF标识符，但在本次实验中，只做了8次循环，当add si,2执行第8次后，CF标识符被更改，但是此时循环已经结束，CF的值不会再影响后续结果。

② 在debug中调试，观察数据段中做128位加之前，和，加之后，数据段的值的变化。

执行加法前：

 执行加法后：

 

 

 

实验任务2

assume cs:code, ds:data
data segment
        str db 80 dup(?)
data ends

code segment
start:  
        mov ax, data
        mov ds, ax
        mov si, 0
s1:        
        mov ah, 1
        int 21h
        mov [si], al
        cmp al, '#'
        je next
        inc si
        jmp s1
next:
        mov ah, 2
        mov dl, 0ah
        int 21h
        
        mov cx, si
        mov si, 0
s2:     mov ah, 2
        mov dl, [si]
        int 21h
        inc si
        loop s2

        mov ah, 4ch
        int 21h
code ends
end start

对源程序task2.asm进行汇编、链接，得到可执行文件task2.exe。

运行程序，从键盘上输入一串字符，以#结束（比如，输入George Orwell, 1984#)，观察结果。结合运

行结果，理解代码并回答问题：

① 汇编指令代码line11-18，实现的功能是？

    使用int 21h中断的1号子功能，实现从键盘输入一个字符，存放在data段；若字符不为#，循环输入；否则跳转到标号为next的程序段。

② 汇编指令代码line20-22，实现的功能是？

    使用int 21h的2号子功能，输出ASCII码值为0ah的字符，即换行符。

③ 汇编指令代码line24-30，实现的功能是？

    使用int 21h的2号子功能，实现循环输出data段中存放的字符。

 

 

 

实验任务3 

编写8086汇编源程序task3.asm，在屏幕上以十进制形式输出data段中这一组连续的数据，数据和数据之间以空格间隔。

data segment

　　x dw 91, 792, 8536, 65521, 2021

　　len equ $ - x

data ends

要求：

　　编写子程序printNumber

　　　　功能：以十进制形式输出一个任意位数的整数（整数范围0 ~ 65535）

　　　　入口参数：寄存器ax（待输出的数据 --> ax）

　　　　出口参数：无

　　编写子程序printSpace

　　　　功能：打印一个空格

　　　　入口参数：无

　　　　出口参数：无

在主体代码中，综合应用寻址方式和循环，调用printNumber和printSpace, 实现题目要求。

assume ds:data,cs:code

data segment 
    x dw 91, 792, 8536, 65521, 2021
    len equ $- x 
data ends

code segment
start:
    mov ax, data
    mov ds, ax

    mov bx,0
    mov cx,5

s:    mov ax,[bx]
    push cx
    push bx
    call printNumber
    pop bx
    pop cx
    add bx,2
    loop s

    mov ax, 4c00h
    int 21h

printNumber:
    mov si,0
    mov bx,10
s1:    mov dx,0
    div bx
     push dx
    inc si
    cmp ax,0
    jne s1

    mov cx,si
s2:    pop ax
    mov ah,2
    add al,48
    mov dl,al
    int 21h
    loop s2
    
    call printSpace
    ret

printSpace:
    mov ah, 2
    mov dl, ' '
    int 21h
    ret

code ends
end start

运行结果：

 

 

 

实验任务4

编写8086汇编源程序task4.asm，将data段中字符串里的小写字符转换成大写。

data segment

　　str db "assembly language, it's not difficult but tedious"

　　len equ $ - str

data ends

要求：

　　编写子程序strupr

　　功能：将包含任意字符的字符串中的小写字母变成大写

　　入口参数

　　　　(ds:si ) 字符串首地址的段地址和偏移地址分别送至ds和si

　　　　(cx) 字符串的长度

　　出口参数：无

在主体代码中，设置入口参数，调用strupr, 实现题目要求

assume ds:data,cs:code

data segment
        str db "assembly language, it's not difficult but tedious"
        len equ $ - str 
data ends

code segment
start:
    mov ax, data
    mov ds, ax

    mov si,0
    mov cx,len

    call strupr

    mov ax, 4c00h
    int 21h

strupr:
s:    mov al,[si]
    cmp al,'a'
    jge great;大于a跳转到great
    jmp print

next:    inc si
    loop s
    ret
    
great:    cmp al,'z'
    jle change;小于z跳转到change
    jmp print

change:    and al, 0dfh;小写转大写
    mov [si],al
    jmp print

print:    mov ah,2
    mov dl,al
    int 21h;输出字符
    jmp next
    
code ends
end start

运行结果：

 

 

 

实验任务5

对源程序task5.asm进行汇编、链接，得到可执行文件task5.exe。

运行程序，输入7，观察结果。输入其他字符，观察结果。结合运行结果和注释，理解代码实现的功能。

assume cs:code, ds:data

data segment
    str1 db "yes", '$'
    str2 db "no", '$'
data ends

code segment
start:
    mov ax, data
    mov ds, ax

    mov ah, 1
    int 21h        ;从键盘输入字符

    mov ah, 2
    mov bh, 0
    mov dh, 24    ;设置光标位置在第24行
    mov dl, 70    ;设置光标位置在第70列
    int 10h        ;设置光标位置

    cmp al, '7'
    je s1
    mov ah, 9
    mov dx, offset str2
    int 21h        ;显示标号str2处的字符串

    jmp over

s1: mov ah, 9
    mov dx, offset str1
    int 21h        ;显示标号str1处的字符串
over:  
    mov ah, 4ch
    int 21h
code ends
end start

 

程序功能：从键盘输入一个字符，若字符为7，则在第24行70列输出yes；否则输出no

 

 

 

实验任务6

本实验任务中，要求自行实现一个42号软中断例程，使得通过 int 42 或 int 2ah 软中断调用，实现在屏幕最下方中间以黑底绿字打印"welcome to 2049!"。

assume cs:code

code segment
start:
    ; 42 interrupt routine install code
    mov ax, cs
    mov ds, ax
    mov si, offset int42  ; set ds:si

    mov ax, 0
    mov es, ax
    mov di, 200h        ; set es:di

    mov cx, offset int42_end - offset int42
    cld
    rep movsb

    ; set IVT(Interrupt Vector Table)
    mov ax, 0
    mov es, ax
    mov word ptr es:[42*4], 200h
    mov word ptr es:[42*4+2], 0

    mov ah, 4ch
    int 21h

int42: 
    jmp short int42_start
    str db "welcome to 2049!"
    len equ $ - str

    ; display string "welcome to 2049!"
int42_start:
    mov ax, cs
    mov ds, ax
    mov si, 202h

    mov ax, 0b800h
    mov es, ax
    mov di, 24*160 + 32*2

    mov cx, len
s:  mov al, [si]
    mov es:[di], al
    mov byte ptr es:[di+1], 2
    inc si
    add di, 2
    loop s

    iret
int42_end:
   nop
code ends
end start

assume cs:code

code segment
start:
    int 42

    mov ah, 4ch
    int 21h
code ends
end start

运行结果：