登入验证机制实作

在 ASP.NET 2.0 提供的 Membership 功能，可以很方便的制作登入验证的动作；不过有时因为特殊需求需要自行制作登入验证机制，例如制作现行构系统的 Web 前端，可能就需要呼叫中间层去执行登入验证的动作，在此提供一个登入验证机制的实作。

我们将登入验证机制包含在一个独立组件中，新的网站应用程序只需参考这个组件就可以使用登入验证机制。此组件中包的类别如下表及下图所示。

型别	说明
TUserInfo	使用者信息。
TBBasePage	页面基础类别。
TBLoginPage	登入页面基础类别。

 

 

．TUserInfo 类别

其中 IUserInfo 接口是定义在更上层的组件中，是为了三层式架构中传递使用者信息使用，例如 Web 组件(ASP.NET)传递到中间层组件(.NET)使用，当然在这个案例中，你也可以直接定义 TUserInfo 类别即可。

TUserInfo 类别的程序代码如下，此案例中只会使用到 IsLogin 属性。

Public Class TUserInfo
    Implements IUserInfo

    Private FID As String = String.Empty
    Private FName As String = String.Empty
    Private FGuid As Guid = Guid.Empty
    Private FHandle As Integer = 0
    Private FSessionID As String = String.Empty
    Private FIsLogin As Boolean = False

    ''' <summary>
    ''' 建构函式。
    ''' </summary>
    Sub New()
        FGuid = Guid.NewGuid()
    End Sub

    ''' <summary>
    ''' 使用者账号。
    ''' </summary>
    Public Property ID() As String Implements IUserInfo.ID
        Get
            Return FID
        End Get
        Set(ByVal value As String)
            FID = value
        End Set
    End Property

    ''' <summary>
    ''' 使用者名称。
    ''' </summary>
    Public Property Name() As String Implements IUserInfo.Name
        Get
            Return FName
        End Get
        Set(ByVal value As String)
            FName = value
        End Set
    End Property

    ''' <summary>
    ''' 执行阶段使用者识别码。
    ''' </summary>
    Public Property Guid() As System.Guid Implements IUserInfo.Guid
        Get
            Return FGuid
        End Get
        Set(ByVal value As System.Guid)
            FGuid = value
        End Set
    End Property

    ''' <summary>
    ''' 执行阶段使用者识别句柄。
    ''' </summary>
    Public Property Handle() As Integer Implements IUserInfo.Handle
        Get
            Return FHandle
        End Get
        Set(ByVal value As Integer)
            FHandle = value
        End Set
    End Property

    ''' <summary>
    ''' 执行阶段使用者标识符串。
    ''' </summary>
    Public Property SessionID() As String Implements IUserInfo.SessionID
        Get
            Return FSessionID
        End Get
        Set(ByVal value As String)
            FSessionID = value
        End Set
    End Property

    ''' <summary>
    ''' 是否已登入。
    ''' </summary>
    Public Property IsLogin() As Boolean Implements IUserInfo.IsLogin
        Get
            Return FIsLogin
        End Get
        Set(ByVal value As Boolean)
            FIsLogin = value
        End Set
    End Property
End Class

 

．TBBasePage 类别

TBBasePage 是页面基础类别，主要做判断是否登入，若未登入则转址到定义的登入页面。TBBasePage 类别的主要属性如下表所示。

属性	说明
IsCheckLogin	是否做登入验证，预设为 True。 继承 TBBasePage 的页面预设是需要做登入验证的，若有页面不需做登入验证(如登入页面)，则需要覆写此属性传回 False。
LoginUrl	登入页面网址。 预设是读取 web.config 中 appSettings 区段的 LoginUrl 参数值。你也可以覆写此属性，改写登入页面网址的定义方式。
UserInfo	使用者信息。此属性是储存于 Seesion 中。

 

TBBasePage 类别的完整程序代码如下所示，其中覆写 OnInit 方法，判断此页面是否做登入验证；若需要做登入验证时，则使用 UserInfo.IsLogin 来判断是否已登入，若未登入则转址到 LoginUrl 属性指定的登入页面网址。

Imports Bee.App

''' <summary>
''' 页面基础类别。
''' </summary>
Public Class TBBasePage
    Inherits System.Web.UI.Page

    Private Const KEY_USERINFO As String = "_UserInfo"
    Private FUserInfo As TUserInfo = Nothing


    ''' <summary>
    ''' 是否做登入验证。
    ''' </summary>
    Protected Overridable ReadOnly Property IsCheckLogin() As Boolean
        Get
            Return True
        End Get
    End Property

    ''' <summary>
    ''' 取得 Web.config 中 appSettings 区段定义的参数。
    ''' </summary>
    Public Overloads Function AppSettings(ByVal Name As String) As String
        Return AppSettings(Name, String.Empty)
    End Function

    ''' <summary>
    ''' 取得 Web.config 中 appSettings 区段定义的参数。
    ''' </summary>
    Public Overloads Function AppSettings(ByVal Name As String, ByVal DefaultValue As String) As String
        Dim sValue As String

        sValue = System.Web.Configuration.WebConfigurationManager.AppSettings(Name)
        If sValue Is Nothing Then
            Return DefaultValue
        Else
            Return sValue
        End If
    End Function

    ''' <summary>
    ''' 登入页面网址。
    ''' </summary>
    Public Overridable ReadOnly Property LoginUrl() As String
        Get
            Dim sUrl As String
            sUrl = Me.AppSettings("LoginUrl")
            If String.IsNullOrEmpty(sUrl) Then
                Throw New Exception("未设定登入页面")
            Else
                Return sUrl
            End If
        End Get
    End Property

    ''' <summary>
    ''' 使用者信息。
    ''' </summary>
    Public ReadOnly Property UserInfo() As TUserInfo
        Get
            If FUserInfo Is Nothing Then
                If Me.Session(KEY_USERINFO) Is Nothing Then
                    FUserInfo = New TUserInfo()
                    Me.Session(KEY_USERINFO) = FUserInfo
                Else
                    FUserInfo = CType(Me.Session(KEY_USERINFO), TUserInfo)
                End If
            End If
            Return FUserInfo
        End Get
    End Property

    Protected Overrides Sub OnInit(ByVal e As System.EventArgs)
        '判断是否做登入验证
        If Me.IsCheckLogin Then
            '判断是否登入，若未登入则转址到登入页面
            If Not Me.UserInfo.IsLogin Then
                Page.Response.Redirect(Me.LoginUrl)
            End If
        End If

        MyBase.OnInit(e)
    End Sub
End Class

 

．TBLoginPage 类别

TBLoginPage 类别是登入页面基础类别。TBLoginPage 类别是继承 TBBasePage 类别，因为它是登入页面所需无须做登入验证，所以覆写 IsCheckLogin 方法传回 False。自行撰写的登入页面可以继承 TBLoginPage 类别，并覆写 ExecuteLogin 方法实作登入验证的动作；按下登入钮时，则是呼叫 Login 方法来进行登入。

''' <summary>
''' 登入页面基础类别。
''' </summary>
Public MustInherit Class TBLoginPage
    Inherits TBBasePage

    ''' <summary>
    ''' 是否做登入验证。
    ''' </summary>
    Protected Overrides ReadOnly Property IsCheckLogin() As Boolean
        Get
            Return False
        End Get
    End Property

    ''' <summary>
    ''' 执行登入验证，衍生类别必须覆写。
    ''' </summary>
    ''' <param name="UserID">登入账号。</param>
    ''' <param name="Password">登入密码。</param>
    ''' <returns>登入成功传回 Treu，反之传回 False。</returns>
    Protected MustOverride Function ExecuteLogin(ByVal UserID As String, ByVal Password As String) As Boolean

    ''' <summary>
    ''' 执行登入。
    ''' </summary>
    ''' <param name="UserID">登入账号。</param>
    ''' <param name="Password">登入密码。</param>
    Protected Overridable Sub Login(ByVal UserID As String, ByVal Password As String)
        If ExecuteLogin(UserID, Password) Then
            Me.UserInfo.IsLogin = True
            Me.Response.Redirect("~/")
        Else
            Me.ClientScript.RegisterStartupScript(Me.GetType, "LoginError", "alert('登入错误');", True)
        End If
    End Sub

End Class

 

．撰写 ASP.NET 网站应用程序测试登入

再来新增一个新的 ASP.NET 网站应用程序，首先在其 web.config 中定义登入页面网址为 "~/Login.aspx"。

  <appSettings>
    <add key="LoginUrl" value="~/Login.aspx"/>
  </appSettings>

 

撰写登入网页命名为 Login.aspx，此页面继承 TBLoginPage 类别，并覆写 ExecuteLogin 方法。在此做登入测试，故在 ExecuteLogin 方法中只判断登入账号/密码为 admin/admin 时即传回 True，表示登入成功。实际使用时可以在此方法自行连结数据库或呼叫中间层做身份认识的动作。当按下「登入」钮时，只需呼叫 TBLoginPage 的 Login 方法传入账号/密码即可。

在网站中任何新增的页面只要继承 TBBasePage，当使用者浏览该网页时，就会由机制处理登入验证的动作，无需在页面做相关控管。

 

Login.aspx 程序代码

<%@ Page Language="VB" AutoEventWireup="false" CodeFile="Login.aspx.vb" Inherits="Login" %>

<html xmlns="http://www.w3.org/1999/xhtml">
<head runat="server">
    <title>未命名页面</title>
</head>
<body>
    <form id="form1" runat="server">
        <div>
            <table align="center" style="border: #0066cc solid 1px" border="1">
                <tr>
                    <td align="center" colspan="3" style="height: 20px; color: white; background-color: #3366cc">
                        登入</td>
                </tr>
                <tr>
                    <td align="center" style="width: 83px; height: 17px; text-align: right;">
                        账号
                    </td>
                    <td align="center" style="height: 17px; text-align: left; width: 209px;">
                        <asp:TextBox ID="txtLoginID" runat="server" Width="200px" AutoCompleteType="Disabled"
                            CssClass="username"></asp:TextBox></td>
                </tr>
                <tr>
                    <td align="center" style="width: 83px; height: 21px; text-align: right;">
                        密码
                    </td>
                    <td align="center" style="height: 21px; text-align: left; width: 209px;">
                        <asp:TextBox ID="txtLoginPwd" runat="server" Width="200px" TextMode="Password" AutoCompleteType="Disabled"
                            EnableViewState="False" CssClass="password"></asp:TextBox></td>
                </tr>
                <tr>
                    <td colspan="3" style="text-align: right; vertical-align: text-bottom; height: 30px;">
                        <asp:Button ID="btnLogin" runat="server" Text="登入" />
                    </td>
                </tr>
            </table>
        </div>
    </form>
</body>
</html>

 

Login.aspx.vb

Partial Class Login
    Inherits Bee.Web.TBLoginPage

    ''' <summary>
    ''' 执行登入验证。
    ''' </summary>
    ''' <param name="UserID">登入账号。</param>
    ''' <param name="Password">登入密码。</param>
    ''' <returns>登入成功传回 Treu，反之传回 False。</returns>
    Protected Overrides Function ExecuteLogin(ByVal UserID As String, ByVal Password As String) As Boolean
        If UserID = "admin" AndAlso Password = "admin" Then
            Return True
        Else
            Return False
        End If
    End Function

    Protected Sub btnLogin_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles btnLogin.Click
        Me.Login(txtLoginID.Text, txtLoginPwd.Text)
    End Sub
End Class