CDS标准视图：维护通知数据 I_PMNotifMaintenanceData

• 视图名称：维护通知数据 I_PMNotifMaintenanceData
• 视图类型：基础视图
• 视图代码：

点击查看代码

@EndUserText.label: 'Notification Maintenance Data'
--@Analytics: { dataCategory: #DIMENSION }
@VDM.viewType: #BASIC
@AbapCatalog: { sqlViewName: 'IPMNTFMAINTDATA', compiler.compareFilter } // N3273656 - remove 'preserveKey'
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations:['_LocationAccountAssignment']

@ObjectModel.representativeKey: 'MaintenanceNotification'
@ObjectModel.semanticKey:  [ 'MaintenanceNotification' ]

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
@ObjectModel.modelingPattern: #NONE
@Metadata.ignorePropagatedAnnotations:true

define view I_PMNotifMaintenanceData
  as select from qmih
  association [0..1] to I_LocationAccountAssignment as _LocationAccountAssignment     on  _LocationAccountAssignment.MaintObjectLocAcctAssgmtNmbr = $projection.MaintObjectLocAcctAssgmtNmbr
  association [0..1] to I_MalfunctionEffect         as _MalfunctionEffect             on  _MalfunctionEffect.MalfunctionEffect = $projection.MalfunctionEffect
  association [0..1] to I_Indicator                 as _MaintenanceObjectIsDown       on  $projection.MaintenanceObjectIsDown = _MaintenanceObjectIsDown.IndicatorValue
  association [0..1] to I_UnitOfMeasure             as _UnitOfMeasure                 on  $projection.MaintObjDowntimeDurationUnit = _UnitOfMeasure.UnitOfMeasure
  association [0..1] to I_Equipment                 as _Equipment                     on  $projection.Equipment = _Equipment.Equipment
  association [0..1] to I_Equipment                 as _RelevantEquipment             on  $projection.RelevantEquipment = _RelevantEquipment.Equipment
  association [0..1] to I_FunctionalLocation        as _RelevantFunctionalLocation    on  $projection.RelevantFunctionalLocation = _RelevantFunctionalLocation.FunctionalLocation
  //Obsolete-C1 released association not intended to used and replaced with I_MaintenancePlanPlant
  association [0..1] to I_Plant                     as _MaintenancePlanningPlant      on  $projection.MaintenancePlanningPlant = _MaintenancePlanningPlant.Plant
  /////////////////////////////////////////////////////////////////////////////////
  association [0..1] to I_MaintenancePlanPlant      as _MaintenancePlanPlant          on  $projection.MaintenancePlanningPlant = _MaintenancePlanPlant.MaintenancePlanningPlant
  association [0..1] to I_User                      as _InspectedByUser               on  $projection.InspectedByUser = _InspectedByUser.UserID
  association [0..1] to I_MaintenancePlannerGroup   as _MaintenancePlannerGroup       on  $projection.MaintenancePlannerGroup  = _MaintenancePlannerGroup.MaintenancePlannerGroup
                                                                                      and $projection.MaintenancePlanningPlant = _MaintenancePlannerGroup.MaintenancePlanningPlant
  association [0..1] to I_Material                  as _Assembly                      on  $projection.Assembly = _Assembly.Material
  association [1..1] to I_MaintenanceNotification   as _MaintenanceNotification       on  $projection.MaintenanceNotification = _MaintenanceNotification.MaintenanceNotification
  association [0..1] to I_MaintenancePlan           as _MaintenancePlan               on  $projection.MaintenancePlan = _MaintenancePlan.MaintenancePlan
  association [0..1] to I_MaintenanceItem           as _MaintenanceItem               on  $projection.MaintenanceItem = _MaintenanceItem.MaintenanceItem
  // association [0..1] to I_MaintenanceItem           as _MaintenanceItem           on  $projection.MaintenancePlan = _MaintenanceItem.MaintenancePlan
  association [0..1] to I_MaintenanceActivityType   as _MaintenanceActivityType       on  $projection.MaintenanceActivityType = _MaintenanceActivityType.MaintenanceActivityType
  association [0..1] to I_MaintenanceRevision       as _MaintenanceRevision           on  $projection.MaintenancePlanningPlant = _MaintenanceRevision.MaintenancePlanningPlant
                                                                                      and $projection.MaintenanceRevision      = _MaintenanceRevision.MaintenanceRevision
  association [0..1] to I_EAMProcessSubPhase        as _SubPhase                      on  $projection.MaintNotifProcessSubPhaseCode = _SubPhase.EAMProcessSubPhaseCode
  association [0..1] to I_EAMProcessPhase           as _Phase                         on  $projection.MaintNotifProcessPhaseCode = _Phase.EAMProcessPhaseCode
  -- Extensions, do not expose as association:
  association [0..1] to E_PMNotifMaintenanceData    as _NotifMaintenanceDataExtension on  _NotifMaintenanceDataExtension.MaintenanceNotification = $projection.MaintenanceNotification


{
  key qmih.qmnum                                            as MaintenanceNotification,

      // Associations
      @ObjectModel.foreignKey.association: '_LocationAccountAssignment'
      qmih.iloan                                            as MaintObjectLocAcctAssgmtNmbr,
      //--[ GENERATED:012:GFBfhxvv7kY4nKFWHa7fa0
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MalfunctionEffectStdVH',
                     element: 'MalfunctionEffect' }
        }]
      // ]--GENERATED
      @ObjectModel.foreignKey.association: '_MalfunctionEffect'
      qmih.auswk                                            as MalfunctionEffect,

      // Notification Reference Objects
      //--[ GENERATED:012:GFBfhxvv7kY4nKFWHa7fa0
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_EquipmentStdVH',
                     element: 'Equipment' }
        }]
      // ]--GENERATED
      @ObjectModel.foreignKey.association: '_Equipment'
      qmih.equnr                                            as Equipment,
      //--[ GENERATED:012:GFBfhxvv7kY4nKFWHa7fa0
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaterialStdVH',
                     element: 'Material' }
        }]
      // ]--GENERATED
      @ObjectModel.foreignKey.association: '_Assembly'
      qmih.bautl                                            as Assembly,

      @ObjectModel.foreignKey.association: '_MaintenancePlanPlant'
      qmih.iwerk                                            as MaintenancePlanningPlant,
      //--[ GENERATED:012:GFBfhxvv7kY4nKFWHa7fa0
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaintPlnrGrpStdVH',
                     element: 'MaintenancePlannerGroup' },
          additionalBinding: [{ localElement: 'MaintenancePlanningPlant',
                                element: 'MaintenancePlanningPlant' }]
        }]
      // ]--GENERATED
      @ObjectModel.foreignKey.association: '_MaintenancePlannerGroup'
      qmih.ingrp                                            as MaintenancePlannerGroup,
      qmih.loc_desc                                         as LocationDescription,
      @ObjectModel.foreignKey.association: '_MaintenanceObjectIsDown'
      qmih.msaus                                            as MaintenanceObjectIsDown,

      qmih.ausvn                                            as MalfunctionStartDate,
      qmih.ausbs                                            as MalfunctionEndDate,
      qmih.auztv                                            as MalfunctionStartTime,
      qmih.auztb                                            as MalfunctionEndTime,

      qmih.datan                                            as InspectionDate,
      qmih.inspk                                            as InspectedByUser,
      qmih.revnr                                            as MaintenanceRevision,


      @DefaultAggregation: #SUM
      //Semantics.quantity.unitOfMeasure: 'MaintObjDowntimeDurationUnit' - N3273656 - AUSZT is always in [sec]
      qmih.auszt                                            as MaintObjectDowntimeDuration, // [sec]

      @Semantics.unitOfMeasure: true
      qmih.maueh                                            as MaintObjDowntimeDurationUnit,

      qmih.kdauf                                            as SalesDocument,
      qmih.kdpos                                            as SalesDocumentItem,

      //--[ GENERATED:012:GFBfhxvv7kY4nKFWHa7fa0
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaintenancePlanStdVH',
                     element: 'MaintenancePlan' }
        }]
      // ]--GENERATED
      @ObjectModel.foreignKey.association: '_MaintenancePlan'
      qmih.warpl                                            as MaintenancePlan,
      //--[ GENERATED:012:GFBfhxvv7kY4nKFWHa7fa0
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaintenanceItemStdVH',
                     element: 'MaintenanceItem' }
        }]
      // ]--GENERATED
      @ObjectModel.foreignKey.association: '_MaintenanceItem'
      qmih.wapos                                            as MaintenanceItem,
      //--[ GENERATED:012:GFBfhxvv7kY4nKFWHa7fa0
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaintActyTypeStdVH',
                     element: 'MaintenanceActivityType' }
        }]
      // ]--GENERATED
      @ObjectModel.foreignKey.association: '_MaintenanceActivityType'
      cast(qmih.ilart as eam_maint_activity_type)           as MaintenanceActivityType,
      qmih.btpln                                            as RelevantFunctionalLocation,
      qmih.bequi                                            as RelevantEquipment,
      qmih.verfv                                            as AvailyBeforeMalfunctionPercent,
      qmih.verfn                                            as AvailyAfterMalfunctionPercent,
      qmih.verfm                                            as AvailyAfterConclusionPercent,
      qmih.anlzv                                            as SystConditionBeforeMalfunction,
      qmih.anlzn                                            as SystConditionAfterMalfunction,
      qmih.anlze                                            as SystConditionAfterCompletion,

      // IME: 2002 LACD
      cast(qmih.lacd_date as vdm_lacd_date preserving type) as LatestAcceptableCompletionDate,
      // IME: 2002 LACD

      qmih.notificationpersonresponsible                    as NotificationPersonResponsible,
      qmih.maintnotifovrlprocphase                          as MaintNotifProcessPhaseCode,
      qmih.maintnotifovrlprocsubphase                       as MaintNotifProcessSubPhaseCode,
     //Notification API 2011
      qmih.notifrejectionreasoncode                         as MaintNotifRejectionReasonCode,
      qmih.abnum                                            as MaintenancePlanCallNumber,
      qmih.plnty                                            as MaintenanceTaskListType,
      qmih.plnnr                                            as TaskListGroup,
      qmih.plnal                                            as TaskListGroupCounter,
     //Notification API 2011

     // Detection Catalog
     qmih.detectioncatalog                                  as MaintNotifDetectionCatalog,
     qmih.detectioncodegroup                                as MaintNotifDetectionCodeGroup,
     qmih.detectioncode                                     as MaintNotifDetectionCode,
     //Detection Catalog
     //Maintenance Notification Processing Context
     qmih.maintnotifprocessingcontext                       as MaintNotifProcessingContext,

     //Previous Final Due Date
     qmih.old_lacd_date                                     as PreviousFinalDueDate,


      // Propagate association
      _MaintenanceNotification,
      _Equipment,
      _LocationAccountAssignment,
      _MalfunctionEffect,
      _MaintenanceObjectIsDown,
      _UnitOfMeasure,
      _MaintenancePlanningPlant, //Obsolete
      _MaintenancePlanPlant,
      _InspectedByUser,
      _MaintenancePlannerGroup,
      _Assembly,
      _MaintenancePlan,
      _MaintenanceItem,
      _MaintenanceActivityType,
      _MaintenanceRevision,
      _RelevantEquipment,
      _RelevantFunctionalLocation,
      _SubPhase,
      _Phase
}

• 事务代码：

• 视图结构：

字段名称	技术名称
通知	MAINTENANCENOTIFICATION
位置/科目分配	MAINTOBJECTLOCACCTASSGMTNMBR
影响	MALFUNCTIONEFFECT
设备	EQUIPMENT
装配	ASSEMBLY
计划工厂	MAINTENANCEPLANNINGPLANT
计划人员组	MAINTENANCEPLANNERGROUP
当前地点	LOCATIONDESCRIPTION
细分	MAINTENANCEOBJECTISDOWN
故障开始	MALFUNCTIONSTARTDATE
故障结束	MALFUNCTIONENDDATE
故障开始(时间)	MALFUNCTIONSTARTTIME
故障结束	MALFUNCTIONENDTIME
技术检验	INSPECTIONDATE
技术检验	INSPECTEDBYUSER
修订	MAINTENANCEREVISION
停机期间	MAINTOBJECTDOWNTIMEDURATION
单位	MAINTOBJDOWNTIMEDURATIONUNIT
销售凭证	SALESDOCUMENT
项目	SALESDOCUMENTITEM
维护计划	MAINTENANCEPLAN
维护项目	MAINTENANCEITEM
活动类型	MAINTENANCEACTIVITYTYPE
受影响的FLoc	RELEVANTFUNCTIONALLOCATION
受影响的设备	RELEVANTEQUIPMENT
故障前的可用性	AVAILYBEFOREMALFUNCTIONPERCENT
故障后的可用性	AVAILYAFTERMALFUNCTIONPERCENT
任务后的可用性	AVAILYAFTERCONCLUSIONPERCENT
Cond.bef.malfn.	SYSTCONDITIONBEFOREMALFUNCTION
Cond.aft.malfn.	SYSTCONDITIONAFTERMALFUNCTION
任务完成后条件	SYSTCONDITIONAFTERCOMPLETION
最终到期日	LATESTACCEPTABLECOMPLETIONDATE
负责人标识	NOTIFICATIONPERSONRESPONSIBLE
流程阶段	MAINTNOTIFPROCESSPHASECODE
流程子阶段	MAINTNOTIFPROCESSSUBPHASECODE
原因代码	MAINTNOTIFREJECTIONREASONCODE
调用号	MAINTENANCEPLANCALLNUMBER
任务清单类型	MAINTENANCETASKLISTTYPE
组	TASKLISTGROUP
组计数器	TASKLISTGROUPCOUNTER
检测方法参数文件	MAINTNOTIFDETECTIONCATALOG
检测方法组	MAINTNOTIFDETECTIONCODEGROUP
检测方法	MAINTNOTIFDETECTIONCODE
通知处理上下文	MAINTNOTIFPROCESSINGCONTEXT
上一个最终到期日	PREVIOUSFINALDUEDATE