获取矩形中心点与矩形外某点连线和矩形交点的算法

　　图形化广泛应用于各种系统中，包括ESB的适配，业务流程的建模，工作流程的定制，数据交换系统的配置等等，这其中不可避免的需要用到各种图形符号来直观、清晰的表达抽象的内容。一般来说，我们会通过标准的图形来表述特定的含义，达到交流的目的，而图形间信息导向一般都是通过线来完成的，一个好的画线算法，不仅能够让业务或者配置图更加美观，也更能清晰的向受众表述业务或者配置内容。

　　本文实现了一个获取矩形中心点与矩形外某点连线与矩形交点的算法。实现语言为ActionScript。

 

/**
         * 获得一个矩形中心点到矩形外某点之间的连线与矩形的交点
         * 算法思路：
         * 以矩形外的某点为坐标原点，将图形分为四个象限，每个象限分两种情况，坐标轴上单独处理
         * 1.坐标轴的情况：
         *     1.负x轴的情况
         *     2.正x轴的情况
         *     3.正y轴的情况
         *     4.负y轴的情况
         * 2.象限情况：
         *     2.1.第一象限：连线与矩形左边相交的情况；与矩形下边相交的情况
         *    2.2.第二象限：连线与矩形右边相交的情况；与矩形下边相交的情况
         *     2.3.第三象限：连线与矩形右边相交的情况；与矩形上边相交的情况
         *     2.4.第四象限：连线与矩形左边相交的情况；与矩形上边相交的情况
         * 
         * */
        private function getIntersectPoint(fromNode:Rectangle,endPoint:Point):Point
        {
            //开始矩形的x坐标
             var x1:Number=fromNode.x;
            //开始矩形的y坐标
             var y1:Number=fromNode.y;
            //结束点的x坐标
            var x2:Number=endPoint.x;
            //结束点的y坐标
            var y2:Number=endPoint.y;
            
            //开始矩形的中心点x坐标
            var fromCenterX:Number=x1+fromNode.width/2;
            //开始矩形的中心点的y坐标
            var fromCenterY:Number=y1+fromNode.height/2;
            //矩形和点之间的x坐标相对距离
            var dx:Number=Math.abs(x1-x2);
            //矩形和点之间的y坐标相对距离
            var dy:Number=Math.abs(y1-y2);
            //相对距离的正切值
            var tanDYX:Number=dy/dx;
            //开始矩形的正切值
            var fromDYX:Number=fromNode.height/fromNode.width;
            
            var returnPoint:Point=null;
            //负x轴
            if(y1==y2&&x1<x2)
            {
                returnPoint= new Point(x1+fromNode.width,fromCenterY);
            }
            //正x轴
            else if(y1==y2&&x1>x2)
            {
                returnPoint= new Point(x1,fromCenterY);
            }
            //正y轴
            else if(x1==x2&&y1<y2)
            {
                returnPoint= new Point(fromCenterX,y1+fromNode.height);
            }
            //负y轴
            else if(x1==x2&&y1>y2)
            {
                returnPoint= new Point(fromCenterX,y1);
            }
            //第一象限
            if(x1>x2&&y1<y2)
            {
                if(fromDYX>=tanDYX)
                {
                    returnPoint= new Point(x1,fromCenterY+tanDYX*fromNode.width/2);
                }
                else
                {
                    returnPoint= new Point(fromCenterX-dx/dy*fromNode.height/2,y1+fromNode.height);
                }
            }
            //第二象限
            else if(x1<x2&&y1<y2)
            {
                //
                if(fromDYX>=tanDYX)
                {
                    returnPoint= new Point(x1+fromNode.width,fromCenterY+tanDYX*fromNode.width/2);
                }
                else
                {
                    returnPoint= new Point(fromCenterX+dx/dy*fromNode.height/2,y1+fromNode.height);
                }
                
            }
            //第三象限
            else if(x1<x2&&y1>y2)
            {
                if(fromDYX>=tanDYX)
                {
                    returnPoint= new Point(x1+fromNode.width,fromCenterY-tanDYX*fromNode.width/2);
                }
                else
                {
                    returnPoint= new Point(fromCenterX+fromNode.height/2*dx/dy,y1);
                }
            }
            //第四象限
            else if(x1>x2&&y1>y2)
            {
                if(fromDYX>=tanDYX)
                {
                    returnPoint= new Point(x1,fromCenterY-fromNode.width/2*tanDYX);
                }
                else
                {
                    returnPoint= new Point(fromCenterX-fromNode.height/2*dx/dy,y1);
                }
            }
            return returnPoint;
        }