CDS标准视图：技术对象类别文本 I_TechnicalObjectTypeText

• 视图名称：技术对象类别文本 I_TechnicalObjectTypeText
• 视图类型：基础
• 视图代码：

点击查看代码

@EndUserText.label: 'Technical Object Type - Text'
@ObjectModel.dataCategory: #TEXT
@Analytics: {  dataExtraction : { enabled: true , delta.changeDataCapture.automatic: true } }
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'ITECHOBJTYPETXT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck:#CHECK
@ObjectModel.representativeKey: 'TechnicalObjectType'

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S

@Metadata.ignorePropagatedAnnotations

@Search.searchable: true
@ObjectModel.supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #EXTRACTION_DATA_SOURCE]


define view I_TechnicalObjectTypeText as select from t370k_t // T370K_T = Language-Dependent Texts for Object Type
association[0..1] to I_TechnicalObjectType as _TechnicalObjectType on _TechnicalObjectType.TechnicalObjectType = $projection.TechnicalObjectType
association [0..1] to I_Language as _Language on _Language.Language = $projection.Language
{

    @ObjectModel.foreignKey.association: '_TechnicalObjectType'
    key t370k_t.eqart as TechnicalObjectType,

    @ObjectModel.foreignKey.association: '_Language'
    @Semantics.language: true
    key t370k_t.spras as Language,

    @Semantics.text: true
    @Search.defaultSearchElement: true
    @Search.fuzzinessThreshold: 0.75
    t370k_t.eartx as TechnicalObjectTypeDesc,


     // Propagate association
     _TechnicalObjectType,
     _Language
}

• 事务代码：

• 视图结构：

字段名称	设备名称
对象类型	TECHNICALOBJECTTYPE
语言	LANGUAGE
对象类型文本	TECHNICALOBJECTTYPEDESC