rem 要使用devenv命令, 需要把你本地的devenv路径添加的系统环境变量里面, 或者你在下面敲入devenv绝对路径.
rem 然后在HKEY_CLASSES_ROOT\Directory\shell这个注册表里面加一个新的项, command内容是D:\svn\ime\zhangfangxue\ClearSrc.bat %1
rem 也就是说, 把本文件保存为ClearSrc.bat, 然后再把它加到右键菜单里面, 上面一行就是把这个命名加到右键菜单.
rem 添加右键菜单的具体方法如下(以EditPlus V1.1为例):
rem 1、打开注册表编辑器(Regedit.exe)。
rem 2、找到主键HKEY_CLASSES_ROOT\*
rem 3、用鼠标右键单击*,选择新建主键,Shell (UPD.要先找到Folder这个项, 修改的是Folder\Shell)
rem 4、在Shell内再新建主键edit,进入edit,新建主键command
rem 5、在主键Shell右边的“默认”中删除健值(显示为“”)。
rem 6、进入edit,双击(默认),把它的值改为新增选项的名字(如EditPlus)。
rem 7、进入command,双击(默认),把它的值改为你所安装的软件的运行程序
rem 具体路径,最后再加一个“%1”(如C:\PROGRA~1\EDITPLUS\EDITPLUS.EXE %1)
for /r "%1" %%a in (*.sln) do (
devenv %%a /clean
)
cd "%1"
del *.ncb *.suo *.scc *.user *.aps *.obj *.ilk *.pdb *.idb *.pch *.dep *.res *.orig /s /f /a /q
del *.exe.embed.* *.exe.inter* *.dll.embed.* *.dll.inter* /s /f /a /q
del BuildLog.htm UpgradeReport*.* UpgradeLog.xml *.sln.old /s /f /a /q
for /f "delims=" %%i in ('dir /ad /b /s') do call :rd_dir_empty "%%i"
goto :eof
rem ======= 删除空目录 =========
:rd_dir_empty
rd %1 2>nul||goto :eof
set dir_route=%1
for /f "delims=" %%i in (%dir_route%) do (
set dir_route="%%~dpi"
for /f "delims=" %%j in ('dir /ad /b "%%~dpi"')do rd "%%~dpi%%j" 2>nul||goto :eof
)
:: 把路径最后的\去掉,以便set route_deepest="%%~dpi"能取到上一层路径
if "%dir_route:~-2,1%"=="\" set dir_route="%dir_route:~1,-2%"
if /i not "%cd%"==%dir_route% call :rd_dir_empty %dir_route%
goto :eof