[汇编]《汇编语言》第9章 转移指令的原理
王爽《汇编语言》第四版 超级笔记
第9章 转移指令的原理
可以修改IP，或同时修改CS和IP的指令统称为转移指令。
概括地讲，转移指令就是可以控制CPU执行内存中某处代码的指令。
8086CPU的转移行为有以下几类。
- 只修改IP时，称为段内转移，比如：jmp ax。
- 同时修改CS和IP时，称为段间转移，比如：jmp 1000:0。
由于转移指令对IP的修改范围不同，段内转移又分为：短转移和近转移。 - 短转移IP的修改范围为-128〜127。
- 近转移IP的修改范围为-32768〜32767。
8086CPU的转移指令分为以下几类。
- 无条件转移指令（如：jmp）
- 条件转移指令
- 循环指令（如：loop）
- 过程
- 中断
这些转移指令转移的前提条件可能不同，但转移的基本原理是相同的。我们在这一章主要通过深入学习无条件转移指令jmp来理解CPU执行转移指令的基本原理。
9.1 操作符offset、jmp指令
操作符offset在汇编语言中是由编译器处理的符号，它的功能是取得标号的偏移地址。比如下面的程序：
assume cs:codesg
codesg segment
start: mov ax,offset start ;相当于mov ax,0
s: mov ax,offset s ;相当于mov ax,3
codesg ends
end start
在上面的程序中，offset操作符取得了标号start和s的偏移地址0和3，所以指令：mov ax,offset start相当于指令mov ax,0，因为start是代码段中的标号，它所标记的指令是代码段中的第一条指令，偏移地址为0。
mov ax,offset s相当于指令mov ax,3，因为s是代码段中的标号，它所标记的指令是代码段中的第二条指令，第一条指令长度为3个字节，则s的偏移地址为3。
问题9.1
思考后看分析。
分析:
（1）s和s0处的指令所在的内存单元的地址是多少？cs:offset s和cs:offset s0。
（2）将s处的指令复制到s0处，就是将cs:offset s处的数据复制到cs:offset s0处。
（3）段地址己知在cs中，偏移地址offset s和offset s0己经送入si和di中。
（4）要复制的数据有多长？mov ax,bx指令的长度为两个字节，即1个字。
程序如下。
assume cs:codesg
codesg segment
s: mov ax,bx ;mov ax,bx 的机器码占两个字节
mov si,offset s
mov di,offset s0
mov ax,cs:[si]
mov cs:[di],ax
s0: nop ;nop的机器码占一个字节
nop
codesg ends
end s
jmp为无条件转移指令，可以只修改IP，也可以同时修改CS和IP。
jmp指令要给出两种信息:
（1）转移的目的地址
（2）转移的距离（段间转移、段内短转移、段内近转移）
不同的给岀目的地址的方法，和不同的转移位置，对应有不同格式的jmp指令。
下面的几节内容中，我们以给出目的地址的不同方法为主线，讲解jmp指令的主要应用格式和CPU执行转移指令的基本原理。
9.2 jmp指令应用场景
依据位移进行转移的jmp指令
jmp short标号（转到标号处执行指令）
这种格式的jmp指令实现的是段内短转移，它对IP的修改范围为-128～127，也就是说，它向前转移时可以最多越过128个字节，向后转移可以最多越过127个字节。
jmp指令中的“short”符号，说明指令进行的是短转移。jmp指令中的“标号”是代码段中的标号，指明了指令要转移的目的地，转移指令结束后，CS:IP应该指向标号处的指令。
程序9.1
assume cs:codesg
codesg segment
start: mov ax,0
jmp short s
add ax,1
s: inc ax
codesg ends
end start
上面的程序执行后，ax中的值为1，因为执行jmp short s后，越过了add ax,1，IP指向了标号s处的inc ax。也就是说，程序只进行了一次ax加1操作。
汇编指令jmp short s对应的机器指令应该是什么样的呢？
我们先看一下别的汇编指令和其相对应的机器指令。
汇编指令 机器指令
mov ax,0123h B8 23 01
mov ax,ds:[0123h] A1 23 01
push ds:[0123h] FF 36 23 01
可以看到，在一般的汇编指令中，汇编指令中的idata（立即数），不论它是表示一个数据还是内存单元的偏移地址，都会在对应的机器指令中岀现，因为CPU执行的是机器指令，它必须要处理这些数据或地址。
现在我们在Debug中将程序9.1翻译成为机器码，看到的结果如图9.1所示。
对照汇编源程序，我们可以看到，Debug将jmp short s中的s表示为inc ax指令的偏移地址8，并将jmp short s表示为jmp 0008，表示转移到cs:0008处。
jmp 0008（Debug中的表示）或jmp short s（汇编语言中的表示）所对应的机器码为EB03，注意，这个机器码中竟不包含转移的目的地址，这意味着CPU在执行EB03时，并不知道转移的目的地址。
那么，CPU根据什么进行转移呢？它知道转移到哪里呢？
令人奇怪的是，汇编指令jmp short s中，明明是带有转移的目的地址（由标号s表示）的，可翻译成机器指令后，怎么目的地址就没了呢？
没有了目的地址，CPU如何知道转移到哪里呢？
我们把程序9.1改写一下，变成下面这样：
程序9.2
assume cs:codesg
codesg segment
start: mov ax,0
mov bx,0
jmp short s
add ax,1
s: inc ax
codesg ends
end start
我们在Debug中将程序9.2翻译成为机器码，看到的结果如图9.2所示。
这说明CPU在执行jmp指令的时候并不需要转移的目的地址。
CPU不是神仙，它只能处理你提供给它的东西，jmp指令的机器码中不包含转移的目的地址，那么，CPU如何知道将IP改为多少呢？
所以，在jmp指令的机器码中，一定包含了某种信息，使得CPU可以将它当做修改IP的依据。这种信息是什么呢？我们一步步地分析。
我们先简单回忆一下CPU执行指令的过程。
（1）从CS:IP指向内存单元读取指令，读取的指令进入指令缓冲器；
（2）(IP)=(IP)+所读取指令的长度，从而指向下一条指令；
（3）执行指令。转到1，重复这个过程。
按照这个步骤，我们参照图9.2看一下，程序9.2中jmp short s指令的读取和执行过程：
（1）(CS)=0BBDH，(IP)=0006H，CS:IP指向EB 03(jmp short s 的机器码)；
（2）读取指令码EB 03进入指令缓冲器；
（3）(IP)=(IP)+所读取指令的长度=(IP)+2=0008H，CS:IP指向add ax,1；
（4）CPU执行指令缓冲器中的指令EB 03；
（5）指令EB 03执行后，(IP)=000BH，CS:IP指向inc ax。
从上面的过程中我们看到，CPU将指令EB 03读入后，IP指向了下一条指令，即CS:0008处的add ax,1，接着执行EB 03。
如果EB 03没有对IP进行修改的话，那么，接下来CPU将执行add ax,1，可是，CPU执行的EB 03却是一条修改IP的转移指令，执行后(IP)=000BH，CS:IP指向inc ax，CS:0008处的add ax,1没有被执行。
CPU在执行EB 03的时候是根据什么修改的IP，使其指向目标指令呢？
就是根据指令码中的03。注意，要转移的目的地址是CS:000B，而CPU执行EB 03时，当前的(IP)=0008H，如果将当前的IP值加3，使(IP)=000BH，CS:IP就可指向目标指令。在转移指令EB 03中并没有告诉CPU要转移的目的地址，却告诉了CPU要转移的位移，即将当前的IP向后移动3个字节。因为程序1、2中的jmp指令转移的位移相同，都是向后3个字节，所以它们的机器码都是EB 03。
原来如此，在“jmp short标号”指令所对应的机器码中，并不包含转移的目的地址，而包含的是转移的位移。
这个位移，是编译器根据汇编指令中的“标号”计算出来的，具体的计算方法如图9.3所示。
实际上，“jmp short 标号“的功能为：(IP)=(IP)+8位位移。
(1) 8位位移=标号处的地址-jmp指令后的第一个字节的地址；
(2) short指明此处的位移为8位位移；
(3) 8位位移的范围为-128-127，用补码表示；
(4) 8位位移由编译程序在编译时算出。
还有一种和"jmp short 标号”功能相近的指令格式，jmp near ptr 标号，它实现的是段内近转移。
“jmp near ptr 标号"的功能为：(IP)=(IP)+16位位移。
(1) 16位位移=标号处的地址-jmp指令后的第一个字节的地址；
(2) near ptr指明此处的位移为16位位移，进行的是段内近转移；
(3) 16位位移的范围为-32768〜32767，用补码表示；
(4) 16位位移由编译程序在编译时算出。
转移的目的地址在指令中的jmp指令
"jmp far ptr 标号”实现的是段间转移，又称为远转移。功能如下:
- (CS)=标号所在段的段地址；
- (IP)=标号在段中的偏移地址。
far ptr 指明了指令用标号的段地址和偏移地址修改CS和IP。
看下面的程序：
程序9.3
assume cs:codesg
codesg segment
start: mov ax,0
mov bx,0
jmp far ptr s
db 256 dup (0)
s: add ax,1
inc ax
codesg ends
end start
在Debug中将程序9.3翻译成为机器码，看到的结果如图9.4所示。
如图9.4中所示，源程序中的db 256 dup (0)，被Debug解释为相应的若干条汇编指令。
这不是关键，关键是，我们要注意一下jmp far ptr s所对应的机器码：EA 0B 01 BD 0B，其中包含转移的目的地址。“0B 01 BD 0B ”是目的地址在指令中的存储顺序，高地址的“BD 0B”是转移的段地址：0BBDH，低地址的“0B 01”是偏移地址：010BH。
转移地址在寄存器中的jmp指令
指令格式：jmp 16位reg
功能：(IP)=(16位reg)
这种指令我们在前面的内容（参见第2章寄存器修改CS、IP的指令小节）中己经讲过，这里就不再详述。
转移地址在内存中的jmp指令
转移地址在内存中的jmp指令有两种格式：
（1）jmp word ptr 内存单元地址(段内转移)
功能：从内存单元地址处开始存放着一个字，是转移的目的偏移地址。
内存单元地址可用寻址方式的任一格式给出。
比如，下面的指令：
mov ax,0123H
mov ds:[0],ax
jmp word ptr ds:[0]
执行后， (IP)=0123H。
又比如，下面的指令：
mov ax,0123H
mov [bx],ax
jmp word ptr [bx]
执行后， (IP)=0123H。
（2）jmp dword ptr 内存单元地址(段间转移)
功能：从内存单元地址处开始存放着两个字，高地址处的字是转移的目的段地址，低地址处是转移的目的偏移地址。
(CS)=(内存单元地址+2)
(IP)=(内存单元地址)
内存单元地址可用寻址方式的任一格式给出。
比如，下面的指令：
mov ax,0123H
mov ds:[0],ax
mov word ptr ds:[2],0
jmp dword ptr ds:[0]
执行后，(CS)=0，(IP)=0123H，CS:IP指向0000:0123。
又比如，下面的指令：
mov ax,0123H
mov [bx],ax
mov word ptr [bx+2],0
jmp dword ptr [bx]
执行后，(CS)=0，(IP)=0123H，CS:IP指向0000:0123。
9.3 jcxz指令、loop指令
JCXZ指令为有条件转移指令，所有的有条件转移指令都是短转移，在对应的机器码中包含转移的位移，而不是目的地址。
对IP的修改范围都为：-128～127。
指令格式：jcxz 标号(如果(cx)=0，转移到标号处执行)。
操作：
当(cx)=0时，(IP)=(IP)+8位位移；
8位位移=标号处的地址-jcxz指令后的第一个字节的地址；
8位位移的范围为-128～127，用补码表示；
8位位移由编译程序在编译时算出。
当(cx)不等于0时，什么也不做(程序向下执行)。
我们从jcxz的功能中可以看岀，“jcxz 标号”的功能相当于：
if ((cx)==0) jmp short 标号；
(这种用C语言和汇编语言进行的综合描述，或许能使你对有条件转移指令理解得更加清楚。)
loop指令为循环指令，所有的循环指令都是短转移，在对应的机器码中包含转移的位移，而不是目的地址。
对IP的修改范围都为：-128～127。
指令格式：loop 标号((cx)=(cx)-1，如果(cx)不等于0，转移到标号处执行。
操作：
(1) (cx)=(cx)-1；
(2) 如果(cx)不等于0，(IP)=(IP)+8位位移。
8位位移=标号处的地址-loop指令后的第一个字节的地址；
8位位移的范围为-128～127，用补码表示；
8位位移由编译程序在编译时算出。
如果(cx)=0，什么也不做(程序向下执行)。
我们从loop的功能中可以看出，“loop标号”的功能相当于：
(cx)--;
if ((cx)!=0) jmp short 标号;
9.4 位移转移的意义、编译器对转移位移超界的检测
前面我们讲到：
jmp short 标号
jmp near ptr 标号
jcxz 标号
loop 标号
等几种汇编指令，它们对IP的修改是根据转移目的地址和转移起始地址之间的位移来进行的。
在它们对应的机器码中不包含转移的目的地址，而包含的是到目的地址的位移。
这种设计，方便了程序段在内存中的浮动装配。
例如：
汇编指令 机器代码
mov cx,6 B9 06 00
mov ax,10h B8 10 00
s: add ax,ax 01 C0
loop s E2 FC
这段程序装在内存中的不同位置都可正确执行，因为loop s在执行时只涉及s的位移（-4，前移4个字节，补码表示为FCH），而不是s的地址。
如果loop s的机器码中包含的是s的地址，则就对程序段在内存中的偏移地址有了严格的限制，因为机器码中包含的是s的地址，如果s处的指令不在目的地址处，程序的执行就会出错。
而loop s的机器码中包含的是转移的位移，就不存在这个问题了，因为，无论s处的指令的实际地址是多少，loop指令的转移位移是不变的。
注意，根据位移进行转移的指令，它们的转移范围受到转移位移的限制，如果在源程序中出现了转移范围超界的问题，在编译的时候，编译器将报错。
比如，下面的程序将引起编译错误：
assume cs:code
code segment
start: jmp short s
db 128 dup (0)
s: mov ax,0ffffh
code ends
end start
jmp short s 的转移范围是-128～127，IP最多向后移动127个字节。
注意，我们在第2章中讲到的形如“jmp 2000:0100"的转移指令，是在Debug中使用的汇编指令，汇编编译器并不认识。如果在源程序中使用，编译时也会报错。
