【IDL】读取文本中三维数组的方法

利用IDL可以自动获取文本中一维、二维甚至三维的数组。当数组为二维以上时，需要通过方法获取数组的行列数等信息。下面以三维数组为例，介绍如何使用IDL自动获取文本中保存的三维数组。

对于三维数组的保存方式有一定的要求，如图所示（习惯遥感图像了，就把第三维看成是波段吧，o(∩_∩)o ~）。本次测试未考虑数据类型，大家可参考代码进行修改。

图：测试所用三维数组及格式说明

代码如下：

• Samples – 列数
• Lines – 行数
• Bands – 波段数

PRO TEST_READ_3D_TXT
  ;文件路径，自行修改
  file = 'D:\Temp\3维数组.txt'
 
  ;获取samples。因为有空行，所以不能用FILE_LINES函数。
 OPENR, lun, file, /get_lun
 WHILE ~EOF(lun) DO BEGIN
   str = ''
   READF, lun, str
   IF STRTRIM(str) NE '' THEN BEGIN
     samples = N_ELEMENTS(STRSPLIT(str))
     BREAK
   ENDIF
 ENDWHILE
 FREE_LUN, lun
 
  ;获取lines和bands, lines是总行数，除以bands得到每一维的行数。
  bands = 1L
  lines = 0L
  blank = 0
 
 OPENR, lun, file, /get_lun
 WHILE ~EOF(lun) DO BEGIN
   str = ''
   READF, lun, str
   IF STRTRIM(str) EQ '' AND blank EQ 1 THEN BEGIN
     bands++
     blank++
   ENDIF ELSE IF STRTRIM(str) NE '' THEN BEGIN
     blank = 1
     lines++
   ENDIF ELSE IF STRTRIM(str) EQ '' AND blank GT 1 THEN BEGIN
     blank++
   ENDIF
 ENDWHILE
 FREE_LUN, lun
 
 IF blank GE 2 THEN bands--
 
 PRINT, 'samples: ', samples
 PRINT, 'lines:  ', lines/bands
 PRINT, 'bands:  ', bands
 
;获取三维数组Data
  Data = INTARR(samples, lines/bands, bands)
 OPENR, lun, file, /get_lun
 READF, lun, Data
 FREE_LUN, lun
 
 PRINT, Data
 
END

 

IDL Prints：

 

samples:           5
lines:             4
bands:             3
      0      1      2      3      4
      5      6      7      8      9
     10     11     12     13     14
     15     16     17     18     19
 
     20     21     22     23     24
     25     26     27     28     29
     30     31     32     33     34
     35      36     37     38     39
 
     40     41     42     43     44
     45     46     47     48     49
     50     51     52     53     54
     55     56     57     58     59