CDS标准视图：维护活动类型描述 I_MaintenanceActivityTypeText

• 视图名称：维护活动类型描述 I_MaintenanceActivityTypeText
• 视图类型：基础
• 视图代码：

点击查看代码

@AbapCatalog.sqlViewName: 'IMTACTTYPET'
@Analytics: { dataExtraction.enabled: true }
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@EndUserText.label: 'Maintenance Activity Type - Text'
@ObjectModel.representativeKey: 'MaintenanceActivityType'

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.dataCategory: #TEXT

@ObjectModel.supportedCapabilities: [ #LANGUAGE_DEPENDENT_TEXT, #EXTRACTION_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET,
                                      #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE ]
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT


@Metadata.ignorePropagatedAnnotations
@Search.searchable: true
@Consumption.ranked: true

define view I_MaintenanceActivityTypeText
  as select from t353i_t
  association [0..1] to I_MaintenanceActivityType as _MaintenanceActivityType on $projection.MaintenanceActivityType = _MaintenanceActivityType.MaintenanceActivityType
  association [0..1] to I_Language                as _Language                on _Language.Language = $projection.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key t353i_t.spras                                                    as Language,
      @ObjectModel.foreignKey.association: '_MaintenanceActivityType'
      @ObjectModel.text.element: 'MaintenanceActivityTypeName'
  key cast( t353i_t.ilart as eam_maint_activity_type preserving type ) as MaintenanceActivityType,

      @Semantics.text: true
      @Search.defaultSearchElement: true
     @Search.fuzzinessThreshold: 0.9
     @Search.ranking: #LOW
      t353i_t.ilatx                                                    as MaintenanceActivityTypeName,

      _Language,
      _MaintenanceActivityType
}

• 事务代码：OIO3
  维护活动类型+文本描述

• 视图结构：

字段名称	设备名称
语言	LANGUAGE
活动类型	MAINTENANCEACTIVITYTYPE
匹配描述	MAINTENANCEACTIVITYTYPENAME