flash瘦身技巧-动态加载swc

程序需要额外的第三方库，如：A.swf和B.swf都需要一样的第三方裤（C.swc），但flash编译后A.swf和B.swf都完全包含了C.swc，增加了swf文件大小。动态加载可以给swf瘦身。

swc库文件其实是个压缩文档，把swc改成zip文件可以看到里面包含了library.swf和catalog.xml两个文件。（完全可以把library.swf解压出来像加载普通swf文件一样处理）

程序需要用到FZip第三方库，要编译通过在这里下载。http://codeazur.com.br/lab/fzip/

package 
{
    import deng.fzip.FZip;
    import deng.fzip.FZipFile;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.net.URLRequest;
    import flash.system.ApplicationDomain;
    import flash.system.LoaderContext;
    import flash.utils.getDefinitionByName;

    public class Main extends Sprite 
    {
        
        public function Main():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);
        }
        
        private function init(e:Event = null):void 
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);
            start();
        }
        
        private function start():void
        {
            var zip:FZip = new FZip();
            zip.addEventListener(Event.COMPLETE, onLoadSWC);
            zip.load(new URLRequest("../lib/lib.swc"));
        }
        
        private function onLoadSWC(e:Event):void
        {
            var zip:FZip = e.target as FZip;
            var zipFile:FZipFile = zip.getFileByName("library.swf");
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onLoad);
            loader.loadBytes(zipFile.content, new LoaderContext(false, ApplicationDomain.currentDomain, null));
        }
        
        private function onLoad(e:Event):void
        {
            var mcCls:Class = getDefinitionByName("swcMC") as Class;
            addChild(new mcCls());
        }
    }
    
}