delphi – 自定义组件和Tab键顺序

我有一个自定义组件(继承自TCustomPanel),它由两个其他组件组成(比方说两个编辑).如何在使用组件时正确获取Tab键顺序？

在Tab键顺序设计器中,我只能访问无法获得焦点的组件本身,因为它是一个面板.在运行时发生的事情是我可以使用tab键访问编辑,但只有在组件下方的两个按钮聚焦后才能访问.

如何在这种情况下更改Tab键顺序？

解决方法

组件中嵌套控件的Tab键顺序与组件所在表单的Tab键顺序不同.当您选中嵌套控件时,表单的Tab键顺序列表中组件的Tab键顺序.一旦所有Tab键顺序列表合并,它们将导致最终循环：

>表单上的控件(TabOrder = 0)
>表单上的另一个控件(TabOrder = 1)
>您的面板组件(TabOrder = 2)

>编辑1(TabOrder = 0)
>编辑2(TabOrder = 1)

>表单上的另一个控件(TabOrder = 3)

为了能够设置面板组件设计时间的Tab键顺序：

>使用设计器中的Tab键顺序编辑器(右键单击组件的父级)并使用编辑器中的箭头更改Tab键顺序,或者
>发布组件的TabOrder属性并在对象检查器中设置它：

type 
  TMyPanel = class(TCustomPanel) 
  published 
    property TabOrder; 
  end;

在运行时,始终可以设置组件的Tab键顺序,因为TabOrder属性在TWinControl中声明为public.

… which cannot have focus because it is a panel.

不,一个面板可以很好地聚焦,但默认情况下不会.这是使用TabStop属性处理的,默认情况下为False.您不希望TabStop为您的组件设置True,因为(1)面板没有指示它有焦点,(2)它不是(我想象的).

更改嵌套控件的Tab键顺序最好在组件的构造函数中或在运行时完成.

为了能够在设计时在组件内设置嵌套控件的Tab键顺序,需要更多的工作.我不认为你想要那个,但是因为我之前的回答(删除)是垃圾(并投票,扼杀)我已经找到了一个例子作为补偿.

首先,请注意,使用设计器中的Tab键顺序编辑器设置这些编辑的Tab键顺序(右键单击面板组件)将更改Tab键顺序,但它不会持续.那是因为这些更改没有流式传输到DFM.

为了能够流式传输/保存控件的设计时更改,您需要发布它们：

type
  TMyPanel = class(TCustomPanel)
  private
    FEdit1: TEdit;
    FEdit2: TEdit;
  public
    constructor Create(AOwner: TComponent); override;
  published 
    property Edit1: TEdit read FEdit1;
    property Edit2: TEdit read FEdit2;
  end;
 
constructor TMyPanel.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  FEdit1 := TEdit.Create(Self);
  FEdit1.SetBounds(10,10,100,21);
  FEdit1.Name := 'Edit1';
  FEdit1.Parent := Self;
  FEdit1.SetSubComponent(True);
  FEdit2 := TEdit.Create(Self);
  FEdit2.SetBounds(10,41,21);
  FEdit2.Name := 'Edit2';
  FEdit2.Parent := Self;
  FEdit2.SetSubComponent(True);
end;

当然,这会发布这些控件的所有属性,现在用户可以随意更改.要防止这种情况,请考虑限制TEdit控件的已发布属性：

unit MyPanelEdit;
 
interface
 
uses
  DesignEditors,Unit2,DesignIntf,SysUtils,Classes,TypInfo,StdCtrls;
 
type
  TEditProperty = class(TComponentProperty)
  private
    function FilterFunc(const ATestEditor: IProperty): Boolean;
  public
    function GetAttributes: TPropertyAttributes; override;
    procedure GetProperties(Proc: TGetPropProc); override;
  end;
 
procedure Register;
 
implementation
 
procedure Register;
begin
  RegisterPropertyEditor(TypeInfo(TEdit),TMyPanel,'',TEditProperty);
end;
 
{ TEditProperty }
 
function TEditProperty.FilterFunc(const ATestEditor: IProperty): Boolean;
begin
  Result := ATestEditor.GetName = 'TabOrder';
end;
 
function TEditProperty.GetAttributes: TPropertyAttributes;
begin
  Result := [paSubProperties];
end;
 
procedure TEditProperty.GetProperties(Proc: TGetPropProc);
var
  LComponents: IDesignerSelections;
  LDesigner: IDesigner;
begin
  LComponents := GetSelections;
  if LComponents <> nil then
  begin
    if not Supports(
        FindRootDesigner(LComponents[0]),IDesigner,LDesigner) then
      LDesigner := Designer;
    GetComponentProperties(LComponents,[tkInteger],LDesigner,Proc,FilterFunc);
  end;
end;
 
end.

这会将已发布的TEdit属性的属性限制为仅显示TabOrder.