NOI 4976:硬币

描述

宇航员Bob有一天来到火星上，他有收集硬币的习惯。于是他将火星上所有面值的硬币都收集起来了，一共有n种，每种只有一个：面值分别为a₁,a₂… a_n。 Bob在机场看到了一个特别喜欢的礼物，想买来送给朋友Alice，这个礼物的价格是X元。Bob很想知道为了买这个礼物他的哪些硬币是必须被使用的，即Bob必须放弃收集好的哪些硬币种类。飞机场不提供找零，只接受恰好X元。

输入

第一行包含两个正整数n和x。（1 <= n <= 200, 1 <= x <= 10000)
第二行从小到大为n个正整数a1, a2, a3 … an （1 <= ai <= x)

输出

第一行是一个整数，即有多少种硬币是必须被使用的。
第二行是这些必须使用的硬币的面值（从小到大排列）。

样例输入

5 18
1 2 3 5 10

样例输出

2
5 10

提示

输入数据将保证给定面值的硬币中至少有一种组合能恰好能够支付X元。
如果不存在必须被使用的硬币，则第一行输出0，第二行输出空行

思路：解题思路:我们考虑a[i]是否满足其实必须元素，容易想到，f[x]-f[x-a[i]]是否为零，但是f[x-a[i]]的方案数中可能也会用到a[i]，所以f[x-a[i]]-f[x-a[i]*2]，整理一下就是f[x]-f[x-a[i]]+f[x-a[i] *2]，也很容易发现容斥规律，由此可以递归求解，递归边界为x-a[i] *k<0或者f[x-a[i] *k]==0; 

例如：测试数据,01背包后  

f=(1,1,1,2,1,2,2,1,2,1,2,2,1,2,1,2,2,1,2）

那么， f[18]->f[15]  使用了3，

          但是，15=10,5  或  15=10,2,3;

          这样，我们就多考虑了一种情况；

所以，要加上这种多考虑的情况

program ex03;
var f:array[0..10000] of int64;
    a,ans:array[0..1000] of longint;
    n,tot,x:longint;
procedure dp;                      //01背包
var i,j:longint;
begin
  f[0]:=1;
  for i:=1 to n do
   for j:=x downto a[i] do
   begin
      f[j]:=f[j]+f[j-a[i]];
    end;
end;
procedure init;
var i:longint;
begin
  readln(n,x);
  for i:=1 to n do read(a[i]);
end;
function cal(x,y:longint):longint;
begin
  if x<0 then exit(0) else exit(f[x]-cal(x-y,y));
end;
procedure doit;
var i:longint;
begin
  for i:=1 to n do
  begin
    if f[x]-cal(x-a[i],a[i])=0 then       //判断是否必要
    begin
      inc(tot);
      ans[tot]:=a[i];
    end;
  end;
end;
procedure print;
var i:longint;
begin
  writeln(tot);
  for i:=1 to tot do
  write(ans[i],' ');
end;
begin
  init;
  dp;
  doit;
  print;
end.