NOIP2011解题报告-Day1

题目：

https://files.cnblogs.com/lijianlin1995/NOIP2011%E6%8F%90%E9%AB%98%E7%BB%84Day1.pdf

        CLJ神犇的NOIP题解应该是最广为流的，但是神犇就是神犇，追求复杂度，方法很高端。所以我写一点能过就行的算法。RQNOJ提交通过了。

铺地毯

        第一感觉二维线段树，发现只查询一个点，可以朴素。如果halt要注意文件操作。

type Tdt=record
      x,y,xl,yl:longint;
      end;
var dt:array[1..10000] of Tdt;
    i,color,n,x,y:longint;
begin
  readln(n);
  for i:=1 to n do
    with dt[i] do
      readln(x,y,xl,yl);
  readln(x,y);
  color:=-1;
  for i:=n downto 1 do
    if (x>=dt[i].x)and(x<=dt[i].x+dt[i].xl)and
       (y>=dt[i].y)and(y<=dt[i].y+dt[i].yl)
         then begin
              color:=i;
              break;
              end;
  writeln(color);
end.

旅馆

        考试的时候写的O(n^2)的算法，枚举左右端点，维护区间最小值，得分很低。

把两个人的住宿位置看做一个闭区间的左右端点。一个合法的区间要求:

        I:含有一个点i满足ok[i]=1

        II:color[l]=color[r]

        求出合法的区间数即为答案。

        维护前缀和，count[i][j]为前1..i颜色j的数量，用指针f记录最后出现ok[i]=1的i。如果一个区间可以由靠左的ok[i]满足，一定可以由区间内靠右的ok[i]满足，不妨让最靠右的ok[i]满足。从1到n枚举区间右端点。通过前缀和计算左端点的方案数。

1.ok[i]=1 可以在i喝咖啡，右边的人可以住的位置是count[i-1][color[i]],f更改为i；(条件I被右端点满足)

2.ok[i]=0 在f喝咖啡，inc(ans,count[f][color[i]]);(条件II被f满足)

program hotel;
const maxn=200000;
var color:array[0..maxn] of byte;
    ok:array[0..maxn] of boolean;
    n,p,k,i,f,t:longint;
    count:array[0..maxn,0..50] of longint;
    ans:int64=0;
begin
fillchar(count,sizeof(count),0);
readln(n,k,p);f:=0;
for i:=1 to n do
  begin
  readln(color[i],t);
  if t<=p then ok[i]:=true
          else ok[i]:=false;
  count[i]:=count[i-1];
  inc(count[i][color[i]]);
  end;
for i:=1 to n do
  begin
  if ok[i] then f:=i-1;
  inc(ans,count[f][color[i]]);
  if ok[i] then inc(f);
  end;
writeln(ans);
end.

 

Mayan游戏

        DFS，复杂度5*7^5=52521875不大，加上下落和清除，期望得分30—100。要注意横纵坐标和行列的关系。几个剪枝和要注意的问题：

1.如果一个方块左边有方块，那左边的方块右移比右边的方块左移优。
２.方块移动以后没有处理下落会WA40
3.读数据出问题，如果一行有7个方块，会有8个数字（最后一个是0），WA20
4.处理消除后的方块下落时下标越界。
5.忘记向左移动 WA60
        2的处理写疵了，索性用了消除后的下落过程。

        考试跟KAC大神同考场，考完大神叹息“我写了3KB”

program mayan;
TYPE Tmap=array[0..4,0..7] of shortint;
var n,i,j,step:longint;
    a:Tmap;
    t:shortint;
    x,y,g:array[1..5] of integer;
procedure swap(var a,b:shortint);
var t:shortint;begin t:=a;a:=b;b:=t;end;
procedure print;
          var i:longint;
          begin
          for i:=1 to step do
            writeln(x[i],' ',y[i],' ',g[i]);
          halt;
          end;
function  clean(var map:Tmap):boolean;
          var i,j,k:integer;
              finish:boolean;
              f:array[0..4,0..6] of boolean;
          begin
          clean:=true;
          fillchar(f,sizeof(f),false);
          for i:=0 to 4 do
            for j:=0 to 6 do
              if map[i][j]<>0 then
                begin
                if(i in [1..3])and
                  (map[i][j]=map[i-1][j])and
                  (map[i][j]=map[i+1][j])
                  then begin
                       f[i][j]:=true;
                       f[i-1][j]:=true;
                       f[i+1][j]:=true;
                       end;
                if(j in [1..5])and
                  (map[i][j]=map[i][j+1])and
                  (map[i][j]=map[i][j-1])
                  then begin
                       f[i][j]:=true;
                       f[i][j+1]:=true;
                       f[i][j-1]:=true;
                       end;
                end;
          for i:=0 to 4 do
            for j:=6 downto 0 do
              if f[i][j] then
                begin
                clean:=false;
                map[i][j]:=0;
                end;
          end;
procedure fall(var map:Tmap);
          var i,j,k:integer;
          begin
          for i:=0 to 4 do
            for j:=1 to 6 do
              if(map[i][j]<>0)and(map[i][j-1]=0)
                then begin
                     k:=j;
                     while(k>0)and(map[i][k-1]=0)do dec(k);
                     map[i][k]:=map[i][j];map[i][j]:=0;
                     end;
          end;
function  finish(map:Tmap):boolean;
          var i,j:longint;
          begin
          for i:=0 to 4 do
            for j:=0 to 6 do
              if map[i][j]<>0
                then exit(false);
          exit(true);
          end;
procedure DFS(map:Tmap);
          var i,j,k:integer;
          begin
          if step<>0 then swap(map[x[step]][y[step]],map[x[step]+g[step]][y[step]]);
          repeat fall(map) until clean(map);
          if step=n then if finish(map)then print
                                       else exit;
          for i:=0 to 4 do
            for j:=0 to 6 do
              begin
              if map[i][j]<>0
                then begin
                     inc(step);
                     if(i>0)and(map[i-1][j]=0)
                       then begin
                            x[step]:=i;
                            y[step]:=j;
                            g[step]:=-1;
                            DFS(map);
                            end;
                     if(i<4)
                       then begin
                            x[step]:=i;
                            y[step]:=j;
                            g[step]:=1;
                            DFS(map);
                            end;
                     dec(step);
                     end;
              end;
          end;
begin
readln(n);step:=0;
for i:=0 to 4 do
  begin
  t:=-1;
  repeat
    inc(t);
    read(a[i][t]);
  until a[i][t]=0;
  end;
DFS(a);
writeln('-1');
end.