使用 Inno Setup 安装 MySQL 8.0

使用 MySQLInstallerConsole 安装数据库

1.下载官方安装包, 如 mysql-installer-community-8.0.20.0.msi

2.创建安装文件
msiexec.exe /i mysql-installer-community-8.0.20.0.msi /qb /l* mysql-log.txt
执行成功后, 会在 C:\Program Files (x86)\MySQL\MySQL Installer for Windows 生成安装文件 MySQLInstallerConsole.exe

3.查看安装状态
MySQLInstallerConsole.exe community status
注意: 由于下载的是社区版, 安装时需要在命令参数加上 community, 并且是第一个参数, 后面使用这个命令时都需要加上

4.安装 MySQL Server
MySQLInstallerConsole.exe community Install -silent server;8.0.20;x64:*:type=config;openfirewall=false;generallog=true;binlog=true;serverid=3308;enable_tcpip=true;port=3308;servicename=diy.MySQL80;rootpasswd=root001;installdir="C:\diy\MySQL\mysql-8.0.20";datadir="C:\diy\MySQL\data":type=user;username=root;password=root001;role=DBManager;auth_plugin=caching_sha2_password
服务名 servicename=diy.MySQL80
端口号为 3308
用户 root
密码 root001
安装路径 installdir="C:\diy\MySQL\mysql-8.0.20"
数据路径 datadir="C:\diy\MySQL\data"
注意: 这里使用 -silent 参数, 以禁用确认

5.升级, MySQL 8.0 升级时, 即使指定了 -silent 选项, 也会卡在输入 'Y' continue, 即不能直接静默升级
MySQLInstallerConsole upgrade * -silent
MySQLInstallerConsole upgrade server:8.0.21 -silent
MySQLInstallerConsole upgrade workbench:8.0.21 -silent

6.安装 MySQL 其它功能:
MySQLInstallerConsole community install -silent ^
workbench;8.0.21;x64:* ^
shell;8.0.21;x64:* ^
connector/ODBC;8.0.21;x64:* ^
connector/J;8.0.21;x86:* ^
connector/C++;8.0.21;x64:* ^
connector/NET;8.0.21;x86:*

 

 

使用 mysqld.exe 安装数据库

1.优点: 使用这种方式, 通过指定不同的端口号和服务名称, 在一台主机中安装多个数据库, 并且可以实现静默升级

2.解压官方安装包, 如 mysql-8.0.20-winx64.zip, 可以找到 mysqld.exe 的位置 mysql-8.0.20-winx64/bin/mysqld.exe目录

3.my.ini 放到 bin 同级目录中--即mysql-8.0.20-winx64

4.端口, 安装目录, 数据目录等配置信息在 my.ini 文件中指定

5.执行以下命令以完成数据库安装
mysqld.exe --initialize-insecure
mysqld.exe --install diy.MySQL80

7.启动服务
sc start diy.MySQL80

6.设置密码. --initialize-insecure 参数安装的 MySQL, 不会设置密码, 此时登录 MySQL 后, 使用下面的语句进行更改
alter user 'root'@'localhost' identified by 'root001';

7.升级 MySQL, 这里只考虑小版本升级, 不包括数据需要迁移这种大的版本改动
(1)下载高版本的应用包, 如 mysql-8.0.21-winx64.zip
(2)停止服务: sc stop diy.MySQL80
(3)删除服务: mysqld.exe --remove diy.MySQL80
(4)按照 1-5 重新安装新版本程序即可

 

 

 

设置为允许外部连接

1.管理员权限打开 cmd, 进入 MySQL 安装目录, 登录 mysql (输入以下命令后, 按提示输入密码)
mysql -P3308 -uroot -p

2.登录成功后, 执行以下数据库命令
USE mysql;
UPDATE user SET host='%' WHERE user ='root';
FLUSH PRIVILEGES;
GRANT ALL PRIVILEGES ON *.* TO 'root'@'%'WITH GRANT OPTION;

3.关闭系统防火墙

 

测试连接

1.本地连接
mysql -P3308 -uroot -p

2.访问其它主机的数据库
mysql -h192.168.1.68 -P3308 -uroot -p

 

 

通过 sql 命令查看版本号

1.MySQl登录成功后会显示版本号，也可以通过下面的 SQL 语句查看
select version();

2.注意 mysql.exe --version 查看的是应用程序的版本号，不会显示实际运行的服务的版本号

 

 

安装 MySQL 的 InnoSetup 脚本

; Script generated by the Inno Setup Script Wizard.
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!

; 升级时, 只需要将版本号相关的部分替换掉, 即可实现自动升级
#define MyAppName                      "MySQL"
#define MYSQL_SERVICE                  "diy.MySQL80"
#define MYSQL_VERSION                  "8.0.20"
#define MYSQL_PORT                     "3308"
#define MYSQL_PASSWD                   "root001"
#define MYSQL_DATA_DIR                 "diy\MySQL\Data"
#define MYSQL_PACKAGE_DIR              "mysql-8.0.20-winx64"
#define MYSQL_INSTALL_DIR              "diy\MySQL\MySQL8\mysql-8.0.20-winx64"

[Setup]
; NOTE: The value of AppId uniquely identifies this application.
; Do not use the same AppId value in installers for other applications.
; (To generate a new GUID, click Tools | Generate GUID inside the IDE.)
AppId = {{A0EF8E7D-DF4E-5E8A-9C51-a017482BAC3D}
AppName = {#MyAppName}
AppVersion = {#MYSQL_VERSION}
;AppVerName = {#MyAppName} {#MYSQL_VERSION}
; 默认安装路径
DefaultDirName = "C:\{#MYSQL_INSTALL_DIR}"
DefaultGroupName = {#MyAppName}
OutputDir = .
OutputBaseFilename = diy_mysql_installer
; 注意, 必须要求管理员权限, 因为开启关闭服务等命令必须要管理员权限才能成功
PrivilegesRequired = admin

[Languages]
Name: cn; MessagesFile: "compiler:Languages\ChineseSimplified.isl"
Name: en; MessagesFile: "compiler:Default.isl"

[Messages]
cn.BeveledLabel = 中文
en.BeveledLabel = 英文

[CustomMessages]
cn.msgInstallMySQL = 安装 MySQL
cn.msgUpgradeMySQL = 更新 MySQL
en.msgInstallMySQL = Install MySQL
en.msgUpgradeMySQL = Upgrade MySQL

[Tasks]

[Dirs]
; 创建一个临时工作目录
Name: "{app}\workdir"; Attribs: hidden; Flags: deleteafterinstall

[Files]
; 拷贝 MySQL 安装包
Source: "MySQL\{#MYSQL_PACKAGE_DIR}\*"; DestDir: {code:GetMySQLInstallDir|{app}}; Check: CheckInitMySQL(); Flags: ignoreversion createallsubdirs recursesubdirs uninsneveruninstall
Source: "MySQL\my.ini"; DestDir: {code:GetMySQLInstallDir|{app}}; Check: CheckInitMySQL(); Flags: ignoreversion uninsneveruninstall

[Icons]

[Run]
; 安装 MySQL, 并启动服务, 更新密码和版本号
Filename: {code:GetMySQLInstallDir|{app}}\bin\mysqld.exe; Parameters: " --initialize-insecure"; WorkingDir:{app}\workdir; StatusMsg: {cm:msgInstallMySQL}; Check: CheckInstallMySQL(); BeforeInstall: BeforeInstallMySQL; Flags: runhidden
Filename: {code:GetMySQLInstallDir|{app}}\bin\mysqld.exe; Parameters: " --install {#MYSQL_SERVICE}"; WorkingDir:{app}\workdir; StatusMsg: {cm:msgInstallMySQL}; Check: CheckInstallMySQL(); Flags: runhidden
Filename: sc.exe; Parameters: " start {#MYSQL_SERVICE}"; WorkingDir:{app}\workdir; StatusMsg: {cm:msgInstallMySQL}; Check: CheckInstallMySQL(); AfterInstall: AfterInstallMySQL; Flags: runhidden
; 更新 MySQL: 停止服务, 删除服务, 重新安装新版本, 并启动服务, 更新版本号
Filename: sc.exe; Parameters: " stop {#MYSQL_SERVICE}"; WorkingDir:{app}\workdir; StatusMsg: {cm:msgUpgradeMySQL}; Check: CheckUpgradeMySQL(); Flags: runhidden
Filename: {code:GetMySQLInstallDir|{app}}\bin\mysqld.exe; Parameters: " --remove {#MYSQL_SERVICE}"; WorkingDir:{app}\workdir; StatusMsg: {cm:msgUpgradeMySQL}; Check: CheckUpgradeMySQL(); Flags: runhidden
Filename: {code:GetMySQLInstallDir|{app}}\bin\mysqld.exe; Parameters: " --initialize-insecure"; WorkingDir:{app}\workdir; StatusMsg: {cm:msgUpgradeMySQL}; Check: CheckUpgradeMySQL(); BeforeInstall: BeforeInstallMySQL; Flags: runhidden
Filename: {code:GetMySQLInstallDir|{app}}\bin\mysqld.exe; Parameters: " --install {#MYSQL_SERVICE}"; WorkingDir:{app}\workdir; StatusMsg: {cm:msgUpgradeMySQL}; Check: CheckUpgradeMySQL(); Flags: runhidden
Filename: sc.exe; Parameters: " start {#MYSQL_SERVICE}"; WorkingDir:{app}\workdir; StatusMsg: {cm:msgUpgradeMySQL}; Check: CheckUpgradeMySQL(); AfterInstall: AfterUpgradeMySQL; Flags: runhidden


[Code]
function GetInstallDriveName(aRoot: String): String;
var
theAppDir: String;
begin
  theAppDir := ExpandConstant(aRoot);
  if Length(theAppDir) > 0 then begin
    Result := theAppDir[1] + ':\';
  end else begin
    Result := 'D:\';
  end;
end;

function GetMySQLInstallDir(aRoot: String): String;
begin
  Result := GetInstallDriveName(aRoot) + ExpandConstant('{#MYSQL_INSTALL_DIR}');
end;

function GetMySQLDataDir(aRoot: String): String;
begin
  Result := GetInstallDriveName(aRoot) + ExpandConstant('{#MYSQL_DATA_DIR}');
end;

// 将 MySQL 版本号转为整数(a.b.c -> a << 16 + b << 8 + c, a/b/c 为整数), 失败时返回 -1
function GetMySQLVersionValue(aVersionText: String): Integer;
var
theSubText: String;
theVersionValue : Integer;
i: Integer;
begin
  theVersionValue := 0;
  for i := 1 to Length(aVersionText) do begin
    if aVersionText[i] <> '.' then begin
      theSubText := theSubText + aVersionText[i];
    end else begin
      if Length(theSubText) > 0 then begin
        theVersionValue := (theVersionValue SHL 8) + StrToInt(theSubText);
        theSubText := '';
      end;
    end;
  end;
  if Length(theSubText) > 0 then begin
    theVersionValue := (theVersionValue SHL 8) + StrToInt(theSubText);
  end;
  if Length(aVersionText) <> 0 then begin
    Result := theVersionValue;
  end else begin
    Result := -1;
  end;
end;

function ReadMySQLVersion(): String;
var
  theVersionText: String;
begin
  if RegQueryStringValue(HKEY_LOCAL_MACHINE, 'SOFTWARE\diy\MySQL', 'Version', theVersionText) then begin
    Result := theVersionText;
  end else begin
    Log('read mysql version failed');
    Result := '';
  end;
end;

procedure SaveMySQLVersion();
begin
  if not RegWriteStringValue(HKEY_LOCAL_MACHINE, 'SOFTWARE\diy\MySQL', 'Version', ExpandConstant('{#MYSQL_VERSION}')) then begin
    Log('Save mysql version failed');
  end;
end;

function IsNewMySQLVersion(): Boolean;
var
thePrevVersionValue: Integer;
theCurrentVersionValue: Integer;
begin
  Result := False;
  thePrevVersionValue := GetMySQLVersionValue(ReadMySQLVersion());
  theCurrentVersionValue := GetMySQLVersionValue(ExpandConstant('{#MYSQL_VERSION}'));
  if theCurrentVersionValue > thePrevVersionValue then begin
    Result := True;
  end;
end;

function CheckInstallMySQL(): Boolean;
var
theVersionValue: Integer;
begin
  Result := False;
  theVersionValue := GetMySQLVersionValue(ReadMySQLVersion());
  if theVersionValue = -1 then begin
    Result := True;
  end;
end;

function CheckUpgradeMySQL(): Boolean;
begin
  Result := False;
  if IsNewMySQLVersion() then begin
    Result := True;
  end;
end;

function CheckInitMySQL(): Boolean;
begin
  Result := False;
  if CheckInstallMySQL() or CheckUpgradeMySQL() then begin
    Result := True;
  end;
end;

function IsMySQLAppExists(): Boolean;
var
theMySQLApp: String;
begin
  theMySQLApp := GetMySQLInstallDir(ExpandConstant('{app}')) + '\bin\mysql.exe';
  Result := FileExists(theMySQLApp);
end;

procedure BeforeInstallMySQL();
var
theAppDir: String;
theMySQLInstallDir: String;
theMySQLDataDir: String;
theMyIniFile: String;
begin
  theAppDir := ExpandConstant('{app}');
  theMySQLInstallDir := GetMySQLInstallDir(theAppDir);
  theMySQLDataDir := GetMySQLDataDir(theAppDir);
  theMyIniFile := theMySQLInstallDir + '\my.ini';
  if not SetIniString('mysqld', 'datadir', theMySQLDataDir, theMyIniFile) then begin
    Log('update datadir failed');
  end;
  if not SetIniString('mysqld', 'basedir', theMySQLInstallDir, theMyIniFile) then begin
    Log('update basedir failed');
  end;
end;

procedure ResetMySQLPasswd();
var
theMySQLApp: String;
theMySQLParam: String;
theSQL: String;
theCommandParam: String;
theResultCode: Integer;
begin
  theMySQLApp := GetMySQLInstallDir(ExpandConstant('{app}')) + '\bin\mysql.exe';
  theMySQLParam := ' -P' + ExpandConstant('{#MYSQL_PORT}') + ' -uroot -e';
  // alter user 'root'@'localhost' identified by '12345';
  theSQL := ' "alter user ''root''@''localhost'' identified by ''' + ExpandConstant('{#MYSQL_PASSWD}') + ''';"';
  theCommandParam := theMySQLParam + theSQL;
  if not Exec(theMySQLApp, theCommandParam, '', SW_HIDE, ewWaitUntilTerminated, theResultCode) then begin
    Log('reset passwd failed, result msg:' + SysErrorMessage(theResultCode));
  end;
end;

procedure AfterInstallMySQL();
begin
  if IsMySQLAppExists() then begin
    ResetMySQLPasswd();
    SaveMySQLVersion();
  end;
end;

procedure AfterUpgradeMySQL();
begin
  if IsMySQLAppExists() then begin
    SaveMySQLVersion();
  end;
end;

 

 

 

# Other default tuning values
# MySQL Server Instance Configuration File
# ----------------------------------------------------------------------
# Generated by the MySQL Server Instance Configuration Wizard
#
#
# Installation Instructions
# ----------------------------------------------------------------------
#
# On Linux you can copy this file to /etc/my.cnf to set global options,
# mysql-data-dir/my.cnf to set server-specific options
# (@localstatedir@ for this installation) or to
# ~/.my.cnf to set user-specific options.
#
# On Windows you should keep this file in the installation directory 
# of your server (e.g. C:\Program Files\MySQL\MySQL Server X.Y). To
# make sure the server reads the config file use the startup option 
# "--defaults-file". 
#
# To run the server from the command line, execute this in a 
# command line shell, e.g.
# mysqld --defaults-file="C:\Program Files\MySQL\MySQL Server X.Y\my.ini"
#
# To install the server as a Windows service manually, execute this in a 
# command line shell, e.g.
# mysqld --install MySQLXY --defaults-file="C:\Program Files\MySQL\MySQL Server X.Y\my.ini"
#
# And then execute this in a command line shell to start the server, e.g.
# net start MySQLXY
#
#
# Guidelines for editing this file
# ----------------------------------------------------------------------
#
# In this file, you can use all long options that the program supports.
# If you want to know the options a program supports, start the program
# with the "--help" option.
#
# More detailed information about the individual options can also be
# found in the manual.
#
# For advice on how to change settings please see
# https://dev.mysql.com/doc/refman/8.0/en/server-configuration-defaults.html
#
#
# CLIENT SECTION
# ----------------------------------------------------------------------
#
# The following options will be read by MySQL client applications.
# Note that only client applications shipped by MySQL are guaranteed
# to read this section. If you want your own MySQL client program to
# honor these values, you need to specify it as an option during the
# MySQL client library initialization.
#
[client]

# pipe=

# socket=MYSQL

port=3307

[mysql]
no-beep

# default-character-set=

# SERVER SECTION
# ----------------------------------------------------------------------
#
# The following options will be read by the MySQL Server. Make sure that
# you have installed the server correctly (see above) so it reads this 
# file.
#
# server_type=3
[mysqld]

# The next three options are mutually exclusive to SERVER_PORT below.
# skip-networking
# enable-named-pipe
# shared-memory

# shared-memory-base-name=MYSQL

# The Pipe the MySQL Server will use
# socket=MYSQL

# The TCP/IP Port the MySQL Server will listen on
port=3307

# Path to installation directory. All paths are usually resolved relative to this.
basedir=F:\diy\MySQL\MySQL8

# Path to the database root
datadir=F:\diy\MySQL\Data

# The default character set that will be used when a new schema or table is
# created and no character set is defined
# character-set-server=

# The default authentication plugin to be used when connecting to the server
default_authentication_plugin=caching_sha2_password

# The default storage engine that will be used when create new tables when
default-storage-engine=INNODB

# Set the SQL mode to strict
sql-mode="STRICT_TRANS_TABLES,NO_ENGINE_SUBSTITUTION"

# General and Slow logging.
log-output=FILE

general-log=1

general_log_file="diy.log"

slow-query-log=1

slow_query_log_file="diy-slow.log"

long_query_time=10

# Error Logging.
log-error="diy.err"

# ***** Group Replication Related *****
# Specifies the base name to use for binary log files. With binary logging
# enabled, the server logs all statements that change data to the binary
# log, which is used for backup and replication.
log-bin="diy-bin"

# ***** Group Replication Related *****
# Sets the binary logging format, and can be any one of STATEMENT, ROW,
# or MIXED. ROW is suggested for Group Replication.
# binlog_format

# ***** Group Replication Related *****
# Causes the master to write a checksum for each event in the binary log.
# binlog_checksum supports the values NONE (disabled) and CRC32.
# The default is CRC32. When disabled (value NONE), the server verifies
# that it is writing only complete events to the binary log by writing
# and checking the event length (rather than a checksum) for each event.
# NONE must be used with Group Replication.
# binlog_checksum

# ***** Group Replication Related *****
# The base name for the relay log. The server creates relay log files in
# sequence by adding a numeric suffix to the base name. If you specify this
# option, the value specified is also used as the base name for the relay log
# index file. Relay logs increase speed by using load-balancing between disks.
relay_log="diy-relay"

server-id=3307

# ***** Group Replication Related *****
# The host name or IP address of the slave to be reported to the master
# during slave registration. This value appears in the output of SHOW SLAVE HOSTS
# on the master server. Leave the value unset if you do not want the slave to
# register itself with the master.
# report_host=0.0

# ***** Group Replication Related *****
# The TCP/IP port number for connecting to the slave, to be reported to the master during
# slave registration. Set this only if the slave is listening on a nondefault port or if
# you have a special tunnel from the master or other clients to the slave.
# report_port

# ***** Group Replication Related *****
# This option specifies whether global transaction identifiers (GTIDs) are
# used to identify transactions. ON must be used with Group Replication.
# gtid_mode

# ***** Group Replication Related *****
# When enabled, the server enforces GTID consistency by allowing execution of
# only statements that can be safely logged using a GTID. You must set this
# option to ON before enabling GTID based replication.
# enforce_gtid_consistency

# ***** Group Replication Related *****
# Whether updates received by a slave server from a master server should be
# logged to the slave's own binary log. Binary logging must be enabled on
# the slave for this variable to have any effect. ON must be used with
# Group Replication.
# log_slave_updates

# ***** Group Replication Related *****
# Determines whether the slave server logs master status and connection information
# to an InnoDB table in the mysql database, or to a file in the data directory.
# The TABLE setting is required when multiple replication channels are configured.
# master_info_repository

# ***** Group Replication Related *****
# Determines whether the slave server logs its position in the relay logs to an InnoDB
# table in the mysql database, or to a file in the data directory. The TABLE setting is
# required when multiple replication channels are configured.
# relay_log_info_repository

# ***** Group Replication Related *****
# Defines the algorithm used to hash the writes extracted during a transaction. If you
# are using Group Replication, this variable must be set to XXHASH64 because the process
# of extracting the writes from a transaction is required for conflict detection on all
# group members.
# transaction_write_set_extraction

# NOTE: Modify this value after Server initialization won't take effect.
lower_case_table_names=1

# Secure File Priv.
; secure-file-priv="C:/diy/MySQL/Data/Uploads"

# The maximum amount of concurrent sessions the MySQL server will
# allow. One of these connections will be reserved for a user with
# SUPER privileges to allow the administrator to login even if the
# connection limit has been reached.
max_connections=151

# The number of open tables for all threads. Increasing this value
# increases the number of file descriptors that mysqld requires.
# Therefore you have to make sure to set the amount of open files
# allowed to at least 4096 in the variable "open-files-limit" in
# section [mysqld_safe]
table_open_cache=2000

# Maximum size for internal (in-memory) temporary tables. If a table
# grows larger than this value, it is automatically converted to disk
# based table This limitation is for a single table. There can be many
# of them.
tmp_table_size=7M

# How many threads we should keep in a cache for reuse. When a client
# disconnects, the client's threads are put in the cache if there aren't
# more than thread_cache_size threads from before.  This greatly reduces
# the amount of thread creations needed if you have a lot of new
# connections. (Normally this doesn't give a notable performance
# improvement if you have a good thread implementation.)
thread_cache_size=10

#*** MyISAM Specific options
# The maximum size of the temporary file MySQL is allowed to use while
# recreating the index (during REPAIR, ALTER TABLE or LOAD DATA INFILE.
# If the file-size would be bigger than this, the index will be created
# through the key cache (which is slower).
myisam_max_sort_file_size=100G

# The size of the buffer that is allocated when sorting MyISAM indexes
# during a REPAIR TABLE or when creating indexes with CREATE INDEX
# or ALTER TABLE.
myisam_sort_buffer_size=8M

# Size of the Key Buffer, used to cache index blocks for MyISAM tables.
# Do not set it larger than 30% of your available memory, as some memory
# is also required by the OS to cache rows. Even if you're not using
# MyISAM tables, you should still set it to 8-64M as it will also be
# used for internal temporary disk tables.
key_buffer_size=8M

# Size of the buffer used for doing full table scans of MyISAM tables.
# Allocated per thread, if a full scan is needed.
read_buffer_size=8K

read_rnd_buffer_size=148K

#*** INNODB Specific options ***
# innodb_data_home_dir=

# Use this option if you have a MySQL server with InnoDB support enabled
# but you do not plan to use it. This will save memory and disk space
# and speed up some things.
# skip-innodb

# If set to 1, InnoDB will flush (fsync) the transaction logs to the
# disk at each commit, which offers full ACID behavior. If you are
# willing to compromise this safety, and you are running small
# transactions, you may set this to 0 or 2 to reduce disk I/O to the
# logs. Value 0 means that the log is only written to the log file and
# the log file flushed to disk approximately once per second. Value 2
# means the log is written to the log file at each commit, but the log
# file is only flushed to disk approximately once per second.
innodb_flush_log_at_trx_commit=1

# The size of the buffer InnoDB uses for buffering log data. As soon as
# it is full, InnoDB will have to flush it to disk. As it is flushed
# once per second anyway, it does not make sense to have it very large
# (even with long transactions).
innodb_log_buffer_size=1M

# InnoDB, unlike MyISAM, uses a buffer pool to cache both indexes and
# row data. The bigger you set this the less disk I/O is needed to
# access data in tables. On a dedicated database server you may set this
# parameter up to 80% of the machine physical memory size. Do not set it
# too large, though, because competition of the physical memory may
# cause paging in the operating system.  Note that on 32bit systems you
# might be limited to 2-3.5G of user level memory per process, so do not
# set it too high.
innodb_buffer_pool_size=8M

# Size of each log file in a log group. You should set the combined size
# of log files to about 25%-100% of your buffer pool size to avoid
# unneeded buffer pool flush activity on log file overwrite. However,
# note that a larger logfile size will increase the time needed for the
# recovery process.
innodb_log_file_size=48M

# Number of threads allowed inside the InnoDB kernel. The optimal value
# depends highly on the application, hardware as well as the OS
# scheduler properties. A too high value may lead to thread thrashing.
innodb_thread_concurrency=9

# The increment size (in MB) for extending the size of an auto-extend InnoDB system tablespace file when it becomes full.
innodb_autoextend_increment=64

# The number of regions that the InnoDB buffer pool is divided into.
# For systems with buffer pools in the multi-gigabyte range, dividing the buffer pool into separate instances can improve concurrency,
# by reducing contention as different threads read and write to cached pages.
innodb_buffer_pool_instances=8

# Determines the number of threads that can enter InnoDB concurrently.
innodb_concurrency_tickets=5000

# Specifies how long in milliseconds (ms) a block inserted into the old sublist must stay there after its first access before
# it can be moved to the new sublist.
innodb_old_blocks_time=1000

# It specifies the maximum number of .ibd files that MySQL can keep open at one time. The minimum value is 10.
innodb_open_files=300

# When this variable is enabled, InnoDB updates statistics during metadata statements.
innodb_stats_on_metadata=0

# When innodb_file_per_table is enabled (the default in 5.6.6 and higher), InnoDB stores the data and indexes for each newly created table
# in a separate .ibd file, rather than in the system tablespace.
innodb_file_per_table=1

# Use the following list of values: 0 for crc32, 1 for strict_crc32, 2 for innodb, 3 for strict_innodb, 4 for none, 5 for strict_none.
innodb_checksum_algorithm=0

# The number of outstanding connection requests MySQL can have.
# This option is useful when the main MySQL thread gets many connection requests in a very short time.
# It then takes some time (although very little) for the main thread to check the connection and start a new thread.
# The back_log value indicates how many requests can be stacked during this short time before MySQL momentarily
# stops answering new requests.
# You need to increase this only if you expect a large number of connections in a short period of time.
back_log=80

# If this is set to a nonzero value, all tables are closed every flush_time seconds to free up resources and
# synchronize unflushed data to disk.
# This option is best used only on systems with minimal resources.
flush_time=0

# The minimum size of the buffer that is used for plain index scans, range index scans, and joins that do not use
# indexes and thus perform full table scans.
join_buffer_size=256K

# The maximum size of one packet or any generated or intermediate string, or any parameter sent by the
# mysql_stmt_send_long_data() C API function.
max_allowed_packet=4M

# If more than this many successive connection requests from a host are interrupted without a successful connection,
# the server blocks that host from performing further connections.
max_connect_errors=100

# Changes the number of file descriptors available to mysqld.
# You should try increasing the value of this option if mysqld gives you the error "Too many open files".
open_files_limit=4161

# If you see many sort_merge_passes per second in SHOW GLOBAL STATUS output, you can consider increasing the
# sort_buffer_size value to speed up ORDER BY or GROUP BY operations that cannot be improved with query optimization
# or improved indexing.
sort_buffer_size=256K

# The number of table definitions (from .frm files) that can be stored in the definition cache.
# If you use a large number of tables, you can create a large table definition cache to speed up opening of tables.
# The table definition cache takes less space and does not use file descriptors, unlike the normal table cache.
# The minimum and default values are both 400.
table_definition_cache=1400

# Specify the maximum size of a row-based binary log event, in bytes.
# Rows are grouped into events smaller than this size if possible. The value should be a multiple of 256.
binlog_row_event_max_size=8K

# If the value of this variable is greater than 0, a replication slave synchronizes its master.info file to disk.
# (using fdatasync()) after every sync_master_info events.
sync_master_info=10000

# If the value of this variable is greater than 0, the MySQL server synchronizes its relay log to disk.
# (using fdatasync()) after every sync_relay_log writes to the relay log.
sync_relay_log=10000

# If the value of this variable is greater than 0, a replication slave synchronizes its relay-log.info file to disk.
# (using fdatasync()) after every sync_relay_log_info transactions.
sync_relay_log_info=10000

# Load mysql plugins at start."plugin_x ; plugin_y".
# plugin_load

# The TCP/IP Port the MySQL Server X Protocol will listen on.
# loose_mysqlx_port=33060