读取bmp格式图片

flash加载外部数据：

Loader类可用于加载 SWF 文件或图像（JPG、PNG 或 GIF）文件。

URLLoader 类以文本、二进制数据或 URL 编码变量的形式从 URL 下载数据。

URLStream 类提供对下载 URL 的低级访问。 数据一下载，便可随即为 ActionScript 使用，这和使用 URLLoader 时需要等到整个文件下载完不同。 并且 URLStream 类还允许在完成下载前关闭流。 已下载文件的内容将作为原始二进制数据提供。

 

如果要加载图片一般使用的是Loader类，但是Loader类有一些不支持的文件比如bmp图片就加载不了。要解决这个问题可以使用URLLoader 类。通过URLLoader以二进制形式加载数据，然后将接收到的数据转换为bmp。 这个例子同样也可以扩张到其他Loader类不支持加载的文件。代码如下：


package
{
    import flash.display.MovieClip;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.net.URLRequest;
    import flash.net.URLLoaderDataFormat;
    import flash.display.BitmapData;
    import flash.display.Bitmap;
    import flash.net.URLLoader;
    import flash.utils.ByteArray;
    
    public class imageUrlLoadExample extends MovieClip
    {
        private var url:String = "http://issue2012.alog.cn/shake/upload/1337853313203-13751741307.bmp";
        private var urlLoader:URLLoader;
        
        public function imageUrlLoadExample()
        {
            urlLoader = new URLLoader();
            urlLoader.addEventListener(Event.COMPLETE, urlLoaderComplete);
            urlLoader.addEventListener(IOErrorEvent.IO_ERROR, urlLoaderIOError);
            urlLoader.dataFormat = URLLoaderDataFormat.BINARY;
            urlLoader.load(new URLRequest(url));
        }
        
        private function urlLoaderComplete(e:Event):void
        {
            var byteArr:ByteArray = ByteArray(urlLoader.data);
            var bitmapData:BitmapData = new BitmapData(10, 10);
            bitmapData = BMPEncoder.decode(byteArr);
            
            var bitmap:Bitmap = new Bitmap(bitmapData);
            addChild(bitmap);
        }
        
        private function urlLoaderIOError(e:IOErrorEvent):void
        {
            trace(e);
        }
    }
}

还有一个比较少用的URLStream 类，此类相对URLLoader类有个很突出的特点，就是可以不用等全部内容下载完的就可以使用。下给出一个例子：

package
{
    import flash.display.Loader;
    import flash.display.MovieClip;
    import flash.events.IOErrorEvent;
    import flash.net.URLStream;
    import flash.net.URLRequest;
    import flash.events.Event;
    import flash.events.ProgressEvent;
    import flash.utils.ByteArray;
    import flash.utils.getTimer;
    
    public class urlStreamExample extends MovieClip
    {
        private var url:String = "http://www.wohuia.com/files/information/352544/d2a2ca089f0560b6cdc61fef068ebe75.jpg";
        private var imageLoad:Loader;
        private var imageStream:URLStream;
        
        private var imageData:ByteArray;
        
        public function urlStreamExample()
        {
            imageLoad = new Loader();
            imageStream = new URLStream();
            imageStream.addEventListener(Event.COMPLETE, imageStreamComplete);
            imageStream.addEventListener(IOErrorEvent.IO_ERROR, imageStreamIOError);
            imageStream.addEventListener(ProgressEvent.PROGRESS, imageStreamProgress);
            startLoad(url);
        }
        
        private function startLoad(_url:String):void
        {
            if (imageStream.connected)
            {
                imageStream.close();
            }
            try
            {
                imageStream.load(new URLRequest(_url + "?" + getTimer()));
            }
            catch (error:Error)
            {
                trace("Unable to load requested document.");
            }
            //清除load
            imageLoad.unload();
            imageData = new  ByteArray();
            imageLoad.scaleX = imageLoad.scaleY = 0.5;
            addChild(imageLoad);
        }
        
        private function imageStreamProgress(e:ProgressEvent):void
        {
            if (imageStream.bytesAvailable == 0)
            {
                return;
            }
            progressData();
        }
        
        private function progressData():void
        {
            if (imageStream.connected)
            {
                imageStream.readBytes(imageData, imageData.length);
                trace("imageData" + imageData.bytesAvailable);
            }
            imageLoad.unload();
            imageLoad.loadBytes(imageData);
        }
        private function imageStreamComplete(e:Event):void
        {
            trace("imageStream.bytesAvailable" );
        }
        private function imageStreamIOError(e:IOErrorEvent):void {
            trace(e);
            
        }
    }

}