树形图计数——特殊的图逆向搜索法

树形图计数

count.pas/c/cpp

 

【问题描述】

       小k同学最近正在研究最小树形图问题。所谓树形图，是指有向图的一棵有根的生成树，其中树的每一条边的指向恰好都是从根指向叶结点的方向。现在小k在纸上画了一个图，他想让你帮忙数一下这个图有多少棵树形图。

 

【输入格式】

第1行输入1个正整数：n，表示图中点的个数

第2~n+1行每行输入n个字符，描述了这个图的邻接矩阵。第i+1行第j个字符如果是0则表示没有从i连向j的有向边，1表示有一条从i到j的有向边。

 

【输出格式】

输出1行1个整数，表示这个有向图的树形图个数。

 

【样例输入】

count.in

4

0100

0010

0001

1000

 

【样例输出】

count.out

4

 

【数据规模和约定】

对于100%的数据， n<=8

 

统计树形图即统计生成树的个数

以下的方法是用枚举+逆向搜索实现的

具体的解释在代码中

program count;
  var
    a,b:array[1..10,1..10]of longint;
    f,ff:array[1..10]of boolean;
    fa:array[1..10]of longint;
    n,i,j,k,root:longint;
    ans:qword;
    flag:boolean;
    ch:char;
  function judge:boolean;//判断是否构成了一棵生成树
    var
      i,x:longint;
    begin
      fillchar(f,sizeof(f),false);
      f[root]:=true;//根标记为已访问
      for i:=1 to n do//枚举每个节点向上找
        begin
          fillchar(ff,sizeof(ff),false);//ff数组标记用，判断是否有环
          x:=fa[i];//x为i点的父节点
          while (fa[x]<>root)and(not f[fa[x]])and(fa[x]<>0) do//当x的父节点不是根，且x父节点未被访问过，且存在x的父节点
            begin
              if ff[x] then exit(false);//如果x节点在本次寻找中已被访问，则存在环，返回假
              ff[x]:=true;//标记x已访问
              x:=fa[x];//把x赋值为x的父节点编号
            end;
          if fa[x]=0 then exit(false);//如果最终x的父节点为0，代表i点未能连到根节点，返回假
          if (fa[x]=root)or(f[fa[x]]) then//如果x父节点为根节点或x父节点被（大循环中）访问过
            begin
              x:=i;//x重新赋值为i
              while not f[x] do
                begin
                  f[x]:=true;
                  x:=fa[x];
                end;//向上追溯并把沿途的点标记为已访问
            end;
        end;
      exit(true);//若能执行到这步，返回真
    end;

  procedure dfs(x:longint);//搜索x节点，按顺序搜——1~n，枚举每个节点的父节点
    var
      i,j:longint;
    begin
      if x=root then
        begin
          dfs(x+1);
          exit;//如果正在搜根，则跳过
        end;
      if x=n+1 then
        begin
          if judge then inc(ans);
          exit;
        end;//如果已经搜完了所有的点，则判断是否符合题意，若符合，则answer加一
      for i:=1 to n do
        if b[i,x]<>0 then
          begin
            fa[x]:=i;
            dfs(x+1);
          end;//再如果是别的情况（不是根节点，且正在访问图中的节点），则枚举每个节点，看是否有i——>x的边
        //若有边，则把x的父节点暂定为i，搜索下一个点（这样也很好地处理了不同树形的情况）
     //因为回溯回来时会对该点可能的入边接着进行枚举
    end;

  begin
    assign(input,'count.in');
    reset(input);
    assign(output,'count.out');
    rewrite(output);
    readln(n);
    for i:=1 to n do
      begin
        for j:=1 to n do
          begin
            read(ch);
            if ch='1' then b[i,j]:=1
              else b[i,j]:=0;
          end;
        readln;
      end;//读入邻接矩阵并存储
    for root:=1 to n do//枚举根节点
      begin
        flag:=false;
        for i:=1 to n do
          if b[root,i]<>0 then
            begin
              flag:=true;
              break;
            end;//如果flag为true，说明有连出去的边，即，root点可以做根，为下面的搜索作判断根据
        fa[root]:=root;//父亲数组记录此节点的父节点
        if flag then dfs(1);//若root可做根，则搜索
      end;
    writeln(ans);
    close(input);
    close(output);
  end.