TClientDataSet[19]: 查找字段(fkLookup)

动态建立(其中的 School 字段是 Lookup 字段):

 

 

---

 

//先在窗体上放置: DBGrid1、DataSource1、ClientDataSet1、ClientDataSet2; 其他全用代码实现:

procedure TForm1.FormCreate(Sender: TObject);
begin
  { 关联控件 }
  DBGrid1.DataSource := DataSource1;
  DataSource1.DataSet := ClientDataSet1;

  { 把 ClientDataSet2 定义为一个 School 列表, 同时添加测试数据 }
  with ClientDataSet2 do begin
    FieldDefs.Add('ID', ftInteger);
    FieldDefs.Add('Name', ftString, 20);
    CreateDataSet;
    AppendRecord([1, '哈佛大学']);
    AppendRecord([2, '斯坦福大学']);
    AppendRecord([3, '耶鲁大学']);
    AppendRecord([4, '加州理工学院']);
    AppendRecord([5, '加州大学']);
    AppendRecord([6, '剑桥大学']);
    AppendRecord([7, '麻省理工学院']);
    AppendRecord([8, '牛津大学']);
    AppendRecord([9, '哥伦比亚大学']);
    MergeChangeLog;
    SaveToFile('C:\Temp\School.xml', dfXMLUTF8); { 保存下, 也给后面的例子用 }
  end;

  { 下面是定义 ClientDataSet1; 先添加两个普通字段 }
  with TStringField.Create(Self) do
  begin
    FieldName := 'Student';   { 用于显示学生名称 }
    Size := 12;
    DataSet := ClientDataSet1;
  end;
  with TIntegerField.Create(Self) do
  begin
    FieldName := 'School_ID'; { 用于和 ClientDataSet2 的 ID 字段关联 }
    DataSet := ClientDataSet1;
  end;

  { 添加 Lookup 字段 }
  { 通过 School_ID 和 ClientDataSet2.ID 的关联, 从 ClientDataSet2 中查找 Name 字段的值 }
  with TStringField.Create(Self) do
  begin
    FieldName := 'School';
    FieldKind := fkLookup;   { 上两个字段会默认 FieldKind := fkData }
    DataSet := ClientDataSet1;
    KeyFields := 'School_ID';
    LookupDataSet := ClientDataSet2;
    LookupKeyFields := 'ID';
    LookupResultField := 'Name';
  end;
  ClientDataSet1.CreateDataSet;
end;

---

设计时添加 Lookup 字段(其中 ClientDataSet2 使用了上面刚保存的 School.xml):