CDS标准视图：测量文档数据 I_MeasurementDocumentData

• 视图名称：测量文档数据 I_MeasurementDocumentData
• 视图类型：基础视图
• 视图代码：

点击查看代码

@AbapCatalog.sqlViewName: 'IMEASDOCDATA'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Measurement Document Data'

@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'MeasurementDocument'
@Metadata.ignorePropagatedAnnotations: true

@Analytics: {
  dataCategory: #FACT,
  dataExtraction: {
    enabled: true
  }
}

@ObjectModel: {
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #L
  }
}

@ObjectModel.modelingPattern:           #EXTRACTION_DATA_SOURCE
@ObjectModel.supportedCapabilities:     [ #EXTRACTION_DATA_SOURCE ]



define view I_MeasurementDocumentData
  as select from I_MeasurementDocument
    inner join   I_MeasuringPointData on I_MeasurementDocument.MeasuringPoint = I_MeasuringPointData.MeasuringPoint
{
  key I_MeasurementDocument.MeasurementDocument,

      @ObjectModel.foreignKey.association: '_MeasuringPoint'
      I_MeasurementDocument.MeasuringPoint,

      @ObjectModel.foreignKey.association: '_Language'
      I_MeasurementDocument.Language,

      I_MeasurementDocument.MeasurementDocumentText,

      I_MeasurementDocument.MsmtRdngDate,

      I_MeasurementDocument.MsmtRdngTime,

      @Semantics.dateTime: true
      I_MeasurementDocument.MeasurementReadingDateTime,

      I_MeasurementDocument.MeasurementDocumentHasLongText,

      I_MeasurementDocument.MsmtRdngByUser,

      @Semantics.systemDate.createdAt: true
      I_MeasurementDocument.CreationDate,

      I_MeasurementDocument.CreationTime,

      @Semantics.dateTime: true
      I_MeasurementDocument.MsmtDocumentCreationDateTime,

      @Semantics.user.createdBy: true
      I_MeasurementDocument.CreatedByUser,

      @Semantics.systemDate.lastChangedAt: true
      I_MeasurementDocument.LastChangeDate,

      @Semantics.user.lastChangedBy: true
      I_MeasurementDocument.LastChangedByUser,

      I_MeasurementDocument.SingleLevelDeletionLogicFlag,

      I_MeasurementDocument.MeasurementDocumentOrigin,

      @ObjectModel.foreignKey.association: '_InspectionLot'
      I_MeasurementDocument.InspectionLot,

      I_MeasurementDocument.InspectionCharacteristic,

      @ObjectModel.foreignKey.association: '_MsmtRdngSourceMeasurementDoc'
      I_MeasurementDocument.MsmtRdngSourceMeasurementDoc,

      I_MeasurementDocument.ProdnRsceToolTypeCode,

      I_MeasurementDocument.ProdnRsceToolInternalID,

      @ObjectModel.foreignKey.association: '_ControllingObject'
      I_MeasurementDocument.MsmtDocumentReferredOrder,

      I_MeasurementDocument.MsmtIsDoneAfterTaskCompltn,

      @Semantics.quantity.unitOfMeasure: 'MeasurementReadingEntryUoM'
      I_MeasurementDocument.MeasurementReading,

      @Semantics.quantity.unitOfMeasure: 'MeasurementReadingEntryUoM'
      I_MeasurementDocument.MeasurementReadingInEntryUoM,

      @ObjectModel.foreignKey.association: '_UnitOfMeasure'
      @Semantics.unitOfMeasure: true
      I_MeasurementDocument.MeasurementReadingEntryUoM,

      I_MeasurementDocument.MsmtDocumentSIUnitOfMeasure,

      @Semantics.quantity.unitOfMeasure: 'MeasurementReadingEntryUoM'
      I_MeasurementDocument.MeasurementCounterReading,

      @Semantics.quantity.unitOfMeasure: 'MeasurementReadingEntryUoM'
      I_MeasurementDocument.MsmtCounterReadingDifference,

      I_MeasurementDocument.MsmtCntrReadingDiffIsEntered,

      I_MeasurementDocument.MsmtCounterReadingIsReplaced,

      @ObjectModel.foreignKey.association: '_MsmtDocumentCatalogType'
      I_MeasurementDocument.MeasurementDocumentCatalogType,

      @ObjectModel.foreignKey.association: '_MeasurementDocumentCodeGroup'
      I_MeasurementDocument.MeasurementDocumentCodeGroup,

      @ObjectModel.foreignKey.association: '_MeasurementValuationCode'
      I_MeasurementDocument.MsmtValuationCode,

      I_MeasurementDocument.MsmtValuationCodeVersNmbr,

      I_MeasurementDocument.MsmtRdngStatus,

      I_MeasurementDocument.MsmtRdngIsReversed,

      I_MeasurementDocument.InspectionValuationResult,

      I_MeasurementDocument.MsmtRdngIsIntervalDoc,

      I_MeasurementDocument.MsmtRdngIntervalStartDate,

      I_MeasurementDocument.MsmtRdngIntervalStartTime,

      I_MeasurementDocument.MaintOrderOperationInternalID,

      cast( case when I_MeasurementDocument.MeasurementReading < _MeasuringPoint.MeasuringPointMinimumThreshold then 1
      else 0 end as eam_msmt_rdng_under_threshold)             as MsmtReadingIsUnderThreshold,

      cast( case when I_MeasurementDocument.MeasurementReading > _MeasuringPoint.MeasuringPointMaximumThreshold then 1
      else 0 end as eam_msmt_rdng_over_threshold)              as MsmtReadingIsOverThreshold,

      I_MeasurementDocument._MeasuringPoint.AuthorizationGroup as AuthorizationGroup,
      // Propagate association(s)
      I_MeasurementDocument._Language,
      I_MeasurementDocument._MeasuringPoint,
      I_MeasurementDocument._InspectionLot,
      I_MeasurementDocument._MsmtRdngSourceMeasurementDoc,
      I_MeasurementDocument._ControllingObject,
      I_MeasurementDocument._UnitOfMeasure,
      I_MeasurementDocument._MsmtDocumentCatalogType,
      I_MeasurementDocument._MeasurementDocumentCodeGroup,
      I_MeasurementDocument._MeasurementValuationCode
}

• 事务代码：IK13/IK17
  测量文档和测量点关系、测量凭证描述、测量日期和时间、长文本、创建者等等

• 视图结构：

字段名称	技术名称
测量文档	MEASUREMENTDOCUMENT
测量点	MEASURINGPOINT
语言	LANGUAGE
文本	MEASUREMENTDOCUMENTTEXT
日期	MSMTRDNGDATE
度量时间	MSMTRDNGTIME
时戳	MEASUREMENTREADINGDATETIME
长文本	MEASUREMENTDOCUMENTHASLONGTEXT
读取人	MSMTRDNGBYUSER
创建日期	CREATIONDATE
时间	CREATIONTIME
时戳	MSMTDOCUMENTCREATIONDATETIME
创建人	CREATEDBYUSER
更改日期	LASTCHANGEDATE
更改人	LASTCHANGEDBYUSER
删除标识	SINGLELEVELDELETIONLOGICFLAG
原始标识	MEASUREMENTDOCUMENTORIGIN
检验批次	INSPECTIONLOT
特征	INSPECTIONCHARACTERISTIC
源文档	MSMTRDNGSOURCEMEASUREMENTDOC
对象类别	PRODNRSCETOOLTYPECODE
ProdResTool	PRODNRSCETOOLINTERNALID
订单对象号	MSMTDOCUMENTREFERREDORDER
后期维护任务	MSMTISDONEAFTERTASKCOMPLTN
计量读数	MEASUREMENTREADING
计量读数	MEASUREMENTREADINGINENTRYUOM
凭证计量单位	MEASUREMENTREADINGENTRYUOM
SI 单位	MSMTDOCUMENTSIUNITOFMEASURE
计数器读数	MEASUREMENTCOUNTERREADING
差异	MSMTCOUNTERREADINGDIFFERENCE
输入差异	MSMTCNTRREADINGDIFFISENTERED
替换计数器	MSMTCOUNTERREADINGISREPLACED
目录类型	MEASUREMENTDOCUMENTCATALOGTYPE
代码组	MEASUREMENTDOCUMENTCODEGROUP
评估代码	MSMTVALUATIONCODE
版本	MSMTVALUATIONCODEVERSNMBR
处理状态	MSMTRDNGSTATUS
冲销标识	MSMTRDNGISREVERSED
评估	INSPECTIONVALUATIONRESULT
间隔凭证	MSMTRDNGISINTERVALDOC
起始时间	MSMTRDNGINTERVALSTARTDATE
起始时间	MSMTRDNGINTERVALSTARTTIME
工序对象编号	MAINTORDEROPERATIONINTERNALID
阈值以下的读数	MSMTREADINGISUNDERTHRESHOLD
阈值以上的读数	MSMTREADINGISOVERTHRESHOLD
授权组	AUTHORIZATIONGROUP