18.Hive数据查询
一、基本查询
创建部门表：
hive (default)> create table if not exists dept(
deptno int,
dname string,
loc int
)
row format delimited fields terminated by '\t';
创建员工表：
hive (default)> create table if not exists emp(
empno int,
ename string,
job string,
mgr int,
hiredate string,
sal double,
comm double,
deptno int)
row format delimited fields terminated by '\t';
初始化数据：
hive (default)> load data local inpath '/root/datas/dept.txt' into table
dept;
hive (default)> load data local inpath '/root/datas/emp.txt' into table emp;
全表查询： hive (default)> select * from emp;
选择特定列查询： hive (default)> select empno, ename from emp;
列别名：hive (default)> select ename AS name, deptno dn from emp;
常用函数: count()、max()、min()、sum()、avg()
Limit语句：hive (default)> select * from emp limit 5;
Where语句: hive (default)> select * from emp where sal >1000;
注意：where子句中不能使用字段别名。
like和rlike：使用LIKE运算选择类似的值，%代表零个或多个字符(任意个字符)，_ 代表一个字符。RLIKE子句是Hive中这个功能的一个扩展，其可以通过Java的正则表达式这个更强大的语言来指定匹配条件。
hive (default)> select * from emp where sal LIKE '2%';
Group By语句：GROUP BY语句通常会和聚合函数一起使用，按照一个或者多个列队结果进行分组，然后对每个组执行聚合操作。
hive (default)> select t.deptno, avg(t.sal) avg_sal from emp t group by t.deptno;
Having语句： 对分组内做条件约束
hive (default)>select deptno, avg(sal) avg_sal from emp group by deptno having avg_sal > 2000;
注意：连接谓词中不支持or。
二、Join语句
Hive支持通常的SQL JOIN语句，但是只支持等值连接，不支持非等值连接。
内连接
只有进行连接的两个表中都存在与连接条件相匹配的数据才会被保留下来。
hive (default)> select e.empno, e.ename, d.deptno from emp e join dept d on e.deptno = d.deptno;
左外连接
JOIN操作符左边表中符合WHERE子句的所有记录将会被返回。
hive (default)> select e.empno, e.ename, d.deptno from emp e left join dept d on e.deptno = d.deptno;
右外连接
右外连接：JOIN操作符右边表中符合WHERE子句的所有记录将会被返回。
hive (default)> select e.empno, e.ename, d.deptno from emp e right join dept d on e.deptno = d.deptno;
满外连接
满外连接：将会返回所有表中符合WHERE语句条件的所有记录。如果任一表的指定字段没有符合条件的值的话，那么就使用NULL值替代。
hive (default)> select e.empno, e.ename, d.deptno from emp e full join dept d on e.deptno = d.deptno;
多表连接
注意：连接n个表，至少需要n-1个连接条件。例如：连接三个表，至少需要两个连接条件。
hive (default)>SELECT e.ename, d.dname, l.loc_name
FROM emp e
JOIN dept d
ON d.deptno = e.deptno
JOIN location l
ON d.loc = l.loc;
大多数情况下，Hive会对每对JOIN连接对象启动一个MapReduce任务。本例中会首先启动一个MapReduce job对表e和表d进行连接操作，然后会再启动一个MapReduce job将第一个MapReduce job的输出和表l进行连接操作，Hive总是按照从左到右的顺序执行的。
当对3个或者更多表进行join连接时，如果每个on子句都使用相同的连接键的话，那么只会产生一个MapReduce job。
三、排序
3.1 全局排序（Order By）
Order By：全局排序，只有一个Reducer；ASC: 升序（默认）DESC: 降序
hive (default)> select * from emp order by sal desc;
3.2 多个列排序
hive (default)> select ename, deptno, sal from emp order by deptno, sal ;
3.3 内部排序（Sort By）
对于大规模的数据集order by的效率非常低。在很多情况下，并不需要全局排序，此时可以使用sort by。
Sort by为每个Reducer产生一个排序文件。每个Reducer内部进行排序，对全局结果集来说不是排序。
hive (default)> set mapreduce.job.reduces=3;
hive (default)> select * from emp sort by deptno desc;
3.4 分区排序（Distribute By）
在有些情况下，我们需要控制某个特定行应该到哪个Reducer，通常是为了进行后续的聚集操作。Distribute by子句可以做这件事。Distribute by类似MR中Partition（自定义分区）进行分区，结合Sort by使用。
hive (default)> set mapreduce.job.reduces=3;
hive (default)> select * from emp distribute by deptno sort by empno desc;
注意：
1．Distribute by的分区规则是根据分区字段的Hash码与Reduce的个数进行模除后，余数相同的分到一个区。
2．Hive要求Distribute by语句要写在Sort by语句之前。
3.5 Cluster By
当Distribute by和Sorts by字段相同时，可以使用Cluster by方式。Cluster by除了具有Distribute by的功能外还兼具Sort by的功能。但是排序只能是升序排序，不能指定排序规则为ASC或者DESC。
hive (default)> select * from emp cluster by deptno;
四、分桶及抽样查询
4.1 分桶表数据存储
分区提供一个隔离数据和优化查询的便利方式。不过，并非所有的数据集都可形成合理的分区。对于一张表或者分区，Hive可以进一步组织成桶，也就是更为细粒度的数据范围划分。分桶是将数据集分解成更容易管理的若干部分的另一个技术。
分区针对的是数据的存储路径；分桶针对的是数据文件。
设置分桶属性：hive (default)> set hive.enforce.bucketing=true;
创建分桶表时，数据只能通过子查询的方式导入
创建普通表stu：
hive (default)> create table stu(id int, name string)
row format delimited fields terminated by '\t';
创建分桶表stu_buck：
hive (default)> create table stu_buck(id int, name string)
clustered by(id)
into 4 buckets
row format delimited fields terminated by '\t';
向普通表stu导入数据：load data local inpath '/root/datas/student.txt' into table stu;
通过子查询的方式导入数据到分桶表：insert into table stu_buck select id, name from stu;
Hive的分桶采用对分桶字段的值进行哈希，然后除以桶的个数求余的方式决定该条记录存放在哪个桶当中。
4.2 分桶抽样查询
对于非常大的数据集，有时用户需要使用的是一个具有代表性的查询结果而不是全部结果。Hive可以通过对表进行抽样来满足这个需求。
查询表stu_buck中的数据：hive (default)> select * from stu_buck tablesample(bucket 1 out of 4 on id);
注：tablesample是抽样语句，语法：TABLESAMPLE(BUCKET x OUT OF y) 。
y必须是table总bucket数的倍数或者因子。Hive根据y的大小，决定抽样的比例。例如，table总共分了4份，当y=2时，抽取(4/2=)2个bucket的数据，当y=8时，抽取(4/8=)1/2个bucket的数据。
x表示从哪个bucket开始抽取，如果需要取多个分区，以后的分区号为当前分区号加上y。例如，table总bucket数为4，tablesample(bucket 1 out of 2)，表示总共抽取（4/2=）2个bucket的数据，抽取第1(x)个和第3(x+y)个bucket的数据。
注意：x的值必须小于等于y的值。
五、常用查询函数
5.1 空字段赋值
NVL函数：给值为NULL的数据赋值，它的格式是NVL( value，default_value)。它的功能是如果value为NULL，则NVL函数返回default_value的值，否则返回value的值。
hive (default)> select emp,nvl(comm, 0) from emp;
5.2 CASE WHEN
需求：求出不同部门男女各多少人
数据准备：
[hucheng@hadoop100 datas]$ vi emp_sex.txt
悟空 A 男
大海 A 男
宋宋 B 男
凤姐 A 女
婷姐 B 女
婷婷 B 女
创建Hive表并导入数据
hive (default)> create table emp_sex(name string, dept_id string, sex string)
row format delimited fields terminated by "\t";
hive (default)> load data local inpath '/root/datas/emp_sex.txt' into table emp_sex;
按需求查询数据:
hive (default)> select
dept_id,
sum(case sex when '男' then 1 else 0 end) male_count,
sum(case sex when '女' then 1 else 0 end) female_count
from emp_sex
group by dept_id;
5.3 行转列
CONCAT(str1,str2…)：返回输入字符串连接后的结果，支持任意个输入字符串;
CONCAT_WS(separator, str1, str2,...)：它是一个特殊形式的CONCAT()。第一个参数剩余参数间的分隔符。分隔符可以是与剩余参数一样的字符串。如果分隔符是NULL，返回值也将为NULL。这个函数会跳过分隔符参数后的任何NULL和空字符串。分隔符将被加到被连接的字符串之间;
COLLECT_SET(col)：函数只接受基本数据类型，它的主要作用是将某字段的值进行去重汇总，产生Array类型字段。
数据准备：
[root@hadoop100 datas]$ vi constellation.txt
孙悟空 白羊座 A
大海 射手座 A
宋宋 白羊座 B
猪八戒 白羊座 A
凤姐 射手座 A
需求：把星座和血型一样的人归类到一起，结果如下：
射手座,A 大海|凤姐
白羊座,A 孙悟空|猪八戒
白羊座,B 宋宋
创建Hive表并导入数据
hive (default)> create table person_info(name string, constellation string,
blood_type string)
row format delimited fields terminated by "\t";
hive (default)>load data local inpath "/root/datas/constellation.txt" into table person_info;
按需求查询：
hive (default)> select concat_ws("|",collect_set(name)) all_name, base from
(select name,concat(constellation,",",blood_type) base from person_info) t
group by base ;
5.4 列转行
EXPLODE(col)：将Hive一列中复杂的Array或者Map结构拆分成多行。
LATERAL VIEW
用法：LATERAL VIEW udtf(expression) tableAlias AS columnAlias
解释：用于和Split、explode等UDTF一起使用，它能够将一列数据拆成多行数据，在此基础上可以对拆分后的数据进行聚合。
数据准备：
[root@hadoop100 datas]$ vi movie.txt
《疑犯追踪》 悬疑,动作,科幻,剧情
《Lie to me》 悬疑,警匪,动作,心理,剧情
《战狼2》 战争,动作,灾难
需求：将电影分类中的数组数据展开，结果如下：
《疑犯追踪》 悬疑
《疑犯追踪》 动作
《疑犯追踪》 科幻
《疑犯追踪》 剧情
《Lie to me》 悬疑
《Lie to me》 警匪
《Lie to me》 动作
《Lie to me》 心理
《Lie to me》 剧情
《战狼2》 战争
《战狼2》 动作
《战狼2》 灾难
创建Hive表并导入数据：
hive (default)> create table movie_info(movie string, category array<string>)
row format delimited fields terminated by "\t"
collection items terminated by ",";
hive (default)> load data local inpath "/root/datas/movie.txt" into table movie_info;
按需求查询：
hive (default)> select movie,category_name from movie_info
lateral view explode(category) table_tmp as category_name;
5.5 窗口函数（开窗函数）
OVER()：指定分析函数工作的数据窗口大小，这个数据窗口大小可能会随着行的变而变化。
CURRENT ROW：当前行
n PERCEDING：往前n行数据
n FOLLOWING：往后n行数据
UNBOUNDED：起点；UNBOUNDED PRECEDING：表示从前面的起点；UNBOUNDED FOLLOWING：到后面的终点。
LAG(col,n,default_val)：往前第n行数据
LEAD(col,n, default_val)：往后第n行数据
NTILE(n)：把有序分区中的行分发到指定数据的组中，各个组有编号，编号从1开始，对于每一行，NTILE返回此行所属的组的编号。注意：n必须为int类型。
数据准备：
[root@hadoop100 datas]$ vim business.txt
jack,2017-01-01,10
tony,2017-01-02,15
jack,2017-02-03,23
tony,2017-01-04,29
jack,2017-01-05,46
jack,2017-04-06,42
tony,2017-01-07,50
jack,2017-01-08,55
mart,2017-04-08,62
mart,2017-04-09,68
neil,2017-05-10,12
mart,2017-04-11,75
neil,2017-06-12,80
mart,2017-04-13,94
创建Hive表并导入数据：
hive (default)> create table business(name string, orderdate string,cost int)
ROW FORMAT DELIMITED FIELDS TERMINATED BY ',';
hive (default)> load data local inpath "/root/datas/business.txt" into table business;
① 查询在2017年4月份购买过的顾客及总人数
hive (default)> select distinct name,count(*) over()
from business
where substring(orderdate,0,7) = '2017-04';
② 查询顾客的购买明细及月购买总额
hive (default)> select name,orderdate,cost,
sum(cost) over(partition by name,month(orderdate))
from business;
③ 上述的场景, 将每个顾客的cost按照日期进行累加
hive (default)> select *,
sum(cost) over(partition by name order by orderdate
rows between unbounded preceding and current row)
from business;
④ 查询每个顾客上次的购买时间
hive (default)> select *,lag(orderdate,1,"---")
over(partition by name order by orderdate)
from business;
⑤ 查询前20%时间的订单信息
hive (default)> select * from (
select name,orderdate,cost, ntile(5) over(order by orderdate) sorted
from business
) t
where sorted = 1;
5.6 Rank
RANK() ：排序相同时会重复，总数不会变
DENSE_RANK()： 排序相同时会重复，总数会减少
ROW_NUMBER() ：会根据顺序计算
数据准备：
[root@hadoop100 datas]$ vim score.txt
孙悟空 语文 87
孙悟空 数学 95
孙悟空 英语 68
大海 语文 94
大海 数学 56
大海 英语 84
宋宋 语文 64
宋宋 数学 86
宋宋 英语 84
婷婷 语文 65
婷婷 数学 85
婷婷 英语 78
创建Hive表并导入数据：
hive (default)> create table score(name string,subject string, score int)
row format delimited fields terminated by "\t";
hive (default)> load data local inpath '/root/datas/score.txt' into table score;
需求:计算每门学科成绩排名
hive (default)> select name,subject,score,
rank() over(partition by subject order by score desc) rp,
dense_rank() over(partition by subject order by score desc) drp,
row_number() over(partition by subject order by score desc) rmp
from score;
