罗云彬win32汇编教程笔记 子函数的声明, 定义与调用

在主程序中用call指令来调用子程序。 

Win32汇编中的子程序也采用堆栈来传递参数，这样就可以用invoke伪指令来进行调用和语法检查工作。

一. 子程序的定义
子程序的定义方式如下所示。
子程序名  proc [距离][语言类型][可视区域][USES 寄存器列表][,参数:类型]...[VARARG]
         local 局部变量列表
         指令
子程序名  endp

proc和endp伪指令定义了子程序开始和结束的位置， proc后面跟的参数是子程序的属性和输入参数。子程序的属性有：
1.距离——可以是NEAR，FAR，NEAR16，NEAR32，FAR16或FAR32，Win32中只有一个平坦的段，无所谓距离，所以对距离的定义往往忽略。
2.语言类型——表示参数的使用方式和堆栈平衡的方式，可以是StdCall，C，SysCall，BASIC、FORTRAN和PASCAL，如果忽略，则使用程序头部 .model定义的值。
3.可视区域——可以是PRIVATE，PUBLIC和EXPORT。PRIVATE表示子程序只对本模块可见；PUBLIC表示对所有的模块可见（在最后编译链接完成的 .exe文件中）；EXPORT表示是导出的函数，当编写DLL的时候要将某个函数导出的时候可以这样使用。默认的设置是PUBLIC。
4.   USES寄存器列表——表示由编译器在子程序指令开始前自动安排push这些寄存器的指令，并且在ret前自动安排pop指令，用于保存执行环境，但笔者认为不如自己在开头和结尾用pushad和popad指令一次保存和恢复所有寄存器来得方便。
5.   参数和类型——参数指参数的名称，在定义参数名的时候不能跟全局变量和子程序中的局部变量重名。对于类型，由于Win32中的参数类型只有32位（dword）一种类型，所以可以省略。在参数定义的最后还可以跟VARARG，表示在已确定的参数后还可以跟多个数量不确定的参数，在Win32汇编中惟一使用VARARG的API就是wsprintf，类似于C语言中的printf，其参数的个数取决于要显示的字符串中指定的变量个数。

完成了定义之后，可以用invoke伪指令来调用子程序.

如果调用在定义之前, 则报这个错误, 声明一下即可(使用proto声明).
error A2006: undefined symbol : _ProcWinMain
在写源程序的时候有意识地把子程序的位置提到invoke语句的前面，省略掉proto语句，可以简化程序和避免出错。

二.参数传递和堆栈平衡
在调用子程序时，参数的传递是通过堆栈进行的，也就是说，调用者把要传递给子程序的参数压入堆栈，子程序在堆栈中取出相应的值再使用，比如，如果要调用：
SubRouting(Var1, Var2, Var3)

经过编译后的最终代码可能是（注意只是“可能”）：
push  Var3
push  Var2
push  Var1
call  SubRouting
add   esp,12

也就是说，调用者首先把参数压入堆栈，然后调用子程序，在完成后，由于堆栈中先前压入的数不再有用，调用者或者被调用者必须有一方把堆栈指针修正到调用前的状态，即堆栈的平衡。参数是最右边的先入堆栈还是最左边的先入堆栈、还有由调用者还是被调用者来修正堆栈都必须有个约定，不然就会产生错误的结果，这就是在上述文字中使用“可能”这两个字的原因。各种语言中调用子程序的约定是不同的，所以在proc以及proto语句的语言属性中确定语言类型后，编译器才可能将invoke伪指令翻译成正确的样子，不同语言的不同点如表3.4所示。

表3.4  不同语言调用方式的差别
     C  SysCall     StdCall  BASIC FORTRAN  PASCAL
最先入栈参数  右  右   右   左  左   左 
清除堆栈者   调用者 子程序  子程序  子程序 子程序  子程序 
允许使用VARARG  是  是   是   否  否   否
注：VARARG 表示参数的个数可以是不确定的，如wsprintf函数，本表中特殊的地方是StdCall 的堆栈清除平时是由子程序完成的，但使用VARARG 时是由调用者清除的。

为了了解编译器对不同类型子程序的处理方式，先来看一段源程序：
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
Sub1    proc         C _Var1,_Var2
        mov          eax,_Var1
        mov          ebx,_Var2
        ret
Sub1    endp

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
Sub2    proc         PASCAL _Var1,_Var2
        mov          eax,_Var1
        mov          ebx,_Var2
        ret
Sub2    endp

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
Sub3    proc         _Var1,_Var2
        mov          eax,_Var1
        mov          ebx,_Var2
        ret
b3  endp

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
        …
        invoke       Sub1,1,2
        invoke       Sub2,1,2
        invoke       Sub3,1,2

编译后再进行反汇编，看编译器是如何转换处理不同类型的子程序的：

; 这里是Sub1 － C类型
:00401000 55                    push ebp
:00401001 8BEC                  mov ebp, esp
:00401003 8B4508                mov eax, dword ptr [ebp+08]
:00401006 8B5D0C                mov ebx, dword ptr [ebp+0C]
:00401009 C9                    leave
:0040100A C3                    ret

; 这里是Sub2 － PASCAL类型
:0040100B 55                    push ebp
:0040100C 8BEC                  mov ebp, esp
:0040100E 8B450C                mov eax, dword ptr [ebp+0C]
:00401011 8B5D08                mov ebx, dword ptr [ebp+08]
:00401014 C9                    leave
:00401015 C20800                ret 0008

; 这里是Sub3 — StdCall类型
:00401018 55                    push ebp
:00401019 8BEC                  mov ebp, esp
:0040101B 8B4508                mov eax, dword ptr [ebp+08]
:0040101E 8B5D0C                mov ebx, dword ptr [ebp+0C]
:00401021 C9                    leave
:00401022 C20800                ret 0008
        …

; 这里是invoke Sub1,1,2 — C类型
:00401025 6A02                  push 00000002
:00401027 6A01                  push 00000001
:00401029 E8D2FFFFFF            call 00401000
:0040102E 83C408                add esp, 00000008

; 这里是invoke Sub2,1,2 — PASCAL类型
:00401031 6A01                  push 00000001
:00401033 6A02                  push 00000002
:00401035 E8D1FFFFFF            call 0040100B

; 这里是invoke Sub3,1,2 — StdCall类型
:0040103A 6A02                  push 00000002
:0040103C 6A01                  push 00000001
:0040103E E8D5FFFFFF            call 00401018

可以清楚地看到，在参数入栈顺序上，C类型和StdCall类型是先把右边的参数先压入堆栈，而PASCAL类型是先把左边的参数压入堆栈。在堆栈平衡上，C类型是在调用者在使用call指令完成后，自行用add esp,8指令把8个字节的参数空间清除，而PASCAL和StdCall的调用者则不管这个事情，堆栈平衡的事情是由子程序用ret 8来实现的，ret指令后面加一个操作数表示在ret后把堆栈指针esp加上操作数，完成的是同样的功能。

Win32约定的类型是StdCall，所以在程序中调用子程序或系统API后，不必自己来平衡堆栈，免去了很多麻烦。

存取参数和局部变量都是通过堆栈来定义的，所以参数的存取也是通过ebp做指针来完成的。在探讨局部变量的时候，已经就没有参数的情况下ebp指针和局部变量的对应关系做了分析，现在来分析一下ebp指针和参数之间的对应关系，注意，这里是以Win32中的StdCall为例，不同的语言类型，指针的顺序可能是不同的。

假定在一个子程序中有两个参数，主程序调用时在 push 第一个参数前的堆栈指针esp为X，那么压入两个参数后的esp为X-8，程序开始执行call指令，call指令把返回地址压入堆栈，这时候esp为X-C，接下去是子程序中用push ebp来保存ebp的值，esp变为X-10，再执行一句mov ebp,esp，就可以开始用ebp存取参数和局部变量了，图3.4说明了这个过程。


图3.4  ebp指针、参数和局部变量的关系

在源程序中，由于参数、局部变量和ebp的关系是由编译器自动维护的，所以读者不必关心它们的具体关系，但到了用Soft-ICE等工具来分析其他软件的时候，遇到调用子程序的时候一定要先看清楚它们之间的类型差别。

在子程序中使用参数，可以使用与存取局部变量同样的方法，因为这两者的构造原理几乎一模一样，所以，在子程序中有invoke语句时，如果要用到输入参数的地址当做invoke的参数，同样要遵循局部变量的使用方式，不能用offset伪操作符，只能用addr来完成。同样，所有对局部变量使用的限制几乎都可以适用于参数。

 

[plain] view plain copy
print?
  1.         .386  
  2.         .model flat,stdcall  
  3.         option casemap:none  
  4. ;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>  
  5. ; Include 文件定义  
  6. ;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>  
  7. include     windows.inc  
  8. include     user32.inc  
  9. includelib  user32.lib  
  10. include     kernel32.inc  
  11. includelib  kernel32.lib  
  12. LPVAR   typedef  PTR DWORD ;定义一个指针类型数据LPVAR  
  13. sum proto a:LPVAR,b:LPVAR ;声明，这里可省略  
  14.   
  15. .const  
  16. szText db 'hello world!',0  
  17. szCaption db 'hello',0  
  18. .code  
  19. sum proc a:LPVAR,b:LPVAR  
  20. pushad  
  21.     invoke MessageBox,NULL,a,b,0  
  22. popad  
  23. ret  
  24. sum endp  
  25. start:  
  26.         ;invoke MessageBox,NULL,offset szText,offset szCaption,0  
  27.         invoke sum,offset szText,offset szCaption ;调用子程序呢  
  28.         invoke ExitProcess,0  
  29. end start  
		.386
		.model flat,stdcall
		option casemap:none
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Include 文件定义
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
include		windows.inc
include		user32.inc
includelib	user32.lib
include		kernel32.inc
includelib	kernel32.lib
LPVAR   typedef  PTR DWORD ;定义一个指针类型数据LPVAR
sum proto a:LPVAR,b:LPVAR ;声明，这里可省略

.const
szText db 'hello world!',0
szCaption db 'hello',0
.code
sum proc a:LPVAR,b:LPVAR
pushad
	invoke MessageBox,NULL,a,b,0
popad
ret
sum endp
start:
		;invoke MessageBox,NULL,offset szText,offset szCaption,0
		invoke sum,offset szText,offset szCaption ;调用子程序呢
		invoke ExitProcess,0
end start


 

jpg改rar
posted @ 2017-09-25 10:46  狂客  阅读(2014)  评论(0)  编辑  收藏  举报