手机写操作系统之 使用C语言编写内核
手机写操作系统之
使用C语言编写内核
下一步我们想用C语言编写32位系统，那么怎么办？
很简单，就是在kernel.asm使用call语句直接调用C程序。
具体过程如下：
汇编文件kernel.asm生成中间文件asmkernel.o。
C文件kernel.c生成中间文件kernel.o。
这两个中间文件再链接生成kernel.bin文件，具体过程参见makefile。
kernel.asm源码：
[BITS 32]
[GLOBAL start] ;导出 start这个入口，以便让链接器识别 ,
[EXTERN main] ;用到本文件外定义的函数 在kernel.c
jmp start
start:
call main ;调用C
jmp $
kernel.c源码：
int main()
{
int *p=(int )0x10050;
int offset = 50 * ( 800 + 1 ) + 250 ;
int b=p;
int short *video_addr=(int *)b;
video_addr = video_addr + offset ;
for (int i = 0 ; i < 50 ; i++){
*video_addr = 0x7ff ; //蓝色
video_addr ++ ;
}
}
kernelloader.asm源码：
[BITS 16]
jmp main
gdt_entries equ 3 ;共有三个段描述符：null,os code32,os data32
pe equ 1 ;bit PE in CR0
null equ 0h
os_code32_sel equ 8h ;1,gdt,rpl=00
os_data32_sel equ 10h ;2,gdt,rpl=00
VESA: times 256 db 0 ;分配一块区域存放 vesa 返回的信息，大小256，我们只需要其中的一个32位值
pdescr times 6 db 0
gdt_table times (gdt_entries*8) db 0
set_video_mode: ;设置显卡模式
push es
;设置显卡模式
mov ax , 0x4f02
mov bx , 0x4114 ;800X600 ( 5:6:5 ) 16位色彩
int 0x10
;取得该模式下显卡线性地址
mov bx , 0x1000
mov es , bx
mov di , VESA ;es:di指向256空间，int 10h将在此填写数据
mov ax , 0x4f01
mov cx , 0x114
int 0x10
;第40个字节开始存有显卡地址0xe0000000,将此地址再存入指定的地址0x10050
mov eax , [ es:VESA + 40 ]
;将此地址再存入指定的地址0x10050,
mov [ es:0x50 ] , eax ;eax内容为 0xe0000000
pop es
ret
read_kernel: ;读入 kernel 程序
push es
.rk:
mov ax , 0x8000 ;kernel.bin 所在的段基址
mov es , ax
mov bx , 0 ;写入到内存0x8000:0000 物理地址=0x80000
mov ah , 2
mov dh , 0 ;磁头
mov dl , 0 ;驱动器号
mov ch , 0 ;磁道0
mov cl , 4 ;第4个扇区开始
mov al , 1 ;读入扇区数,每个扇区为 512B
int 0x13
jc .rk
pop es
ret
main:
mov ax,1000h
mov ds,ax
;设置显卡模式
call set_video_mode
;读入 kernel
call read_kernel
;打开 A 20 地址线
mov ax , 0x2401
int 0x15
;[1]built up GDT table
cli
mov eax,gdt_table
;item 0:null descriptor,
mov dword[eax],0
mov dword[eax+4],0
add eax,8
;item 1,OS code32 descriptor,
;Base=00000000h,limit=0ffh,G=1,D=1,type=a,dpl=0
mov word[eax],0ffh
mov word[eax+2],0
mov byte[eax+4],00h
mov byte[eax+5],09ah
mov byte[eax+6],0c0h
mov byte[eax+7],00h
add eax,8
;item 2,OS data32 descriptor
;Base=00000000h,Limit=0fffffh,G=1,D=1,Type=2,DPL=0
mov word[eax],0ffffh
mov word[eax+2],0000h
mov byte[eax+4],00h
mov byte[eax+5],092h
mov byte[eax+6],0cfh ;高四位是G D 0 AVL，此处为1100 = c ,低四位是limit bit 16-19 此处为f
mov byte[eax+7],00h
add eax,8
;[2]built false GDT descriptor
mov word[pdescr+0],(gdt_entries*8)
mov dword[pdescr+2],gdt_table+00010000h
lgdt [pdescr]
;[3]enter into protected mode
;刷新CR0
mov eax,cr0
or eax,pe
mov cr0,eax
jmp flush
flush:
mov ax,os_data32_sel
mov ds,ax
mov es,ax
mov ss,ax
mov fs,ax
mov gs,ax
jmp dword os_code32_sel:0x80000 ;跳转到0x8000:0000保护模式 物理地址0x80000
boot.asm
[BITS 16] ;编译成16位的指令
[ORG 0x7C00]
jmp main
read_kernelloader: ;读入 kernelloader 程序
push es
.rk:
mov ax , 0x1000 ;kernelloader.bin 所在的段基址
mov es , ax
mov bx , 0
mov ah , 2
mov dl , 0 ;驱动器号
mov ch , 0
mov cl , 2
mov al , 2 ;读入扇区数,每个扇区为 512B
int 0x13
jc .rk
pop es
ret
main: ;主程序
mov ax , 0x0 ;boot.bin 程序的段基址
mov ds , ax
call read_kernelloader ;读入 kernelloader 程序
jmp dword 0x1000:0 ;跳转到 kernelloader 处执行
times 510-($-$$) db 0
db 0x55
db 0xAA
g.sh
!/bin/sh
echo "=启动 ya=="
cd /sdcard/A/ya/
make
cd ~
cp -r /sdcard/A/ya/out ./
cd out
chmod 755 ./*
执行命令，当前目录下生成a.img文件
./create_img.o a.img
执行命令，向a.img写入代码，内容是boot.bin
写入磁盘位置从0偏移量起始,占1个扇区512字节
./write_in_img.o a.img boot.bin 0
执行命令，向a.img写入代码，内容是kernelloader.bin
boot.bin已经占用了512字节,写入磁盘位置从512偏移量起始,占2个扇区1024字节
./write_in_img.o a.img kernelloader.bin 512
执行命令，向a.img写入代码，内容是kernel.bin
boot.bin+kernelloader.bin已经占用了512+1024 = 1536字节,写入磁盘位置从1536偏移量起始，占1个扇区512字节
./write_in_img.o a.img kernel.bin 1536
结果复制到手机
cp -f ./a.img /sdcard/A/ya/final
cd ~
rm -r out
makefile
######################
声明要编译的所有组成,这里的ya是本工程名称，可以取任何名字，这里就用ya
######################
ya:out/boot.bin out/kernelloader.bin out/asmkernel.o out/kernel.o out/kernel.ld out/kernel.bin out/create_img.o out/write_in_img.o out/drawcode.o
开始对各部分编译，注意不是空格是Tab键
out/boot.bin:code/boot.asm
nasm code/boot.asm -o out/boot.bin
out/kernelloader.bin:code/kernelloader.asm
nasm code/kernelloader.asm -o out/kernelloader.bin
编译asm文件，生成中间文件
out/asmkernel.o:code/kernel.asm
nasm -f elf32 code/kernel.asm -o out/asmkernel.o
编译C文件，生成中间文件
out/kernel.o:code/kernel.c
clang -fpack-struct -std=c99 --target=i386 -c code/kernel.c -o out/kernel.o
链接内核
out/kernel.ld:out/asmkernel.o out/kernel.o
ld -m elf_i386 -static -e start -Ttext 0x80000 out/asmkernel.o out/kernel.o -o out/kernel.ld
生成可执行代码文件
out/kernel.bin:out/kernel.ld
objcopy -R .note -R .comment -S -O binary out/kernel.ld out/kernel.bin
制作内核映象工具
out/create_img.o:code/create_img.cpp
clang++ code/create_img.cpp -o out/create_img.o
写入文件,argv[1]=目标文件 argv[2]=源文件 argv[3]=写入偏移量
out/write_in_img.o:code/write_in_img.cpp
clang++ code/write_in_img.cpp -o out/write_in_img.o
######################
运行模拟器，结果显示如图：
