快速打开关闭sqlserver相关服务
前言
SQL Server安装后默认是一直随系统启动的，对于服务器当然没问题，但是对于个人开发而言，确实是不希望在不需要时一直运行相关SQL Server的服务。毕竟个人电脑性能有限，还是希望软件能够要用的才打开，不需要时能够释放占用的性能。
于是就有了这篇文章，提供一个脚本，需要时开启SQL Server相关服务，不需要是关闭SQL Server相关服务。
脚本
复制下面代码到文本文件，然后保存后改文件后缀名为.bat，然后以管理员身份运行
::脚本目的：需要用sqlserver快速开启相关服务，不需要时快速关闭相关服务已节省资源
::测试SQL版本：SQL Server 2008 R2
@ECHO OFF&CLS&color 0a
:HeadStart
ECHO=
ECHO= =-=-=-=-=-=选择开启或关闭=-=-=-=-=-=
ECHO= 1、开启sqlserver的6个相关服务
ECHO= 2、关闭sqlserver的6个相关服务
ECHO= 9、退出
ECHO= =-=-=-=-==-=-=-=-==-=-=-=-==-=-=-=
ECHO=
set/p ID= 请选择：
if "%id%"=="1" (
::数据库引擎
echo=***打开mssqlserver***
net start mssqlserver
::远程MSSMS管理
echo=***打开sqlserveragent***
net start sqlserveragent
::全文索引程序，一般mssqlserver服务启动后就会级联开启该服务
echo=***打开mssqlfdlauncher***
net start mssqlfdlauncher
::分布式事务
echo=***打开msdtc***
net start msdtc
::备份还原数据库用的
echo=***打开SQLWriter***
net start SQLWriter
::MSSQLServerADHelper100是帮助服务，通常情况下不需要手动管理
echo=***需要时候自己添加命令net start MSSQLServerADHelper100***
)
if "%id%"=="2" (
::MSSQLServerADHelper100是帮助服务，通常情况下不需要手动管理
echo=***关闭MSSQLServerADHelper100***
net stop MSSQLServerADHelper100
echo=***关闭mssqlfdlauncher***
net stop mssqlfdlauncher
echo=***关闭msdtc***
net stop msdtc
echo=***关闭SQLWriter***
net stop SQLWriter
echo=***关闭sqlserveragent***
net stop sqlserveragent
echo=***关闭mssqlserver***
net stop mssqlserver /y
)
if "%id%"=="9" exit
pause
Goto HeadStart
相关的6个服务
-
服务名：mssqlserver
显示名：SQL Server(MSSQLSERVER)服务，SQLServer服务实例，主要服务，只有开启了这个你才能使用Microsoft SQLServer Management Studio连接该数据库实例，开启后会级联开启mssqlfdlauncher服务。
-
服务名：sqlserveragent
显示名：SQL Server 代理 (MSSQLSERVER)
说明：执行作业、监视 SQL Server、激发警报，以及允许自动执行某些管理任务。
-
服务名：mssqlfdlauncher
显示名：SQL Full-text Filter Daemon Launcher (MSSQLSERVER)
说明：用于启动全文筛选器后台程序进程的服务，该进程将为 SQL Server 全文搜索执行文档筛选和断字。禁用此服务将使 SQL Server 的全文搜索功能不可用。
-
服务名：msdtc
显示名：Distributed Transaction Coordinator
说明：协调跨多个数据库、消息队列、文件系统等资源管理器的事务。如果停止此服务，这些事务将会失败。如果禁用此服务，显式依赖此服务的其他服务将无法启动。当一个事务中涉及多个数据源（比如两台sqlserver）服务器，需要MSDTC的协调处理，一般单机可关闭该服务。
-
服务名：SQLWriter
显示名：SQL Server VSS Writer
说明：sqlwriter是Microsoft SQL Server的编写器服务，允许备份和还原应用程序，以便在Volume Shadow Copy Service（VSS）框架中进行操作，服务器上的所有SQL实例只有一个SQL编写器服务。
-
服务名：MSSQLServerADHelper100
显示名：SQL Active Directory Helper 服务
-
服务名：SQLBrowser
显示名：SQL Server Browser
说明：如果一个物理服务器上面有多个SQL Server实例，那么为了确保客户端能访问到正确的实例，所以自SQL Server 2005提供了一个新的Browser服务。如果一台计算机上只有一个实例，且配置为静态端口，则无需启动Browser服务；反之则需要启动。
有关MSSQLServerADHelper启动问题
I want to inform that MSSQLServerADHelper service is dynamically started by an instance of SQL Server or Analysis Manager when needed, and is stopped as soon as it has completed its work, we don’t need to start it manually. Additionally, let’s change the service startup account as localsystem account and check whether the error occurs again.
