(5)打造简单OS-进入保护模式
1.简介：
8086实模式
80286才出现保护模式，保护模式下的段寄存器存储的是段选择子，不在是8086实模式的段基址了！
[扩展知识]：可以看了后面知识在回头看一下这段.
[8086各个段寄存器和通用寄存器都是16位，地址总线20位，采用段式段+偏移可访问物理内存1M]
[80286各个段寄存器和通用寄存器都是16位，地址总线24位，采用段式选择子+偏移可访问虚拟内存1G；物理内存16M]
80286全局描述符表一项是占8字节，其中段基址占3字节(24位与地址总线一致)
[80386段寄存器依然16位，通用寄存器也各自扩展到了32位，地址总线32位，采用段页式(选择子+偏移+分页)可访问虚拟内存4G；物理内存4G]
80386全局描述符表一项也是占8字节，其中段基址占4字节(32位与地址总线一致)，也是在80286描述符基础上增加了些位域内容
2.选择子
保护模式下的段寄存器存储的是段选择子！这时候选择子相当于数组中的索引，那么怎么用这13位索引获取段基址呢？段寄存器16位每个位域代表意思具体结构如下：
用高13位索引获取段基址，这样我们必须要在内存某个地方去保存例如实模式下的各个段寄存器的值，另外在加上一些限制和保护体现，最终会形成一种叫做全局描述符表！全局描述符表只是一个概念，也就是描述一个数据的结构组成。描述符表由一项一项的描述符组成，其中每一项占8字节。
既然是索引，就像数组那样总该有个地址可以确定这个数组的首地址吧，在80386中有一个这样的寄存器GDTR里面由软件写入地址，这个地址里存放的便是全局描述符表的首地址，然后利用[首地址+8*索引值]就可以算出最终所要找到的全局描述符表中的一项，即 段选择子指向的描述符地址= GDTR里存的地址 +８×索引
选择子高13位索引即可索引到2的13次方8192个描述符[0~8191]，与GDT界限的16位界限一致，因GDTR是48位寄存器，其中32位是GDTR存储的基址，16位是界限！即GDT界限大小为2的16次方65536，又因为每个描述符占8位，65536/8=8192！所以综上所述，选择子高13位索引和描述符表界限一致!
扩展知识：如何获取段基址https://blog.csdn.net/jadeshu/article/details/72837230
......待添加内容
3.进入保护模式需要以下几个步骤：
-
打开A20
-
加载gdt ：进入保护模式需要使用GDTR，则需要加载设置GDTR
-
将cr0寄存器的PE位置设为1
演示程序
mbr.s
;主引导程序
;------------------------------------------------------------
SECTION MBR vstart=0x7c00
mov ax,cs
mov ds,ax
mov es,ax
mov ss,ax
mov fs,ax
mov sp,0x7c00
mov ax,0xb800
mov gs,ax
; 清屏
;利用0x06号功能，上卷全部行，则可清屏。
; -----------------------------------------------------------
;INT 0x10 功能号:0x06 功能描述:上卷窗口
;------------------------------------------------------
;输入：
;AH 功能号= 0x06
;AL = 上卷的行数(如果为0,表示全部)
;BH = 上卷行属性
;(CL,CH) = 窗口左上角的(X,Y)位置
;(DL,DH) = 窗口右下角的(X,Y)位置
;无返回值：
mov ax, 0600h
mov bx, 0700h
mov cx, 0 ; 左上角: (0, 0)
mov dx, 184fh ; 右下角: (80,25),
; 因为VGA文本模式中，一行只能容纳80个字符,共25行。
; 下标从0开始，所以0x18=24,0x4f=79
int 10h ; int 10h
; 输出字符串:MBR
mov byte [gs:0x00],'L'
mov byte [gs:0x01],0xA4
mov byte [gs:0x02],'o'
mov byte [gs:0x03],0xA4
mov byte [gs:0x04],'a'
mov byte [gs:0x05],0xA4 ;A表示绿色背景闪烁，4表示前景色为红色
mov byte [gs:0x06],'d'
mov byte [gs:0x07],0xA4
mov byte [gs:0x08],'!'
mov byte [gs:0x09],0xA4
mov eax,0x2 ; 起始扇区lba地址.第2个扇区
mov bx,0x900 ; 写入的地址 0x900
mov cx,4 ; 待读入的扇区数 4
call rd_disk_m_16 ; 以下读取程序的起始部分（一个扇区）
jmp 0x900 ;跳转到0x900地址
;-------------------------------------------------------------------------------
;功能:读取硬盘n个扇区
rd_disk_m_16:
;-------------------------------------------------------------------------------
; eax=LBA扇区号
; ebx=将数据写入的内存地址
; ecx=读入的扇区数
mov esi,eax ;备份eax
mov di,cx ;备份cx
;读写硬盘:
;第1步：设置要读取的扇区数
mov dx,0x1f2
mov al,cl
out dx,al ;读取的扇区数
mov eax,esi ;恢复ax
;第2步：将LBA地址存入0x1f3 ~ 0x1f6
;LBA地址7~0位写入端口0x1f3
mov dx,0x1f3
out dx,al
;LBA地址15~8位写入端口0x1f4
mov cl,8
shr eax,cl
mov dx,0x1f4
out dx,al
;LBA地址23~16位写入端口0x1f5
shr eax,cl
mov dx,0x1f5
out dx,al
shr eax,cl
and al,0x0f ;lba第24~27位
or al,0xe0 ; 设置7～4位为1110,表示lba模式
mov dx,0x1f6
out dx,al
;第3步：向0x1f7端口写入读命令，0x20
mov dx,0x1f7
mov al,0x20
out dx,al
;第4步：检测硬盘状态
.not_ready:
;同一端口，写时表示写入命令字，读时表示读入硬盘状态
nop
in al,dx
and al,0x88 ;第4位为1表示硬盘控制器已准备好数据传输，第7位为1表示硬盘忙
cmp al,0x08
jnz .not_ready ;若未准备好，继续等。
;第5步：从0x1f0端口读数据
mov ax, di
mov dx, 256
mul dx
mov cx, ax ; di为要读取的扇区数，一个扇区有512字节，每次读入一个字，
; 共需di*512/2次，所以di*256
mov dx, 0x1f0
.go_on_read:
in ax,dx
mov [bx],ax
add bx,2
loop .go_on_read
ret
; times 510-($-$$) db 0
; db 0x55,0xaa
loader.s
;-------------- gdt描述符属性 -----------
DESC_G_4K equ 1_00000000000000000000000b
DESC_D_32 equ 1_0000000000000000000000b
DESC_L equ 0_000000000000000000000b ; 64位代码标记，此处标记为0便可。
DESC_AVL equ 0_00000000000000000000b ; cpu不用此位，暂置为0
DESC_LIMIT_CODE2 equ 1111_0000000000000000b
DESC_LIMIT_DATA2 equ DESC_LIMIT_CODE2
DESC_LIMIT_VIDEO2 equ 0000_000000000000000b
DESC_P equ 1_000000000000000b
DESC_DPL_0 equ 00_0000000000000b
DESC_DPL_1 equ 01_0000000000000b
DESC_DPL_2 equ 10_0000000000000b
DESC_DPL_3 equ 11_0000000000000b
DESC_S_CODE equ 1_000000000000b
DESC_S_DATA equ DESC_S_CODE
DESC_S_sys equ 0_000000000000b
;x=1,c=0,r=0,a=0 代码段是可执行的,非依从的,不可读的,已访问位a清0.
DESC_TYPE_CODE equ 1000_00000000b
;x=0,e=0,w=1,a=0 数据段是不可执行的,向上扩展的,可写的,已访问位a清0.
DESC_TYPE_DATA equ 0010_00000000b
DESC_CODE_HIGH4 equ (0x00 << 24) + DESC_G_4K + DESC_D_32 + DESC_L + DESC_AVL + DESC_LIMIT_CODE2 + DESC_P + DESC_DPL_0 + DESC_S_CODE + DESC_TYPE_CODE + 0x00
DESC_DATA_HIGH4 equ (0x00 << 24) + DESC_G_4K + DESC_D_32 + DESC_L + DESC_AVL + DESC_LIMIT_DATA2 + DESC_P + DESC_DPL_0 + DESC_S_DATA + DESC_TYPE_DATA + 0x00
DESC_VIDEO_HIGH4 equ (0x00 << 24) + DESC_G_4K + DESC_D_32 + DESC_L + DESC_AVL + DESC_LIMIT_VIDEO2 + DESC_P + DESC_DPL_0 + DESC_S_DATA + DESC_TYPE_DATA + 0x0b
;-------------- 选择子属性 ---------------
RPL0 equ 00b
RPL1 equ 01b
RPL2 equ 10b
RPL3 equ 11b
TI_GDT equ 000b
TI_LDT equ 100b
;--------------------------------------------
section loader vstart=0x900
jmp loader_start
;构建gdt及其内部的描述符===============================================
GDT_BASE: dd 0x00000000
dd 0x00000000
CODE_DESC: dd 0x0000FFFF
dd DESC_CODE_HIGH4
DATA_STACK_DESC: dd 0x0000FFFF
dd DESC_DATA_HIGH4
VIDEO_DESC: dd 0x80000007 ; limit=(0xbffff-0xb8000)/4k=0x7
dd DESC_VIDEO_HIGH4 ; 此时dpl为0
GDT_SIZE equ $ - GDT_BASE
GDT_LIMIT equ GDT_SIZE - 1
times 60 dq 0 ; 此处预留60个描述符的空位(slot)
SELECTOR_CODE equ (0x0001<<3) + TI_GDT + RPL0 ; 8[1000] 相当于(CODE_DESC - GDT_BASE)/8 + TI_GDT + RPL0
SELECTOR_DATA equ (0x0002<<3) + TI_GDT + RPL0 ; 16[10000] 同上
SELECTOR_VIDEO equ (0x0003<<3) + TI_GDT + RPL0 ; 24[11000] 同上
;以下是定义gdt的指针，前2字节是gdt界限，后4字节是gdt起始地址
gdt_ptr dw GDT_LIMIT
dd GDT_BASE
;======================================================================
loader_start:
;----------------- 准备进入保护模式 -------------------
;1 打开A20
;2 加载gdt
;3 将cr0的pe位置1
;----------------- 打开A20 ----------------
in al,0x92
or al,0000_0010B
out 0x92,al
;----------------- 加载GDT ----------------
lgdt [gdt_ptr]
;----------------- cr0第0位置1 ----------------
mov eax, cr0
or eax, 0x00000001
mov cr0, eax
jmp dword SELECTOR_CODE:p_mode_start ; 刷新流水线，避免分支预测的影响,这种cpu优化策略，最怕jmp跳转，
; 这将导致之前做的预测失效，从而起到了刷新的作用。
[bits 32]
p_mode_start:
mov ax, SELECTOR_DATA
mov ds, ax
mov es, ax
mov ss, ax
mov esp,0x900
mov ax, SELECTOR_VIDEO
mov gs, ax
;160=80个字符[80*2]
mov byte [gs:160*8], 'J'
mov byte [gs:160*8+1],0x02
mov byte [gs:160*8+2], 'a'
mov byte [gs:160*8+3],0x02
mov byte [gs:160*8+4], 'd'
mov byte [gs:160*8+5],0x02
mov byte [gs:160*8+6], 'e'
mov byte [gs:160*8+7],0x02
mov byte [gs:160*8+8], ' '
mov byte [gs:160*8+9],0x00
mov byte [gs:160*8+10], 'O'
mov byte [gs:160*8+11],0x02
mov byte [gs:160*8+12], 'S'
mov byte [gs:160*8+13],0x02
jmp $程序说明图：
（1）是将硬盘中的MBR加载到内存0X7C00开始的位置，由BIOS完成
（2）mbr.s中将loader加载到内存0X900开始的位置
执行流程 BIOS[CS:IP 0XFFF0：FFF0]--》CS:IP[0：0X7C00]----(MBR将loader加载到0X900)--->CS:IP[0:0X900]---(loader中)
最后进行汇编编译
nasm mbr.S -o mbr 编译产生mbr文件
nasm loader.S -o loader 编译产生loader文件
编译后产生的两个文件放入C++工程中，在用上节中的C++代码进行编译结果生成boot.img文件，最后直接用Bochs进行测试，前面章节都有介绍如何操作，就不做讲解了!
实验结果:
