Oracle sql优化示例

1. 循环插入1到10w数值

create or replace procedure proc_test 
as
begin
  for i in 1..100000
    loop
      execute immediate
      'insert into t values(' || i || ')';
      commit;
    end loop;
end;
/

2. 使用变量绑定，减少sql解析

create or replace procedure proc_test 
as
begin
  for i in 1..100000
    loop
      execute immediate
      'insert into t values(:x) ' using i; ---使用变量，sql只需解析一次，而第一种写法，需要解析1w次。
      commit;
    end loop;
end;
/

3. 使用静态SQL，编译过程即完成解析，而动态SQL是在执行过程中解析的

create or replace procedure proc_test 
as
begin
  for i in 1..100000
    loop
      --execute immediate 删除该行, execute immediate是一种动态SQL写法, 常用于表名，字段名是变量，入参的情况，但这里表名是已知的，直接用静态SQL即可，
         --静态SQL会自动使用绑定变量, 而且是在编译过程就解析好了，而动态SQL是在执行过程中解析的。
      insert into t values(i); 
      commit;
    end loop;
end;
/

4. 批量commit.

create or replace procedure proc_test 
as
begin
  for i in 1..100000
    loop
      insert into t values(i);
    end loop;
    commit; --批量提交
end;
/

5. 写成一条sql，由原来过程一条一条插入，变成一个集合的概念，一整批写入DATA BUFFER区。

insert into t select rownum from dual connect by level<=1000000;
commit;

6. 直接路径方式插入数据，insert into t select ...是将数据先写入DATA BUFFER中，再刷到磁盘里，而create table t ...跳过了数据缓存区，直接写入磁盘。

这种方式一般用于数据迁移。

create table t as select rownum x from dual connect by level<=1000000;

 7. 还有一种方法，在多CPU机器上，关闭日志nologging，并且设置parallel 16 表示用到16个CPU。

不过该方法会占用大量CPU资源，比较影响其他应用，使用时要三思而后行。

create table t nologging parallel 16 
as select rownum x from dual connect by level<=1000000;