SQL Server 数据库初始化准备脚本

通常我们在项目部署前都会写一份数据库初始化脚本。由于数据库外键的限制，我们需要按照数据引用顺序添加初始记录，这个整理过程相当麻烦。

因此写了以下脚本，原理是先去掉所有外键，然后执行一次清空，然后添加数据，最后恢复外键。

网上也有暂时禁用外键添加数据的方法，但由于SQL Server在有外键的情况下，不能使用TRUNCATE TABLE语句，因此暂时禁用外键时，只能使用DELETE语句清除无用数据。如果觉得删除外键不安全，也可以考虑将以下脚本修改为禁用外键的方式运行。

脚本在 SQL Server 2005、SQL Server 2008 R2、SQL Server 2012 上测试过，都没有问题。

SET NOCOUNT ON;

DECLARE @script NVARCHAR(255);

--缓存所有外键
SELECT OBJECT_NAME(fk.constraint_object_id) AS name, OBJECT_NAME(fk.parent_object_id) AS ptab, pc.name AS pcol, OBJECT_NAME(fk.referenced_object_id) AS rtab, rc.name AS rcol
INTO #FK_ON
FROM sys.foreign_key_columns fk
LEFT JOIN sys.columns pc ON fk.parent_column_id = pc.column_id AND fk.parent_object_id = pc.[object_id]
LEFT JOIN sys.columns rc ON fk.referenced_column_id = rc.column_id AND fk.referenced_object_id = rc.[object_id];

BEGIN TRAN

--删除所有外键
DECLARE cur_fk_off CURSOR FOR SELECT 'ALTER TABLE [dbo].[' + OBJECT_NAME(parent_object_id) + '] DROP CONSTRAINT ' + name FROM sys.foreign_keys;
OPEN cur_fk_off
FETCH NEXT FROM cur_fk_off INTO @script
WHILE @@FETCH_STATUS = 0
BEGIN
    EXEC(@script)
    FETCH NEXT FROM cur_fk_off INTO @script
END
CLOSE cur_fk_off
DEALLOCATE cur_fk_off

--清空所有表
DECLARE cur_tabs CURSOR FOR SELECT 'TRUNCATE TABLE [dbo].[' + name + ']' FROM sys.tables;
OPEN cur_tabs
FETCH NEXT FROM cur_tabs INTO @script
WHILE @@FETCH_STATUS = 0
BEGIN
    EXEC(@script)
    FETCH NEXT FROM cur_tabs INTO @script
END
CLOSE cur_tabs
DEALLOCATE cur_tabs

--写入初始化数据
--INSERT INTO ...

--重建所有外键
DECLARE cur_fk_on CURSOR FOR SELECT 'ALTER TABLE [dbo].[' + ptab + '] ADD CONSTRAINT ' + name + ' FOREIGN KEY ([' + pcol + ']) REFERENCES [dbo].[' + rtab + '] ([' + rcol + '])' FROM #FK_ON;
OPEN cur_fk_on
FETCH NEXT FROM cur_fk_on INTO @script
WHILE @@FETCH_STATUS = 0
BEGIN
    EXEC(@script)
    FETCH NEXT FROM cur_fk_on INTO @script
END
CLOSE cur_fk_on
DEALLOCATE cur_fk_on

--清除缓存
DROP TABLE #FK_ON

COMMIT TRAN
GO

本文出自于 飞扬的尘埃的博客 转载请注明出处。