解析三层架构(2)----分层究竟分出了那些东西

在上篇文章写到我们为什么要分层.有很多读者提出来很多宝贵的意见.让我受益匪浅,深深的感觉到自己的水平"还有很大的提升空间".首先感谢这些朋友们,我会进一步总结完善自己的想法.

截取了部分朋友的留言,感谢他们:

这次我用对比的方式描述一下,分层到底分出了什么.俗话说:有分必有合,那么它是把什么合到了一起.

首先写出两个没有分层的demo:

<1>查询信息demo

Public Class Form2
    Private sqlCon As String = "Data Source=LSH;Initial Catalog=ComputerLab;User ID=sa;Password=123456"
    '查询数据库信息信息
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click

        Dim conStr As New SqlConnection '数据库连接对象
        Dim sqlCom As SqlCommand        '数据库执行对象
        Dim Res As DialogResult         '消息提示框返回类型
        Dim dr As SqlDataReader         'dataReader对象
        Dim dt As New DataTable         'Datatable对象

        Dim sql As String = "select * from TableName where Name=@name"                   'sql插入语句
        conStr.ConnectionString = sqlCon                                '给数据库连接对象赋值
        sqlCom = New SqlCommand(sql, conStr)                            '给数据库执行对象赋值
        sqlCom.Parameters.Add("@name", SqlDbType.VarChar, TextBox1.Text)    '给sql语句参数赋值

        Res = MessageBox.Show("是否添加", "提示", MessageBoxButtons.OKCancel)
        '判断是否查询
        If Res = DialogResult.Yes Then
            Try
                conStr.Open()
                dr = sqlCom.ExecuteReader    '执行查询语句
                dt.Load(dr)
            Catch ex As Exception
                Throw ex
            Finally
                If Not IsNothing(conStr) Then   '如果数据库打开,则关闭数据库
                    conStr.Close()
                End If
            End Try
        End If

        MsgBox(dt.Rows.Count)   '显示查询到的行数
    End Sub

<2>添加信息demo

Public Class Form1
    Private sqlCon As String = "Data Source=LSH;Initial Catalog=ComputerLab;User ID=sa;Password=123456"
    '向数据库添加信息
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Dim bln As Boolean = False      '存储返回值
        Dim conStr As New SqlConnection '数据库连接对象
        Dim sqlCom As SqlCommand        '数据库执行对象
        Dim Res As DialogResult         '消息提示框返回类型

        Dim sql As String = "insert into TableName(Name) value(@Name)"  'sql插入语句
        conStr.ConnectionString = sqlCon                                '给数据库连接对象赋值
        sqlCom = New SqlCommand(sql, conStr)                            '给数据库执行对象赋值
        sqlCom.Parameters.Add("@Name", SqlDbType.VarChar, TextBox1.Text) '给sql语句参数赋值

        Res = MessageBox.Show("是否添加", "提示", MessageBoxButtons.OKCancel)
        '判断是否同意插入
        If Res = DialogResult.Yes Then
            Try
                conStr.Open()
                bln = sqlCom.ExecuteNonQuery    '执行插入语句
            Catch ex As Exception
                bln = False
            Finally
                If Not IsNothing(conStr) Then   '如果数据库打开,则关闭数据库
                    conStr.Close()
                End If
            End Try
        End If

        MsgBox(bln) '提示返回信息
    End Sub
End Class

上面的两个没有分层的代码,当然在功能的实现上是完全没有问题.但是这样设计带来了很多的危机:

(1):写这个模块的人必须是一个能力非常强的人,因为他需要操作数据库,理解业务逻辑

(2):如果有另为一个模块需要这两个操作数据库的方法,只能重写或者调用该窗体下的方法.

(3):如果业务逻辑稍有变动,就需要拆开这个模块,重新编写,对于重新设计的人来说这个模块的所有设计都是可见的,很是不安全.

(4):如果要更换或者改动数据库,结果就是每一个模块都要重新编写

(5):如果有另为一个和这个相似的工程,想要复用以前的东西,难度很大

对于一个公司来说,当然不希望发生这样的事情.所以,合理的分层,降低系统的耦合性是必要的.

第一步:把数据库操作提取出来.

对每一个表,把完全对他的操作单独写成类也就是我们的DAO,数据访问类

每一个表对应一个DAO,每个DAO里面包含该数据库的所有增,删,查,改操作.这样做的好处就是对数据库的操作完全独立,达到功能单一.降低了和其他模块的耦合,写代码的时候,程序员不需要了解业务逻辑.

而且,在维护上和扩展上,如果对数据库改动,就会有针对性的去修改DAO.

当然,在设计的时候,我们尽量去封装不变的操作,这样不但能减少代码量,而且能达到很好的复用效果.在数据库操作中,对于数据库的打开,执行,关闭基本上都是一样的.所以我们单独提取出来sqlHelper(数据库助手类)

 

Imports System.Data.SqlClient
Imports System.Configuration

''' <summary>
''' 运行数据库
''' </summary>
Public Class SqlHelp
    Private cmd As SqlCommand   'sqlcommand对象
    Private con As SqlConnection    'sqlconnection对象
    Private dr As SqlDataReader     'sqlDataReader对象
    ''' <summary>
    ''' 获取连接字符串
    ''' </summary>
    ''' <returns>连接字符串</returns>
    ''' <remarks></remarks>
    Public Function GetCon() As SqlConnection
        Dim conStr As String
        conStr = System.Configuration.ConfigurationManager.AppSettings("ConnStr")

        con = New SqlConnection
        con.ConnectionString = conStr

        '打开数据库
        If (con.State = ConnectionState.Closed) Then
            con.Open()
        End If

        Return con

    End Function

    ''' <summary>
    ''' 增 删 改方法
    ''' </summary>
    ''' <param name="sqlStr">数据库语句 活存储过程名</param>
    ''' <param name="Param">参数数组</param>
    ''' <param name="commandType">数据库字符串 或者存储过程名 类型</param>
    Public Function ExecuteNonQuery(ByVal sqlStr As String, ByVal Param() As SqlParameter, ByVal commandType As CommandType) As Boolean

        cmd = New SqlCommand(sqlStr, Me.GetCon)
        cmd.CommandType = commandType

        '添加参数
        If Param IsNot Nothing Then
            cmd.Parameters.AddRange(Param)
        End If

        '执行语句
        Try
            Return CBool(cmd.ExecuteNonQuery)
        Catch ex As Exception
            Return False
        Finally
            If Not IsNothing(con) Then
                con.Close()
            End If
        End Try

    End Function

    ''' <summary>
    ''' 查询
    ''' </summary>
    ''' <param name="sqlStr">sql语句 或者存储过程名</param>
    ''' <param name="Param">参数数组</param>
    ''' <param name="commandType">执行类型</param>
    Public Function ExecuteQuery(ByVal sqlStr As String, ByVal Param() As SqlParameter, ByVal commandType As CommandType) As DataTable
        Dim dt As New DataTable
        cmd = New SqlCommand(sqlStr, Me.GetCon)
        cmd.CommandType = commandType

        '添加参数
        If Param IsNot Nothing Then
            cmd.Parameters.AddRange(Param)
        End If

        '执行语句
        Try
            dr = cmd.ExecuteReader
            dt.Load(dr)
        Catch ex As Exception
            Return Nothing
        Finally
            If Not IsNothing(con) Then
                con.Close()
            End If
        End Try
        Return dt
    End Function

提取后数据库访问层代码如下: 

Imports SqlHelper
Imports System.Data.SqlClient
Public Class DAL
    Private sqlHelper As New SqlHelp
    ''' <summary>
    ''' 查询记录
    ''' </summary>
    ''' <param name="strSelect">关键字</param>
    ''' <returns>记录集</returns>
    ''' <remarks></remarks>
    Public Function SelectInfo(ByVal strSelect As String) As DataTable
        'sql查询语句
        Dim sql As String = "select * from TableName where Name=@name"
        '向sql参数中添加实参
        Dim Para() As SqlParameter = {New SqlParameter("@name", strSelect)}
        '调用sqlhelper执行数据库操作
        Return sqlHelper.ExecuteQuery(sql, Para, Data.CommandType.Text)
    End Function
    ''' <summary>
    ''' 添加记录
    ''' </summary>
    ''' <param name="strAdd">记录信息</param>
    ''' <returns>是否成功</returns>
    ''' <remarks></remarks>
    Public Function AddInfo(ByVal strAdd As String) As Boolean
        'sql插入语句
        Dim sql As String = "insert into TableName(Name) value(@Name)"
        '向sql参数中添加实参
        Dim Para() As SqlParameter = {New SqlParameter("@name", strAdd)}
        '调用sqlhelper执行数据库操作
        Return sqlHelper.ExecuteNonQuery(sql, Para, Data.CommandType.Text)
    End Function
End Class

第二:根据业务逻辑,个人习惯和用例相对应,把相关的逻辑判断,比如添加记录在什么情况下判断,添加前要判断记录是否存在等放到BLL层.

但是对于数据的有效性校验一般还是放在UI层,也可以有其他更好的方法,这些我在以后会总结出来.

代码如下:

Public Class BLL
    Private dal As New DAL
    ''' <summary>
    ''' 业务逻辑层,添加方法
    ''' </summary>
    ''' <param name="strAdd">添加信息</param>
    ''' <remarks></remarks>
    Public Sub Add(ByVal strAdd As String)
        '定义用于存储查询结果的记录集
        Dim dt As New DataTable
        '执行查询,判断添加的信息是否已经存在
        dt = dal.SelectInfo(strAdd)
        If dt.Rows.Count > 0 Then
            Throw New Exception("记录已存在")
        Else
            '添加记录,返回是否成功
            If dal.AddInfo(strAdd) = True Then
                Throw New Exception("添加成功")
            Else
                Throw New Exception("添加失败")
            End If
        End If

    End Sub

End Class

第三:剩下的UI层里,除了判断数据有效性以为,只要调用bll的添加方法就可以了.这样制作UI的人就会减轻了很大的压力,让他们专心做美工或者其他.

代码如下:

Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
        Dim bll As New BLL
        '调用bll层添加方法
        Try
            bll.Add(TextBox1.Text)
        Catch ex As Exception
            '显示添加结果给用户
            MessageBox.Show(ex.Message)
        End Try
    End Sub

当然三层方式还有其他一些技巧,比如为DAL加一层接口,用抽象工厂加反射的方法实现数据库的灵活操作,替换.这里先不叙述.

上述都是个人的一点总结,欢迎大家指导

 

接下文:解析三层架构(3)--实体类与面向对象