【动态规划】新年趣事之打牌

问题

来源： vijos P1071

【问题描述】

过年的时候，大人们最喜欢的活动，就是打牌了。xiaomengxian不会打牌，只好坐在一边看着。

这天，正当一群人打牌打得起劲的时候，突然有人喊道：“这副牌少了几张！”众人一数，果然是少了。于是这副牌的主人得意地说：“这是一幅特制的牌，我知道整副牌每一张的重量。只要我们称一下剩下的牌的总重量，就能知道少了哪些牌了。”大家都觉得这个办法不错，于是称出剩下的牌的总重量，开始计算少了哪些牌。由于数据量比较大，过了不久，大家都算得头晕了。

这时，xiaomengxian大声说：“你们看我的吧！”于是他拿出笔记本电脑，编出了一个程序，很快就把缺少的牌找了出来。

如果是你遇到了这样的情况呢？你能办到同样的事情吗？

【输入文件】

第一行一个整数TotalW，表示剩下的牌的总重量。

第二行一个整数N（1<N<=100），表示这副牌有多少张。

接下来N行，每行一个整数Wi（1<=Wi<=1000），表示每一张牌的重量。

【输出文件】

如果无解，则输出“0”；如果有多解，则输出“-1”；否则，按照升序输出丢失的牌的编号，相邻两个数之间用一个空格隔开。

【输入样例】

270

4

100

110

170

200

【输出样例】

2 4

分析

一看题目我们就知道是背包问题。

注意给出的体积，不是我们要的需要用总体积减去给的体积。

下面可将这个题抽象成一个装箱问题，必须装满。我们很快会想到用boolean类型的动规，但是这样只能判断可行性，对于多解却无能为力。对此我们换一种方程，让方程表示方案总数，方程我在这里不写了。

我们开一个数组path纪录决策，只有当当前体积的方案数为0时，我们纪录决策。（想想为什么）

输出就是递归的输出，和昨天写的那个类似，也是背包问题输出的一般的基本方法

注意方案数有可能很大，所以我们加一句优化，如果方案数大于10000则变成mod 10000的值，由于我们只需要做判定，所以这样是不影响结果的。

反思

有些时候方程的表示无法满足题目的要求，我们考虑更换方程的表示，也许只是用这种表示的某个性质，表面上不能直接看出来。这两天对动规的输出方案有了点感觉，宗旨就是递归，由当前决策推得上一决策。知道推到最初决策在回溯输出即可

注意背包问题的变形

code

program liukee;
var
  v:array[1..100] of longint;
  f,path:array[0..1000500] of longint;
  vtot,n,i,j,sum:longint;

procedure outit(vv:longint);
var
  i:longint;
begin
  if vv=0 then exit;
  outit(vv-v[path[vv]]);
  write(path[vv],' ');
end;

begin
  assign(input,'card.in');reset(input);
  assign(output,'card.out');rewrite(output);
  readln(vtot);
  readln(n);
  for i:=1 to n do
  begin
    readln(v[i]);
	inc(sum,v[i]);
  end;
  vtot:=sum-vtot;
  f[0]:=1;
  for i:=1 to n do
    for j:=vtot downto v[i] do
	begin
          if f[j-v[i]]<>0 then//注意这里的顺序
          begin
            if f[j]=0 then
              path[j]:=i;
	        inc(f[j],f[j-v[i]]);
			if f[j]>10000 then f[j]:=f[j] mod 10000;
          end;
    end;
  if (f[vtot]=0) then
    writeln(0)
  else if f[vtot]>1 then writeln(-1)
  else outit(vtot);
  close(input);
  close(output);
end.