2021.07.11 【ABAP随笔】采购订单Message输出打印

Title

采购订单Message输出打印

很多业务中需要在完成订单的时候来进行单据打印的输出操作，比如新建采购订单的时候，需要输出采购订单的PDF或者使用邮件功能来将采购订单发送给制定人员

SAP 有标准MESSAGE输出的配置功能-TCODE NACE

下面我们就根据采购订单保存时生成一个message smartforms 来说明一下

一 Nace配置

• 设置输出类型

从NEU复制一个到ZNEU目前我们是对于功能1打印输出来做定制化，所以需要选中ZNEU，双击处理程序(保存采购订单后调用的程序FORM)

⽬前我们是对于功能1打印输出来做定制化，所以需要选中ZNEU，双击处理程序(保存 采购订单后调⽤的程序FORM)

发现它是使⽤SAPFM06P使⽤ADOBE FORM来输出的，这⾥对于我们⼀般的ABAPer 来说，使⽤smartforms会⽐较熟练，所以我们创建⼀个:ZTAB_ZHU_PO_OUT_FORM 程序 来调⽤我⾃⼰定义的smartforms来输出打印 设置如下图

• 设置条件记录

• 选择我们创建的ZNEU输出类型

选择根据采购组织和供应商来确定Message 的输出

当我们第一进入时，可以选择左上角输出定价菜单→创建

添加一条条件记录如下图所示：其中VN是供应商功能类型，媒介1表示打印输出，调度时间4表示需要立即输出

同时我们可以点击通讯来对某个供应商设置打印属性设置：

如下图可以对采购组织1310 和供应商133000273的订单输出设置打印设备为LP01，且立即打印

• 设置过程

设置完毕后退出，点击过程来添加设置好的输出类型

可以选择原来的过程进行添加，也可以单独创建一个过程

在新添加的过程ZRMBEF中添加ZNEU 需求为101

• SPRO配置

接下来还要在SPRO→物料管理→采购→消息→输出控制→信息类型→定义采购订单的消息类型，添加ZNEU的输出类型

该配置是在采购订单创建和修改时自动在消息中追加一条Message 输出

如下图是订单在修改之后或者创建时自动添加的一条未处理Message输出

同时在SPRO→物料管理→采购→消息→输出控制→信息类型→信息确定方案 ，将过程RMBEF1修改为之前定义的过程ZRMBEF

当配置和程序都完毕时，我们去ME21N创建对应供应商的采购订单

当保存PO时，弹出框调用WINDOWS本地打印机输出为PDF

 

二 代码部分

 重点关注以下几点内容：

• 在采购订单保存成功之后，后台程序仅仅会调用 ZTAB_ZHU_PO_OUT_FORM中的FORM enter_neu.
• 使用Function 'ME_READ_PO_FOR_PRINTING' 来获取当前PO的信息，都放在doc的返回参数中
• 程序中TNAPR存放着调用程序，SMARTFORMS的信息，所以smartforms为TNAPR-SFORM
• 在程序中发生错误或者打印成功后，使用Function 'NAST_PROTOCOL_UPDATE' 来更新NAST表，NAST表为记录所有OUTPUT Message 状态的表

*&---------------------------------------------------------------------*
*& Report ZTAB_ZHU_PO_OUT_FORM
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
REPORT ztab_zhu_po_out_form.

INCLUDE rvadtabl.
DATA:
  xscreen,                           "Output on printer or screen
  nast_anzal   LIKE nast-anzal,      "Number of outputs (Orig. + Cop.)
  nast_tdarmod LIKE nast-tdarmod.    "Archiving only one time

* Type Pools
TYPE-POOLS: meein.

* DDIC-Tabellen
DATA:
  addr1_sel LIKE addr1_sel,
  addr1_val LIKE addr1_val.

DATA:
  cdhdr    TYPE cdhdr,
  cdshw    TYPE cdshw,
  gs_dd04t TYPE dd04t,
  ekes     TYPE ekes,
  eket     TYPE eket,
  ekko     TYPE ekko,
  ekpo     TYPE ekpo,
  gs_elbp  TYPE elbp,
  esuh     TYPE esuh,
  komg     TYPE komg,
  komk     TYPE komk,
  komp     TYPE komp,
  konp     TYPE konp,
  gs_lfa1  TYPE lfa1,
  gs_lfm1  TYPE lfm1,
  mdpa     TYPE mdpa,
  gs_t001  TYPE t001,
  gs_t001n TYPE t001n,
  t001w    TYPE t001w,
  gs_t005  TYPE t005,
  gs_t100  TYPE t100,
  t161m    TYPE t161m,
  t166c    TYPE t166c,
  gs_t166t TYPE t166t,
  gs_t685b TYPE t685b,
  gs_tinct TYPE tinct,
  wyt3     TYPE wyt3.


* Interne Tabellen
DATA:
  i_cdhdr LIKE cdhdr OCCURS 0 WITH HEADER LINE,
  i_cdshw LIKE cdshw OCCURS 0 WITH HEADER LINE,
  i_dd03l LIKE dd03l OCCURS 0 WITH HEADER LINE,
  i_ekes  LIKE ekes  OCCURS 0 WITH HEADER LINE,
  i_eket  LIKE eket  OCCURS 0 WITH HEADER LINE,
  i_ekpo  LIKE ekpo  OCCURS 0 WITH HEADER LINE,
  i_konp  LIKE konp  OCCURS 0 WITH HEADER LINE,
  i_mdsb  LIKE mdsb  OCCURS 0 WITH HEADER LINE,
  i_nast  LIKE nast  OCCURS 0 WITH HEADER LINE,
  i_t001w LIKE t001w OCCURS 0 WITH HEADER LINE,
  i_t161m LIKE t161m OCCURS 0 WITH HEADER LINE,
  i_t166c LIKE t166c OCCURS 0 WITH HEADER LINE,
  i_t166k LIKE t166k OCCURS 0 WITH HEADER LINE,
  i_t166p LIKE t166p OCCURS 0 WITH HEADER LINE,
  i_t166t LIKE t166t OCCURS 0 WITH HEADER LINE,
  i_ttext LIKE ttext OCCURS 0 WITH HEADER LINE,
  i_ttxit LIKE ttxit OCCURS 0 WITH HEADER LINE,
  i_wyt3  LIKE wyt3  OCCURS 0 WITH HEADER LINE.

DATA: gs_cdshw TYPE cdshw.

DATA:
  i2_cdred LIKE cdred OCCURS 0 WITH HEADER LINE,
  i2_cdshw LIKE cdshw OCCURS 0 WITH HEADER LINE,
  i2_eket  LIKE eket  OCCURS 0 WITH HEADER LINE,
  i2_konp  LIKE konp  OCCURS 0 WITH HEADER LINE,
  i2_mdpm  LIKE mdpm  OCCURS 0 WITH HEADER LINE,
  i2_mdsb  LIKE mdsb  OCCURS 0 WITH HEADER LINE.

DATA:
  tkomv    LIKE komv  OCCURS 0 WITH HEADER LINE,
  tkomvd   LIKE komvd OCCURS 0 WITH HEADER LINE,
  tkomvd_2 LIKE komvd OCCURS 0 WITH HEADER LINE.

DATA:
   ls_doc TYPE meein_purchase_doc_print.

* Smartforms Rückgabestrukturen
DATA:
*   document_output_info TYPE ssfcrespd,
  job_output_info TYPE ssfcrescl,
*   job_output_options   TYPE ssfcresop,
  spoolids        TYPE rspoid.

* Sonstige Variable
DATA:
  c1,
  gv_tdid        TYPE tdid,
  c10(10),
  c20(20),
  c80(80),
  c100(100),
  ix_from_memory TYPE char1,
  xdruvo         LIKE t166k-druvo,
  xindex         LIKE sy-index,
  xobjcl         LIKE cdhdr-objectclas,
  xobjid         LIKE cdhdr-objectid,
  xretco         LIKE sy-subrc,
  xrolln         LIKE dd04t-rollname,
  xspool         TYPE rspoid,
  xsubrc         LIKE sy-subrc,
  xtdid          TYPE stxh-tdid,
  xtdnam         TYPE stxh-tdname,
  xxaend         TYPE meein_xaend,
  zaehl          TYPE i.

DATA: ls_repid TYPE repid,
      ls_bukrs TYPE bukrs,
      lv_adrnr TYPE lfa1-adrnr.

TYPES: tt_mmpa TYPE TABLE OF mmpa.

FIELD-SYMBOLS: <xmmpa>    TYPE tt_mmpa,
               <ls_xmmpa> TYPE mmpa.

DATA ls_xekpa TYPE msgpa. "ekpa.

* Startroutine Nachricht NEU
FORM entry_neu USING return_code TYPE i
                     us_screen   TYPE c.
  CLEAR: xsubrc.

  xretco  = return_code.
  xscreen = us_screen.

  PERFORM processing USING us_screen
                  CHANGING xsubrc.

  IF xsubrc NE 0.
    return_code = 1.
  ELSE.
    return_code = 0.
  ENDIF.
ENDFORM.                    "ENTRY_NEU

FORM processing USING proc_screen TYPE c
             CHANGING cf_retcode  TYPE i.
  DATA:
    lf_fm_name        TYPE rs38l_fnam,
    lf_formname       TYPE tdsfname,
    ls_addr_key       LIKE addr_key,
    ls_composer_param TYPE ssfcompop,
    ls_control_param  TYPE ssfctrlop,
    ls_recipient      TYPE swotobjid,
    ls_sender         TYPE swotobjid.

* Sonderroutine bei Ausgabe Mail mit Anlagen
* ( Aufruf aus ZAMMMP0001 )
  CLEAR xspool.

* Löschen Flag "CX_FROM_MEMORY"
  CLEAR: cf_retcode, ix_from_memory.

* Datenbeschaffung
  CALL FUNCTION 'ME_READ_PO_FOR_PRINTING'
    EXPORTING
      ix_nast        = nast
      ix_screen      = proc_screen
    IMPORTING
      ex_retco       = cf_retcode
      doc            = ls_doc
*     ex_nast        = xnast
    CHANGING
      cx_druvo       = xdruvo
      cx_from_memory = ix_from_memory.
  CHECK cf_retcode = 0.


* Übernahme Änderungen in int. Tabelle für Smartforms
  PERFORM aenderungsbelege.

  SELECT SINGLE * FROM lfa1 INTO gs_lfa1
       WHERE lifnr = nast-parnr.

  lf_formname = tnapr-sform.

* Aufbereitung Druckparameter
  PERFORM set_print_param USING ls_addr_key
                                gs_lfa1-land1
                       CHANGING ls_control_param
                                ls_composer_param
                                ls_recipient
                                ls_sender
                                cf_retcode.

*  Bestimmung Funktionsbaustein für Smartforms-Formular
  CALL FUNCTION 'SSF_FUNCTION_MODULE_NAME'
    EXPORTING
      formname           = lf_formname
    IMPORTING
      fm_name            = lf_fm_name
    EXCEPTIONS
      no_form            = 1
      no_function_module = 2
      OTHERS             = 3.

  IF sy-subrc NE 0.
    cf_retcode = sy-subrc.
    PERFORM protocol_update.
  ENDIF.

  CHECK cf_retcode = 0.

  nast_tdarmod = nast-tdarmod.
  nast_anzal =
  ls_composer_param-tdnewid = 'X'.

  ls_composer_param-tdcopies = nast-anzal.

*  Aufruf Smartforms-FB
  CALL FUNCTION lf_fm_name
    EXPORTING
      archive_index      = toa_dara
      archive_parameters = arc_params
      control_parameters = ls_control_param
      mail_recipient     = ls_recipient
      mail_sender        = ls_sender
      output_options     = ls_composer_param
      user_settings      = space
      ekko               = ls_doc-xekko
      nast               = nast
    IMPORTING
*     document_output_info = document_output_info
      job_output_info    = job_output_info
*     job_output_options = job_output_options
    TABLES
      t_ekpo             = ls_doc-xekpo
    EXCEPTIONS
      formatting_error   = 1
      internal_error     = 2
      send_error         = 3
      user_canceled      = 4
      OTHERS             = 5.

*  Fehlerprotokoll
  IF sy-subrc NE 0.
    cf_retcode = sy-subrc.
    PERFORM protocol_update.
    PERFORM add_smfrm_prot.
  ENDIF.

*  Ermitteln Spool-Nummer
  LOOP AT job_output_info-spoolids INTO spoolids.
    CHECK spoolids NE space.

    PERFORM protocol_update_spool USING '342' spoolids
                                        space space space.
    xspool = spoolids.
  ENDLOOP.



  IF NOT nast_tdarmod IS INITIAL.
    nast-tdarmod = nast_tdarmod.
    CLEAR nast_tdarmod.
  ENDIF.

  IF NOT xspool IS INITIAL.
    sy-msgid = 'VN'.
    sy-msgty = 'I'.
    sy-msgno = '342'.
    sy-msgv1 = xspool.
  ENDIF.
ENDFORM.
*&---------------------------------------------------------------------*
*& Form aenderungsbelege
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM aenderungsbelege .
  REFRESH i_cdshw.

  LOOP AT ls_doc-xaend INTO xxaend.
*  Keine Änderungen aus Bestellbestätigungen
    CHECK xxaend-tabname NE 'EKES'.

*  Keine Änderungen aus Einteilungen (ausser Liefertermin)
    IF xxaend-tabname = 'EKET'.
      CHECK xxaend-fname = 'EINDT'.
    ENDIF.

*  Datenübernahme in Änderungsstruktur
    MOVE-CORRESPONDING xxaend TO i_cdshw.

*  Aufbereitung überflüssiger Nachkommastellen
    REPLACE ',000 ' WITH space INTO i_cdshw-f_old.
    REPLACE ',000 ' WITH space INTO i_cdshw-f_new.

*  Feldbezeichnung in Nachrichtensprache
    SELECT * FROM dd03l
       INTO TABLE i_dd03l
       WHERE tabname   = i_cdshw-tabname
         AND fieldname = i_cdshw-fname
       ORDER BY PRIMARY KEY.   "BHS120614(+).

    IF sy-subrc = 0.
      READ TABLE i_dd03l INDEX 1.

      PERFORM lesen_datenelement
         USING i_dd03l-rollname 'M' i_cdshw-ftext.
    ENDIF.

*  Aufbau Tabelle mit Änderungsbelegen
    APPEND i_cdshw.
  ENDLOOP.

  CHECK sy-subrc NE 0.

* Prüfen, ob bereits mindestens 1 verarbeitete Nachricht vorliegt
  SELECT * FROM nast
     INTO TABLE i_nast
     WHERE kappl = nast-kappl
       AND objky = nast-objky
       AND kschl = nast-kschl
       AND vstat = '1'
       ORDER BY PRIMARY KEY.   "BHS120614(+).
  CHECK sy-subrc = 0.

* Letzte verarbeitete Nachricht wg. Timestamp für Änderungsbelege
  DESCRIBE TABLE i_nast LINES xindex.

  IF xindex > 1.
    SELECT COUNT( * ) FROM nast
       WHERE kappl = nast-kappl
         AND objky = nast-objky
         AND kschl = nast-kschl
         AND vstat = '0'.

    IF sy-subrc NE 0.
      xindex = xindex - 1.
    ENDIF.
  ENDIF.

  READ TABLE i_nast INDEX xindex.

* Lesen Änderungsbelege
  PERFORM lesen_aenderungsbelege USING 'EINKBELEG' nast-objky.
ENDFORM.
*&---------------------------------------------------------------------*
*& Form lesen_aenderungsbelege
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*&      --> P_
*&      --> NAST_OBJKY
*&---------------------------------------------------------------------*
FORM lesen_aenderungsbelege USING xxobjcl TYPE cdhdr-objectclas
                                  xxobjid TYPE nast-objky.
  CHECK nast-kschl = 'NEU '.

  xobjcl = xxobjcl.
  xobjid = xxobjid.

  CALL FUNCTION 'CHANGEDOCUMENT_READ_HEADERS'
    EXPORTING
      objectclass                = xobjcl
      objectid                   = xobjid
      username                   = space
    TABLES
      i_cdhdr                    = i_cdhdr
    EXCEPTIONS
      no_position_found          = 1
      wrong_access_to_archive    = 2
      time_zone_conversion_error = 3
      OTHERS                     = 4.
  CHECK sy-subrc = 0.

  LOOP AT i_cdhdr INTO cdhdr.
    CHECK cdhdr-udate > i_nast-datvr
       OR ( cdhdr-udate = i_nast-datvr AND
            cdhdr-utime > i_nast-uhrvr ).

    CALL FUNCTION 'CHANGEDOCUMENT_READ_POSITIONS'
      EXPORTING
        changenumber            = cdhdr-changenr
      TABLES
        editpos                 = i2_cdshw
        editpos_with_header     = i2_cdred
      EXCEPTIONS
        no_position_found       = 1
        wrong_access_to_archive = 2
        OTHERS                  = 3.
    CHECK sy-subrc = 0.

*    APPEND LINES OF i2_cdred TO i_cdred.
    APPEND LINES OF i2_cdshw TO i_cdshw.
  ENDLOOP.

* Prüfung änderungsrelevante Felder
  SELECT * FROM t166c
     INTO TABLE i_t166c.

  CASE ls_doc-xekko-bstyp.
    WHEN 'A'.
      DELETE i_t166c WHERE xanfr NE 'X'.
    WHEN 'F'.
      DELETE i_t166c WHERE xbest NE 'X'.
    WHEN 'K'.
      DELETE i_t166c WHERE xkont NE 'X'.
    WHEN 'L'.
      DELETE i_t166c WHERE xlfpl NE 'X'.
  ENDCASE.

*  Keine Änderungen aus Einteilungen und Bestellbestätigungen
  DELETE i_cdshw WHERE tabname = 'EKES'.

  DELETE i_cdshw WHERE tabname = 'EKET'
                   AND fname  NE 'EINDT'.

  LOOP AT i_cdshw WHERE chngind = 'U'.
    READ TABLE i_t166c WITH KEY tname = i_cdshw-tabname
                                fname = i_cdshw-fname.
    IF sy-subrc NE 0.
      DELETE i_cdshw.
      CONTINUE.
    ENDIF.

*  Druckaufbereitung
*  Aufbereitung überflüssiger Nachkommastellen
    REPLACE ',000 ' WITH space INTO i_cdshw-f_old.
    REPLACE ',000 ' WITH space INTO i_cdshw-f_new.

*  Feldbezeichnung in Nachrichtensprache
    SELECT * FROM dd03l
       INTO TABLE i_dd03l
       WHERE tabname   = i_cdshw-tabname
         AND fieldname = i_cdshw-fname
       ORDER BY PRIMARY KEY.   "BHS120614(+).

    IF sy-subrc = 0.
      READ TABLE i_dd03l INDEX 1.

      PERFORM lesen_datenelement
         USING i_dd03l-rollname 'M' i_cdshw-ftext.
    ENDIF.

    MODIFY i_cdshw.
  ENDLOOP.
ENDFORM.
*&---------------------------------------------------------------------*
*& Form set_print_param
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*&      --> LS_ADDR_KEY
*&      --> GS_LFA1_LAND1
*&      <-- LS_CONTROL_PARAM
*&      <-- LS_COMPOSER_PARAM
*&      <-- LS_RECIPIENT
*&      <-- LS_SENDER
*&      <-- CF_RETCODE
*&---------------------------------------------------------------------*
FORM set_print_param  USING is_addr_key       LIKE addr_key
                           xxland1           LIKE lfa1-land1
                  CHANGING cs_control_param  TYPE ssfctrlop
                           cs_composer_param TYPE ssfcompop
                           cs_recipient      TYPE swotobjid
                           cs_sender         TYPE swotobjid
                           cf_retcode        TYPE sy-subrc.
  DATA:
    lf_device TYPE tddevice,
    lf_repid  TYPE sy-repid,
    ls_itcpo  TYPE itcpo.

  lf_repid = sy-repid.

  CALL FUNCTION 'WFMC_PREPARE_SMART_FORM'
    EXPORTING
      pi_nast       = nast
      pi_country    = xxland1
      pi_addr_key   = is_addr_key
      pi_repid      = lf_repid
      pi_screen     = xscreen
    IMPORTING
      pe_returncode = cf_retcode
      pe_itcpo      = ls_itcpo
      pe_device     = lf_device
      pe_recipient  = cs_recipient
      pe_sender     = cs_sender.

  IF cf_retcode = 0.
    MOVE-CORRESPONDING ls_itcpo TO cs_composer_param.

    CLEAR cs_composer_param-tddelete.
    cs_composer_param-tdlifetime = 8.

    cs_control_param-device    = lf_device.
    cs_control_param-no_dialog = ''.
    cs_control_param-preview   = xscreen.
    cs_control_param-getotf    = ls_itcpo-tdgetotf.
    cs_control_param-langu     = nast-spras.
  ENDIF.

ENDFORM.
*&---------------------------------------------------------------------*
*& Form protocol_update
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM protocol_update .
  IF xscreen NE space.
    MESSAGE ID sy-msgid TYPE 'I' NUMBER sy-msgno
          WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    EXIT.
  ENDIF.

  CALL FUNCTION 'NAST_PROTOCOL_UPDATE'
    EXPORTING
      msg_arbgb = syst-msgid
      msg_nr    = syst-msgno
      msg_ty    = syst-msgty
      msg_v1    = syst-msgv1
      msg_v2    = syst-msgv2
      msg_v3    = syst-msgv3
      msg_v4    = syst-msgv4
    EXCEPTIONS
      OTHERS    = 1.
ENDFORM.
*&---------------------------------------------------------------------*
*& Form add_smfrm_prot
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM add_smfrm_prot .
  DATA:
    l_s_log     TYPE bal_s_log,
    l_s_msg     TYPE bal_s_msg,
    lt_errortab TYPE tsferror,
    p_loghandle TYPE balloghndl.

  FIELD-SYMBOLS:
     <fs_errortab> TYPE LINE OF tsferror.

* Fehlertabelle lesen
  CALL FUNCTION 'SSF_READ_ERRORS'
    IMPORTING
      errortab = lt_errortab.

  SORT lt_errortab.

* Hinzufügen Smartforms Protokoll zum Nachrichtenprotokoll
  LOOP AT lt_errortab ASSIGNING <fs_errortab>.
    CALL FUNCTION 'NAST_PROTOCOL_UPDATE'
      EXPORTING
        msg_arbgb = <fs_errortab>-msgid
        msg_nr    = <fs_errortab>-msgno
        msg_ty    = <fs_errortab>-msgty
        msg_v1    = <fs_errortab>-msgv1
        msg_v2    = <fs_errortab>-msgv2
        msg_v3    = <fs_errortab>-msgv3
        msg_v4    = <fs_errortab>-msgv4
      EXCEPTIONS
        OTHERS    = 1.
  ENDLOOP.

* Application log
  l_s_log-extnumber = sy-uname.

  CALL FUNCTION 'BAL_LOG_CREATE'
    EXPORTING
      i_s_log      = l_s_log
    IMPORTING
      e_log_handle = p_loghandle
    EXCEPTIONS
      OTHERS       = 1.

  LOOP AT lt_errortab ASSIGNING <fs_errortab>.
    MOVE-CORRESPONDING <fs_errortab> TO l_s_msg.

    CALL FUNCTION 'BAL_LOG_MSG_ADD'
      EXPORTING
        i_log_handle = p_loghandle
        i_s_msg      = l_s_msg
      EXCEPTIONS
        OTHERS       = 1.
  ENDLOOP.
ENDFORM.
*&---------------------------------------------------------------------*
*& Form protocol_update_spool
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*&      --> P_
*&      --> SPOOLIDS
*&      --> SPACE
*&      --> SPACE
*&      --> SPACE
*&---------------------------------------------------------------------*
FORM protocol_update_spool  USING syst_msgno   TYPE symsgno
                                 p_ls_spoolid TYPE rspoid
                                 p_space1     TYPE symsgv
                                 p_space2     TYPE symsgv
                                 p_space3     TYPE symsgv.
  CHECK xscreen = space.

  syst-msgid = 'VN'.
  syst-msgno = syst_msgno.
  syst-msgv1 = p_ls_spoolid.

  CONDENSE syst-msgv1.

  CALL FUNCTION 'NAST_PROTOCOL_UPDATE'
    EXPORTING
      msg_arbgb = syst-msgid
      msg_nr    = syst-msgno
      msg_ty    = syst-msgty
      msg_v1    = syst-msgv1
      msg_v2    = p_space1
      msg_v3    = p_space2
      msg_v4    = p_space3
    EXCEPTIONS
      OTHERS    = 1.
ENDFORM.
* Literale übernehmen aus Datenelemnten
FORM lesen_datenelement USING xxrolln TYPE rollname
                              xxtext  TYPE char1
                              xxfeld  TYPE any.
  SELECT SINGLE * FROM dd04t INTO gs_dd04t
     WHERE rollname   = xxrolln
       AND ddlanguage = nast-spras
       AND as4local   = 'A'
       AND as4vers    = '0000'.
  CHECK sy-subrc = 0.

  CASE xxtext.
    WHEN 'M'.  xxfeld = gs_dd04t-scrtext_m.
    WHEN 'L'.  xxfeld = gs_dd04t-scrtext_l.
    WHEN 'S'.  xxfeld = gs_dd04t-scrtext_s.
    WHEN 'D'.  xxfeld = gs_dd04t-ddtext.
    WHEN 'R'.  xxfeld = gs_dd04t-reptext.
  ENDCASE.
ENDFORM.                    "LESEN_DATENELEMENT