d传递地址时得到闭包

原文

public:
    void server_init() {
        CreateThread(NULL, 0, &this.ClientThread, cast(PVOID)clientSocket, 0, NULL);
    }

private:
    extern(Windows)
    DWORD ClientThread(PVOID param) {
        this.log("你好");
        return 0;
    }

CreateThread调用私函数地址.得到:

不能传递extern (Windows) uint delegate(void* param)
到extern (Windows) uint function(void*) @system参数

非静态成员函数指针总是产生闭包.否则,访问无法类实例的成员.参考
可结合类对象与其他参数,线程函数知道如何解开类对象来调用成员函数:

import std.stdio;

// 这是库
alias MyThreadFunc = uint function(void*);

// 库提供:
extern (C)
void libraryCreateThread(MyThreadFunc func, void* param) {
    writeln("函数");
    func(param);
}

// 我的类
class C {
    string s;

    // 要调用的函数
    void myClientThread(void* param) {
        writeln("想要成员函数");
        writeln("成员:", s);

        // 额外参数为`整`.
        auto arg = *cast(int*)param;
        writeln("额外参:", arg);
    }
}

// 库要的函数.
uint myNonMemberThreadFunc(void* param) {
    writeln("使用参数");

    auto args = *cast(MyThreadArgs*)param;

    writeln("调用成员函数");
    args.c.myClientThread(args.extraArg);

    return 0;
}

// 组合(这里是指针)实例与其他参数
struct MyThreadArgs {
    C c;
    void* extraArg;
}

void main() {
    auto c = new C();
    c.s = "类成员";

    // 其他参数
    int mainArg = 42;

    // 组合类对象,必须在堆上
    auto args = MyThreadArgs(c, &mainArg);

    // 调用库.
    libraryCreateThread(&myNonMemberThreadFunc, cast(void*)&args);
}