雷达方向信号产生

声明：本部分代码非原创，作者系电子科技大学电科院李浩老师，仅加少许注释。如有不妥，请告之。

要求是给出雷达天线的船首信号bz脉冲此时表示天线方向角对准船首位置，我们需要此时产生的方位角为0，一个bp信号，用以计算此时的方位角。由于天线的方向性问题可以产生的bp信号不能满足要求，需要在其中均匀的插入脉冲信号。其中azimuth_pulse为处理后的脉冲信号，azimuth为此脉冲的方向角。

首先每个bp信号到来时计数与上个bp信号之间的时间长度，如果要插入8个脉冲则除以8，每当时间到时产生一个脉冲信号 。同时方位角加1.

先把代码贴这里 再分析

`timescale 1ns / 1ps

//used to generator the azimuth by the BP and BZ signals;
module azimuth(
    input sys_clk, // 100M clock
    input sys_rst_n,
    input sys_en,
    input bp,
    input bz,
    output reg [11:0] azimuth,
    output reg azimuth_pulse
    );

    //define the state
    parameter IDLE = 2'b00;
    parameter BPST = 2'b01;// first bp
    parameter PROCESS = 2'b11;
    parameter BPNX = 2'b10; // next bp

    // define the scan line number  2048
    parameter SCAN_NUM = 12'h800;

    //the time counter for the scan interval
    //used for generating next bp signal
    reg [19:0] scan_intv_cnt;

    // the current time coounter for the scan interval
    // the pulse interval out of  last bp signal
    reg [19:0] curr_intv_cnt;

    //the time counter for the neighbor bp signals
    reg [21:0] bp_intv_cnt;

    // the azimuth counter for the neighbor bp signals
    // count the azimuth pulse between bp signals
    reg [4:0] bp_azimuth_cnt;

    // the azimuth generated only by the bp signals
    // count the sum of azimuth pulse ,the low 3 bits used for betwwen bp
    reg [11:0] temp_azimuth;

    // the azimuth value when the bz signal arrival

    reg [11:0] bz_azimuth;

    // the FSM state and next state
    reg [1:0] curr_st;
    reg [1:0] next_st;

    // define the signals for abstract the edge of bp, bz
    reg bp_ff1, bp_re;
    reg bz_ff1, bz_re;

    always @ (posedge sys_clk or negedge sys_rst_n)
        if (sys_rst_n == 1'b0) begin
            bp_ff1 <= 1'b0;
            bp_re <= 1'b0;
            bz_ff1 <= 1'b0;
            bz_re <= 1'b0;
        end
        else begin
            bp_ff1 <= bp;
            bp_re <= bp && ~bp_ff1;
            bz_ff1 <= bz;
            bz_re <= ~bz && bz_ff1;
        end
    // the FSM define
    // define the current state
    always @ (posedge sys_clk or negedge sys_rst_n)
        if (sys_rst_n == 1'b0) curr_st <= IDLE;
        else curr_st <= next_st;

    //define the state skip
    always @ * begin
        // while the system is reseted, the state is IDLE
        if (sys_rst_n == 1'b0) next_st = IDLE;
        // while the system is disable, the state is IDLE
        else if (sys_en == 1'b0) next_st = IDLE;
        else case (curr_st)
            // if the first bp arrival, state skip to BPST
            IDLE :
                if (bp_re) next_st = BPST;
                else next_st = IDLE;
            // if the bp signal arrival, state skip to the PROCESS
            BPST :
                if (bp_re) next_st = PROCESS;
                else next_st = BPST;
            // the state skip to the BPNX in the next clock
            PROCESS :
                next_st = BPNX;
            // the state skip to the PROCESS while the bp signal arrival
            BPNX :
                if (bp_re) next_st = PROCESS;
                else next_st = BPNX;
        endcase
    end

    // assign the signals in the FSM
    always @ (posedge sys_clk or negedge sys_rst_n)
        if (sys_rst_n == 1'b0) begin
            scan_intv_cnt <= 0;
            curr_intv_cnt <= 0;
            bp_intv_cnt <= 0;
            bp_azimuth_cnt <= 0;
            temp_azimuth <= 0;
            azimuth_pulse <= 0;
        end
        else case (next_st)
            // all sigals in the IDLE state is same as the reset initial
            IDLE : begin
                scan_intv_cnt <= 0;
                curr_intv_cnt <= 0;
                bp_intv_cnt <= 0;
                bp_azimuth_cnt <= 0;
                temp_azimuth <= 0;
                azimuth_pulse <= 0;
            end

            BPST : begin
                // bp_intv_cnt is always increase in this state
                //calcaulate the inteval between the bp signal
                bp_intv_cnt <= bp_intv_cnt + 1'b1;
            end // end the BPST state

            PROCESS : begin
                 // bp signal rise edge arrive
                 //
                 // inteval between azimult pulse = inteval between bp sinals / pulse number between bp
                // assign the curr_intv_cnt divided the bp_intv_cnt by 8
                curr_intv_cnt <= bp_intv_cnt[21:3];

                // clear the bp_intv_cnt
                bp_intv_cnt <= 22'h0;

                // clear the bp_azimuth_cnt
                bp_azimuth_cnt <= 5'h0;

                // assign the temp_azimuth
                // if the bp_azimuth_cnt is less than 8,
                //     temp_azimuth is added 8 compared to the last bp
                // if the bp_azimuth_cnt is larger than 8, but less than 12,
                //     temp_azimuth is added 8 compared to the last bp
                temp_azimuth[2:0] <= 3'h0;// the low 3bits used for pulse number between bp signals

                //bp arrive  azimuth pulse counter out of range, reset ,
                //or , bp_azimuth <=8, because bp_zaimuth= bp interval / pulse interval ,
                // if <8 generate a pulse ,=8 just don't care
                if (temp_azimuth >= SCAN_NUM - 1'b1) temp_azimuth[11:3] <= 9'h0;
                else if (bp_azimuth_cnt < 5'h8) temp_azimuth[11:3] <= temp_azimuth[11:3] + 1'b1;

                // assign the azimuth_pulse
                // if the bp_azimuth_cnt == 8, azimuth_pulse is low
                if (bp_azimuth_cnt == 5'h8) azimuth_pulse <= 1'b0;
                else azimuth_pulse <= 1'b1;
            end // end the PROCESS state

            // BPNX state is similar to the BPST
            // The differet is the scan_intv_cnt clear case
            BPNX : begin
                if (scan_intv_cnt >= curr_intv_cnt)
                    scan_intv_cnt <= 19'h0;
                else scan_intv_cnt <= scan_intv_cnt + 1'b1;
                // azimuth pulse inteval

                //bp inteval , used for next curr_intv_cnt,
                bp_intv_cnt <= bp_intv_cnt + 1'b1;

                if (scan_intv_cnt >= curr_intv_cnt)
                    bp_azimuth_cnt <= bp_azimuth_cnt + 1'b1; // time is up to generate a  azimuth_pulse

                if (scan_intv_cnt >= curr_intv_cnt && temp_azimuth >= SCAN_NUM - 1'b1)
                    temp_azimuth <= 12'h0;  //azimuth_pulse   out of range and  time is up to generate a  azimuth_pulse
                else if (scan_intv_cnt >= curr_intv_cnt)     // or ,just add 1 to temp_azimuth
                    temp_azimuth <= temp_azimuth + 1'b1;

                if (scan_intv_cnt >= curr_intv_cnt) azimuth_pulse <= 1'b1;  //generate a pulse
                else azimuth_pulse <= 1'b0;
            end
        endcase

    // recorder the bz_azimuth
    always @ (posedge sys_clk or negedge sys_rst_n)
        if (sys_rst_n == 1'b0) bz_azimuth <= 12'h0;
        else if (bz_re) bz_azimuth <= temp_azimuth;

    // assign output of azimuth
    // azimuth is the value that temp_azimuth minus the bz_azimuth
    // while temp_azimuth is less than bz_azimuth, then add 12'hE10
    always @ (posedge sys_clk or negedge sys_rst_n)
        if (sys_rst_n == 1'b0) azimuth <= 12'h0;
        else if (temp_azimuth < bz_azimuth)
            azimuth <= 12'h800 + temp_azimuth - bz_azimuth;
        else azimuth <= temp_azimuth - bz_azimuth;
endmodule

 

 
Creativity is the sudden cessation of stupidity.
--Dr. E. Land