使用IDL进行氚羽流监测（四）——绘制预期氚衰变图

这部分研究内容包括确定储罐/井中氚的预期衰变率，假设储罐保持完好并且没有氚泄漏到周围的沉积物中。根据这些假设，储罐中的氚浓度要多久才能低于世卫组织指导的 10000Bq/L饮用水标准？同时又要多久才能低于《核电厂放射性液态流出物排放技术要求》（GB 14587-2011）中要求的排放口下游1km处受纳水体中H-3 浓度不能超过100Bq/L的标准？

本例计算了预期的衰减率，并将其与储罐定期进行的实际测量结果进行了对比。

首先创建一个图表，显示随着时间的推移，放射性衰变对其中一个储罐内的氚浓度可能产生的影响。在这个例子中，我们假设初始年份为1995年（储罐装满并封闭的年份），要计算的年数为150年，根据初始测量，假定储罐内氚的初始浓度为260000 Bq/L 。有以下信息：

初始浓度N₀=260000 Bq/L
储罐填满后被密封
氚的半衰期t_1/2=12.32年
氚的衰变常数k=-ln(2)/t_1/2
t=1995年起的年数
某一年的浓度N=N₀e^-kt

iYear = 1995  ;初始年份。
nYR = 150 ;要计算的年数。
decay = (-(ALOG(2))/12.32)  ;氚的衰变常数。
iBq = 260000 ;初始氚浓度的估计。
 
; 三个方程来计算可能的边界条件。
; Bq 是基于假设的初始氚浓度为2.6x10 5 Bq/L计算得到的放射性衰变。
; BqHigh和BqLow是基于初始浓度可能存在的误差计算得到的衰变可能边界条件。
; 误差范围为正负10%。
Bq = (iBq*EXP(decay*FINDGEN(nYR))) ; expected
BqHigh = ((Bq)*1.10)
BqLow = ((Bq)*0.90)
year = (iYear+FINDGEN(nYR))
 
; 绘制预期衰变和高/低条件。
 myPlot = PLOT(year, Bq, $
   DIMENSIONS=[800, 550], LINESTYLE=4, $
   TITLE="简易的氚源衰变（Bq/L）", $
   XTITLE="年份", YTITLE="氚浓度（Bq/L）", $
   NAME='预期值', $
      font_name = 'Microsoft Yahei')
high = PLOT(year, BqHigh, COLOR='red', $
   DIMENSIONS=[800, 550], /OVERPLOT, $
   THICK=2, NAME='+10%')
low = PLOT(year, BqLow, COLOR='green', $
   DIMENSIONS=[800, 550], /OVERPLOT, $
   THICK=2, NAME='-10%')

IDL显示：

可以将这些模拟数据与定期在储存罐内测量的观测值对比，以评估边界条件建模的准确程度以及衰减模拟与实际情况的接近程度。我们还将绘制两条代表世卫组织指导的 10000Bq/L“警戒”线，代表GB 14587-2011中规定100Bq/L氚浓度“安全”线。

; 为10000 Bq/L “警戒”浓度创建一条线。
year = [2040,2050,2060]
safe10000 = [10000,10000,10000]
 
safe1Plot = PLOT(year, safe10000, DIMENSIONS=[800, 550], $
   COLOR='spring green', NAME='10000 Bq$\slash$L警戒线', $
   /OVERPLOT, THICK=2, LINESTYLE=4)
 
; 为100Bq/L“安全”浓度创建一条线。
year = [2120,2130,2140]
safe100 = [100,100,100]
 
safe2Plot = PLOT(year, safe100, DIMENSIONS=[800, 550], $
   COLOR='LIME', NAME='100 Bq$\slash$L安全线', $
   /OVERPLOT, THICK=2, LINESTYLE=4)


; 绘制观测数据。创建变量
; 观测年份 (obsYear) 和观测浓度 (obsBq)。
obsYear = [1996,1998,2000,2002,2004,2006, $
   2008,2010,2012,2013]
obsBq = [279444,277741,272418,270407,263077,260820,$
261263,260374,251925,225011]
myObs = PLOT(obsYear, obsBq, LINESTYLE=4, COLOR='purple', $
   THICK=3, /OVERPLOT, NAME='实测值')
 
; 使用分配给每个图的名称添加图例。
myLegend = LEGEND(TARGET=[myPlot,myObs,high,low,safe1Plot,safe2Plot], /DATA, $
   /AUTO_TEXT_COLOR, FONT_SIZE=10, POSITION=[2130,2.5e5] , $
      font_name = 'Microsoft Yahei')