裸机利用PE安装win7_vhd系统

 工具win7内核的PE,windows vhd辅助处理的工具,win7原版镜像

附上 windows vhd辅助处理的工具

https://files.cnblogs.com/lovexinsky/VHD_OneKey_2011.rar

U盘PE的制作我就不多讲了下载一个有win7内核的PE安装到U盘就可以了。
1.win键+r打开运行键入 diskpart
2.list disk
3.select disk=0
4.create partition primary size=100  (创建一个100M的主分区)  我一般都自己做个100M分区来做引导
5.active           (设置当前分区为活动) 
6.assign letter=s  (分配驱动器号s并装载) 
7.format fs=ntfs quick label=boot   (快速格式化为ntfs格式) 
8.create partition primary (创建主分区,可加参数size=N,N的单位为M) 
9.assign letter=c  (分配驱动器号c并装载)
10.format fs=ntfs quick (快速格式化为ntfs格式)
11.用虚拟光驱加载win7镜像
12.用windows vhd辅助处理的工具来安装
如图

等待：提示操作完成
13.向100M的主分区中写入boot信息 
   bcdboot C:\windows /s s:       C:\windows表示你安装的系统的目录
安装完成重启你的电脑你就可以看到安装启动界面了！

等安装完后我们在用PE对系统进行差分
同样进入PE利用windows vhd辅助处理的工具来做差分
如图

或者是用命令进入diskpart
键入create vdisk file=D:\WIN7_VHD\WIN7_V_CHILD.VHD parent=D:\WIN7_VHD\WIN7.VHD （创建差分VHD，主VHD设置成刚才创建的）
用辅助工具把  WIN7_V_CHILD.VHD加入引导如图

完成差分。重启你就可以看到启动目录了！

 

顺便附上vhd一件挂载/卸载批处理

@echo off
if "%~n1"=="" goto :install
set "diskpart=echo exit|%ComSpec%/kprompt %%dsc%%$_|diskpart"
if "%~1"=="PARENT" goto :PARENT

:attach
title ====VHD_MNT by chenall======正在自动检测....
set dsc=list$Svdisk
%diskpart%|find /i "%~1" >nul && goto :detach
title ====VHD_MNT by chenall====@@附加VHD@@ %*
set dsc=select$Svdisk$Sfile="%~f1"$_attach$Svdisk$S%2$_
goto :diskpart

:detach
title ====VHD_MNT by chenall====@@分离VHD文件@@%*
set dsc=select$Svdisk$Sfile="%~f1"$_detach$Svdisk$_
goto :diskpart

:PARENT
shift
for /l %%i in (1,1,99) do if not exist "%~dpn1_s%%i.vhd" (set "file=%~n1_s%%i.vhd"&goto :create)

exit /b

:create
title ====VHD_MNT by chenall====@@创建差异VHD文件@@
echo.
echo.
echo. VHD_MNT 创建一个差异VHD镜像文件.
echo. 来源: %1
echo.
echo. 请输入要创建的差异VHD文件名.直接回车使用%file%
echo. 注:不要输入路径名.
echo.
set /pfile=差异VHD:
set dsc=create$Svdisk$Sfile="%~dp1%file%"$SPARENT="%~f1"$_
title ====VHD_MNT by chenall====@@创建差异VHD文件@@%file%

:diskpart
%diskpart%
pause
exit /b

:install
reg query "HKCR\.vhd\shell\@附加/分离\command" /ve 1>nul 2>nul && goto :uninstall
reg add "HKCR\.vhd\shell\@附加/分离\command" /d "vhd_mnt.cmd %%1" /f >nul
reg add "HKCR\.vhd\shell\创建差异VHD\command" /d "vhd_mnt.cmd PARENT=%%1" /f >nul
reg add "HKCR\.vhd\DefaultIcon" /d "%%SystemRoot%%\\system32\\shell32.dll,8" /f >nul
copy /y "%~f0" "%SystemRoot%\system32\vhd_mnt.cmd" >nul
echo.
echo. .VHD文件默认文件设置完成.
echo.
echo. 现在可以直接双击.VHD文件来自动挂载/卸载了(如果已经挂载再次双击该文件时自动卸载)
echo. 
echo. VHD文件快速挂载/卸载工具 by chenall 2011-04-29
echo.                http://chenall.net/post/vhd_mnt
pause
exit

:uninstall
echo.
reg delete "HKCR\.vhd\shell" /f >nul
del /f "%SystemRoot%\system32\vhd_mnt.cmd"
echo.
echo. 已经取消.VHD的默认关联,如果需要双击VHD自动挂载/卸载请再次执行本程序.
echo.
echo. VHD文件快速挂载/卸载工具 by chenall 2011-04-29
echo.                http://chenall.net/post/vhd_mnt
pause
exit

保存为bat文件执行就可以了。