【原题】【noip 2006 T4】【动态规划】2^k进制数（比较特殊）

问题

描述 Description

设r是个2^k 进制数，并满足以下条件：
（1）r至少是个2位的2^k 进制数。
（2）作为2^k进制数，除最后一位外，r的每一位严格小于它右边相邻的那一位。
（3）将r转换为2进制数q后，则q的总位数不超过w。
在这里，正整数k（1≤k≤9）和w（k<w≤30000）是事先给定的。
问：满足上述条件的不同的r共有多少个？
我们再从另一角度作些解释：设S是长度为w 的01字符串（即字符串S由w个“0”或“1”组成），S对应于上述条件（3）中的q。将S从右起划分为若干个长度为k 的段，每段对应一位2k进制的数，如果S至少可分成2段，则S所对应的二进制数又可以转换为上述的2^k 进制数r。
例：设k=3，w=7。则r是个八进制数（2^3=8）。由于w=7，长度为7的01字符串按3位一段分，可分为3段（即1，3，3，左边第一段只有一个二进制位），则满足条件的八进制数有：
2位数：高位为1：6个（即12，13，14，15，16，17），高位为2：5个，…，高位为6：1个（即67）。共6+5+…+1=21个。
3位数：高位只能是1，第2位为2：5个（即123，124，125，126，127），第2位为3：4个，…，第2位为6：1个（即167）。共5+4+…+1=15个。
所以，满足要求的r共有36个。

输入格式 Input Format

输入文件只有1行，为两个正整数，用一个空格隔开：
k W

输出格式 Output Format

输出文件为1行，是一个正整数，为所求的计算结果，即满足条件的不同的r的个数（用十进制数表示），要求最高位不得为0，各数字之间不得插入数字以外的其他字符（例如空格、换行符、逗号等）。
（提示：作为结果的正整数可能很大，但不会超过200位）

 

分析

这道题无法用数学方法解决，我们想到，求方案总数要用递推，那么能否写出方程呢。

我们设f[i,j]表示i位数（从右到左），第i位为j时能产生的所有满足要求的数，根据加法原理：

f[i,j]=f[i-1,j+1]+f[i-1,j+2]………f[i-1,maxnum]显然这样会超时的。我们发现：

f[i,j+1]=f[i-1,j+2]+f[i-1,j+3]+…….+f[i-1,maxnum]那么，这个方程化简为：

f[i,j]=f[i-1,j+1]+f[i,j+1]

除了方程还有几个地方：

1、maxnum的值，我们可以这样看，类似于十进制高精数压位，这是2^k进制，也就是没为压k位二进制。maxnum=1<<k-1(k个1)

   当然有可能给定的w不能整除k，我们就修改n的值，并用top特别的记下第一位数的取值范围。计算方法详见程序

2、方案计算，就是将2~n的每个状态的方案累加，特别注意第一位（也就是从右往左数的第n位），要单独计算。

3、滚动数组，高精度压9位

4、注意题目要求

反思

有些题表面上是数学，其实是考察递推，并不是所有题都能用数学方法解决，递推是个好方法。特别是在解决数据范围极大，或者是统计方案的问题时。要多想，看能否找到方程。不要在不会的数学知识上纠结，最起码，我们还可以——枚举

注意题目要求！！！，记住自己的失误！，一切方法都是基于题目！！！

code

program liukee;
const jz=1000000000;
type arr=array[0..30] of longint;
var
  f:array[0..1,0..1023] of arr;
  ans:arr;
  k,w,maxnum,top,n,i,j:longint;

operator +(a,b:arr)c:arr;
var
  i:longint;
begin
  fillchar(c,sizeof(c),0);
  if a[0]>b[0] then c[0]:=a[0] else c[0]:=b[0];
  for i:=1 to c[0] do
    inc(c[i],a[i]+b[i]);
  for i:=1 to c[0] do
  begin
    inc(c[i+1],c[i] div jz);
	c[i]:=c[i] mod jz;
  end;
  while(c[c[0]+1]>0)do
  begin
    inc(c[0]);
	inc(c[c[0]+1],c[c[0]] div jz);
	c[c[0]]:=c[c[0]] mod jz;
  end;
end;

procedure outit(a:arr);
var
  i:longint;
begin
  write(a[a[0]]);
  for i:=a[0]-1 downto 1 do
  begin
    write(a[i] div 100000000);
	write(a[i] div 10000000 mod 10);
	write(a[i] div 1000000 mod 10);
	write(a[i] div 100000 mod 10);
	write(a[i] div 10000 mod 10);
	write(a[i] div 1000 mod 10);
	write(a[i] div 100 mod 10);
	write(a[i] div 10 mod 10);
	write(a[i] mod 10);
  end;
end;

begin
  readln(k,w);
  n:=w div k;//划分阶段
  maxnum:=(1<<k)-1;//可能达到的数的最大值
  top:=maxnum;
  if (w-n*k)>0 then//最后一位上的数能达到的最大值
  begin
      top:=1<<(w-n*k)-1;
      inc(n);
  end;
  for i:=1 to maxnum do//初始化
  begin
    f[0,i][0]:=1;
    f[0,i][1]:=1;
  end;
  for i:=2 to n do
  begin
    for j:=maxnum downto 1 do
     begin
        f[1,j]:=f[1,j+1]+f[0,j+1];
        if i<>2 then  ans:=ans+f[0,j];
     end;
     f[0]:=f[1];
  end;
  for j:=top downto 1 do
    ans:=ans+f[0,j];
  outit(ans);
end.