如果你的应该程序必须在运行期间加载一个外部大且冗长的XML文件时，这个方案可能是有用的，通过将XML保存为二进制，你可以压缩数据得到一个较小的文件，当然，你可以得到的压缩的数量取决于数据的复杂性，但它通常超过50％（保守估计）。
无可否认的，经压缩的二进制格式的XML数据违背了摆在首位采用XML的初衷——数据可读性。因此，在程序进行前你将必须先决择哪一种更为重要。也许真实的外部数据才是你想要的——允许数据被具体化，可以改变数据而无需重新编译SWF，然而，或许你更喜欢数据不可编辑。
将XML转换为二进制数据（ByteArray）
首先，我们看看XML数据如何存储在ByteArray中。下面的代码假定您已经有名为“xmlData”字符串值变量存储XML数据：
- var data:ByteArray = new ByteArray();
- data.writeUTFBytes(xmlData); // xmlData is original XML string
- data.compress();
保存文件
现在，您已经有二进制数据ByteArray对象，可以将该对象作为原始数据保存为文件。你可以以下任意一种方式实现。
（一）发送到服务器脚本;
（二）用AIR API保存到本地存储;或
（三）使用Flash Player 10 API保存到本地存储。
我 们会用(三），因为是这是每一个Flash开发人员最容易的方案。这个类将会使用flash.net.FileReference。FileReference.save()方法只有在Flash Player 10时才可用。它允许你保存FileReference对象中的数据至本地。
- function on_buttonClick(evt:MouseEvent):void
- {
- var data:ByteArray = new ByteArray();
- data.writeUTFBytes(xmlData); // xmlData is original XML string
- data.compress();
- new FileReference().save(data, "bindata.xml"); // default name "bindata.xml"
- }
save()方法将打一个本地对话框——输入文件名选择存放位置后将会把XML数据存储至本地。注意保存的文件须以“.xml”作为后缀，但是该文件不是可读地——用文本编辑器打开该文件你看到的是些垃圾数据。
加载二进制XML
加载二进制文件同正常的文本XML文件加载方式一样：
- var ldr:URLLoader = new URLLoader();
- ldr.dataFormat = URLLoaderDataFormat.BINARY; // ** make sure you do this **
- ldr.addEventListener(Event.COMPLETE, on_XML);
- ldr.addEventListener(IOErrorEvent.IO_ERROR, on_XML);
- ldr.load(new URLRequest(pathToXMLFile));
因此，代码同正常的文本XML文件加载方式一样，除了需要将dataFormat设置为URLLoaderDataFormat.BINARY。即使你加载一个普通的文本XML文件，上面的代码也会工作得很好。
将二进制数据转换为XML
二进制XML文件加载成功后，将二进制数据转换为文本XML。
- var xmlData:XML;
- function on_XML(evt:Event):void
- {
- if (evt.type == Event.COMPLETE)
- {
- var data:* = URLLoader(evt.target).data;
- if (data is ByteArray)
- {
- try
- {
- ByteArray(data).uncompress();
- }
- catch(e:Error)
- {
- }
- }
- xmlData = XML(data);
- }
- }
上面的代码，你的应用程序将能够同时处理文本XML和二进制XML文件。因此，此代码你仍可以使用，即使您目前没有使用XML存储为压缩的二进制数据。如果在以后您决定将XML采用二进制压缩格式，该应用程序也能很好的处理。 |
