使用cmd查看电脑连接过的wifi密码(一)

有时总会忘记之前的wifi密码，这时候就需要查看wifi密码：

这个我就写了一个bat文件，方便下次使用，这里我添加了中文和英文的判断，主要是语言不同输出的信息不用，不说了直接上代码：

@echo off
echo WiFiPasswordSee
echo ====================================
echo Author:feiquan
echo Create:2018/10/20 17:39
echo UpdataDate:2018/10/20 23:24
echo Version:1.1v
echo Function:Look for your computer connnect WiFi password
echo =====================================
:start
set leg=ch
set /p leg=确定你的Windows系统语言 英文/中文(en/默认:ch):
if %leg%==en (
rem English
netsh wlan show profiles |find "All User Profile"
) else if %leg%==ch (
rem Chinese
netsh wlan show profiles |find "所有用户配置文件"
) else (
goto start
)

echo =====================================


:loop
set /p name=Input your WiFi name(SSID):
if %leg%==en (
rem English
(netsh wlan show profiles name="%name%" key=clear |find "SSID name")||echo     SSID name              : "%name%" 
(netsh wlan show profiles name="%name%" key=clear |find "Key Content")||echo     Key Content            : NO exist
) else if %leg%==ch (
rem Chinese
(netsh wlan show profiles name="%name%" key=clear |find "SSID 名称")||echo     SSID 名称            : "%name%" 
(netsh wlan show profiles name="%name%" key=clear |find "关键内容")||echo     关键内容            : NO exist
) else (
goto start
)
echo =====================================
set temp=y
set /p temp=Continue to look up other WiFi password(默认:y/n):
if "%temp%"=="y" goto loop
pause
exit

 

运行结果：