Delphi – 愤怒的接口

大家好,我是DH,技术交流.

最近我再写程序中需要用到接口,在使用中发现几个问题,这里拿出来说说,希望和大家交流,也希望得到大家的建议.

第一个非常严重的问题就是 查询一个类或者一个接口是否实现了某一个接口.
在delphi里面的方法有个Supports,但这些所有的方法最终都是调用的TObject.GetInterface().

function GetInterface(const IID: TGUID; out Obj): Boolean;

从这个函数的参数,我们就能看出来,接口必须要有IID,也就是GUID.丫的,软件工程里面的接口哪有什么GUID呀.真麻烦,这主要是Delphi早期接口就是为了实现COM的,所以接口都有GUID.现在接口可以没有GUID,但是这接口就不是一个完整的接口了,根本不能查询某个类是否实现了它,这还叫接口么?

来看看第二个 委托吧.

const
  IID_IA: TGUID = '{489D2CC5-D6D6-4683-8EB4-BE7AE8B58586}';
  IID_IB: TGUID = '{7DFBFAC3-98F7-4716-85EE-FBD404C906AC}';

type
  IA = interface
  ['{489D2CC5-D6D6-4683-8EB4-BE7AE8B58586}']
    procedure SayA;
  end;

  IB = Interface
  ['{7DFBFAC3-98F7-4716-85EE-FBD404C906AC}']
    procedure SayB;
  End;

  TA = class(TInterfacedObject, IA)
    procedure SayA;
  end;

  TB = class(TInterfacedObject, IA, IB)
  private
    FA: TA;
  public
    procedure SayB;
    constructor Create();
    destructor Destroy; override;
    property A: TA read FA implements IA;
  end;

委托在上面这个例子中就是用A来帮你实现IA的接口.你自己就在用写代码了.

这2个单独起来都没有问题,可是合起来后,用过几次后supports就查询不出接口了.

下面我们就来看看这个完整的例子吧.

const
  IID_IA: TGUID = '{B506BE0C-07BD-41A4-8931-3DD69ABEAD82}';
  IID_IB: TGUID = '{960A6A2F-D706-48D1-BCEC-D06152B42389}';

type
  IA = interface
  ['{B506BE0C-07BD-41A4-8931-3DD69ABEAD82}']
    procedure SayA;
    function GetO: IA;
    property O: IA  read GetO;
  end;

  IB = interface
  ['{960A6A2F-D706-48D1-BCEC-D06152B42389}']
    procedure SayB;
  end;

  TA = class(TInterfacedObject, IA)
  private
    FO: TObject;
  protected
    function GetO: IA;
  public
    constructor Create(AOwner: TObject);
    procedure SayA;
    property O: IA  read GetO;
  end;

  TB = class(TInterfacedObject, IA, IB)
  private
    FA: TA;
  public
    procedure SayB;
    constructor Create();
    destructor Destroy; override;
    property A: TA read FA Implements IA;
  end;
/////////////////////////////////////////////////////////////////////////////
{ TA }

constructor TA.Create(AOwner: TObject);
begin
  inherited Create;
  FO:= AOwner;
  Supports(FO, IID_IA);//error
end;

function TA.GetO: IA;
begin
  Supports(FO, IID_IA, Result)
end;

procedure TA.SayA;
begin
  ShowMessage('A');
end;

{ TB }

constructor TB.Create;
begin
  FA:= TA.Create(Self);
end;

destructor TB.Destroy;
begin
  FA.Free;
  inherited;
end;

procedure TB.SayB;
begin
  ShowMessage('B');
end;

procedure TForm3.FormCreate(Sender: TObject);
var
  B : TB;
  A : IA;
  C : IB;
begin
  B:= TB.Create;
  try
    //获得IA接口
    Supports(B, IID_IA, A);
    //这里A.O属性是对A的FO进行查询IA接口 ,然后再查询IB接口
    //理论上说 A的FO也就是TB对象,是实现了IA 和 IB接口的.
    //但是实际这里这里C = nil
    Supports(A.O, IID_IB, C);
    C.SayB;//error
  finally
    B.free;
  end;
end;

上面的代码中我写出来有两处错误的地方.错误的原因主要是委托.TB是委托FA来实现IA的.
第一处错误:你在TB.Create->FA.Create中调用Supports(FO,IID_IA).因为FO的IA是委托FA来实现的,所以编译器就会调用FA.GetInterface(IID_IA);
但是我们现在得发现了,这个过程都还在FA.Create中,也就是FA根本就没有创建好,所以这里会出现一个

第二次错误:Supports(A.O, IID_IB, C);A.O是对A.FO查询了IA接口,FO的IA接口是委托给FA的,所以A.O实际上就是FA.IA偏移.那么对它进行查询IB接口,肯定查询不到.
FA.IA.Self = FA.GetInterface(IID_IB, C);我们知道TA是没有实现IB接口的.所以这里C = nil.

---

如何解决这个问题?
第一个:最简单的就是A.O这里用类而不是用被委托的接口类型.
第二个:就是像TComponent那样

IInterfaceComponentReference = interface
    ['{E28B1858-EC86-4559-8FCD-6B4F824151ED}']
    function GetComponent: TComponent;
  end;

所有接口都继承这个接口,并返回Self.哈哈 实现这个接口的地方就千万不能再委托了.

---

上面都是我的一些小小愚见,欢迎大家拍砖