【学习笔记】函数高级使用技巧：利用函数返回函数

【殿堂之路】P70页

原文引用：“有一个proxyObject对象，我们希望根据proxy对象的内容来确定一个方法，处理myObj对象。当proxyObject时字符串时，我们又希望根据字符串的内容来确定返回不同的函数（或方法）。这些函数参数和类型是不完全相同的，有的可能是一个参数，有的可能是多个参数，不同类型。此方法编译器无法检查错误，需要使用者清楚管理好每个目标函数和判断逻辑，否则容易出错。”

//通过A调用只有一个参数的aFunc()
chooseFuncBy("A")("A func has only one parameter");
trace("\n****************\n");

//通过B调用有两个参数的bFunc()
chooseFuncBy("B")("B func has two parameters.","The NO.2 parameter");
trace("\n****************\n");

//input没有匹配到对应的字符串，故调用默认函数kingdaFunc
chooseFuncBy("Hello")("Haha");
trace("\n****************\n");

//初始化两对象
var withObj:Object = new Object();
var myObj:Object = {Name:"Louisluo",Blog:"http://www.cnblogs.com/louisluo77/",hobby:"ActionScript 3"};

//withObj作为chooseFuncBy函数的判断依据，myObj作为参数传递给所要调用的函数
chooseFuncBy(withObj)(myObj);

//定义chooseFuncBy函数，里面有两个条件判断：利用参数的个数，is确定不同类的实例，达到
//选择函数的目的。此外，还可以在这里可以添加其他的条件判断，从而达到拓展运用的目的
function chooseFuncBy(input:*):Function
{
    if (! (input is String))
    {
        return objectFunc;
    }
    switch (input)
    {
        case "A" :
            return aFunc;
        case "B" :
            return bFunc;
        default :
            return kingdaFunc;
    }
}

function aFunc(nS:String):void
{
    trace("aFunc():"+nS);
}

function bFunc(nS:String,nP:String):void
{
    trace("bFunc():"+nS+" one more Parameter:"+nP);
}

function kingdaFunc(...rest):void
{
    trace("Welcome to  Louisluo's blog!");
}

//kingdaObj相当于代理对象，而myObj是被代理对象
function objectFunc(kingdaObj:Object):void
{
    trace("objectFunc():");
    for (var i in kingdaObj)
    {
        trace(i+":"+kingdaObj[i]);
    }
}


/*输出如下：
aFunc():A func has only one parameter

****************

bFunc():B func has two parameters. one more Parameter:The NO.2 parameter

****************

Welcome to  Louisluo's blog!

****************

objectFunc():
Name:Louisluo
Blog:http://www.cnblogs.com/louisluo77/
hobby:ActionScript 3
*/

我的心得：

 暂时还不知道实际应用中，如何灵活地用到这种方法，但是现在先记录下来。希望以后能用上。