【原题】【搜索】【noip 2003 T4】传染病控制

问题

背景 Background

近来，一种新的传染病肆虐全球。蓬莱国也发现了零星感染者，为防止该病在蓬莱国
大范围流行，该国政府决定不惜一切代价控制传染病的蔓延。不幸的是，由于人们尚未完
全认识这种传染病，难以准确判别病毒携带者，更没有研制出疫苗以保护易感人群。于是，
蓬莱国的疾病控制中心决定采取切断传播途径的方法控制疾病传播。经过 WHO（世界卫
生组织）以及全球各国科研部门的努力，这种新兴传染病的传播途径和控制方法已经研究
消楚，剩下的任务就是由你协助蓬莱国疾控中心制定一个有效的控制办法。

描述 Description

研究表明，这种传染病的传播具有两种很特殊的性质；
第一是它的传播途径是树型的，一个人X只可能被某个特定的人Y感染，只要Y不
得病，或者是XY之间的传播途径被切断，则X就不会得病。
第二是，这种疾病的传播有周期性，在一个疾病传播周期之内，传染病将只会感染一
代患者，而不会再传播给下一代。
这些性质大大减轻了蓬莱国疾病防控的压力，并且他们已经得到了国内部分易感人群
的潜在传播途径图（一棵树）。但是，麻烦还没有结束。由于蓬莱国疾控中心人手不够，同
时也缺乏强大的技术，以致他们在一个疾病传播周期内，只能设法切断一条传播途径，而
没有被控制的传播途径就会引起更多的易感人群被感染（也就是与当前已经被感染的人有
传播途径相连，且连接途径没有被切断的人群）。当不可能有健康人被感染时，疾病就中止
传播。所以，蓬莱国疾控中心要制定出一个切断传播途径的顺序，以使尽量少的人被感染。
你的程序要针对给定的树，找出合适的切断顺序。

输入格式 Input Format

输入格式的第一行是两个整数n（1≤n≤300）和p。表示有N个人，接下来p行，每一行有两个整数i和j，表示节点i和j间有边相连（意即，第i人和第j人之间有传播途径相连）。其中节点1是已经被感染的患者。

输出格式 Output Format

只有一行，输出总共被感染的人数。

 

分析

这是一个树形的数据结构。

我们会想到树形dp，显然，这样不行。贪心？有反例！怎么办？搜索！

我们发现n是300的范围，大致估计一下，应该不会超时。如何确定搜索的状态量，根据题目描述，我们想到用时间来划分阶段，也就是说每一个周期作为一个状态，到一个周期枚举所有的能够删掉的点，其实是将下一层节点的值更改。搜的是这一层，改变的是下一层。直到枚举完这下一层的所有状态，再回溯到这一层的初始状态。这种回溯的思想和平时的深度搜索略显不同，平时是递归完之后马上回溯，而这次不是，仔细思考一下为什么，我在这里就不说了。…………

特别注意，题目并未给出点的关系，也就是说，我们无法确定谁在上层，所以我们读入双向边，之后虚拟1为根节点，然后递归构树。这种思想很有用，有些时候我们的确无法确定关系，再涉及到树结构时，可以采用这种方法，保险起见。

反思

这个搜索很特别，特别是回溯，比较难理解，但其本质没有改变。理解就好。

code

program liukee;
var
  son:array[1..400,0..400] of longint;
  g:array[0..400] of longint;//标记该点在什么时候被传染，不被传染的话值为0
  n,m,now,ans:longint;
procedure init;
var
  i,x,y:longint;
begin
  readln(n,m);
  for i:=1 to m do
  begin
    readln(x,y);//读入双向边
   inc(son[x,0]);son[x,son[x,0]]:=y;
    inc(son[y,0]);son[y,son[y,0]]:=x;
  end;
end;

procedure build(k:longint);
var
  i,j,t:longint;
begin
  for i:=1 to son[k,0] do
  begin
    t:=son[k,i];
    for j:=1 to son[t,0] do
      if son[t,j]=k then break;
    son[t,j]:=son[t,son[t,0]];
    dec(son[t,0]);
    build(t);
  end;
end;
 

procedure dfs(k:longint);
var
  i,j:longint;
  f:boolean;
begin
  if now>ans then exit;//最优性剪枝
  f:=false;//判定边界
  for i:=1 to n do
    if g[i]=k then
      for j:=1 to son[i,0] do
      begin
         inc(now);  
         g[son[i,j]]:=k+1;
         f:=true;
      end;
//枚举当前要控制哪个传染路径
  dec(now);
  for i:=1 to n do
    if g[i]=k+1 then
    begin
       g[i]:=0;
       dfs(k+1);
       g[i]:=k+1;
   end； 
//回溯，回到这个状态的初始值
  inc(now);
  for i:=1 to n do
    if g[i]=k+1 then
    begin
       g[i]:=0;
      dec(now);
    end;
  if (not f) then//达到边界，没有能够继续搜索的状态
    if now<ans then ans:=now;//最优性
end;

begin
  init;
  build(1);
  g[1]:=1;
  now:=1;
  ans:=maxlongint;
  dfs(1);//从1时刻开始搜索
  writeln(ans);
end.